media-fonts/urw-fonts/urw-fonts-2.4.9.ebuild

   1 # Copyright 1999-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 # At some point URW++ released fonts under GPL license. After that they were took
   7 # and improved by Valek Filippov and this work was somehow related with AFPL...
   8 # At least it can be found on their svn server:
   9 # http://svn.ghostscript.com/ghostscript/trunk/urw-fonts/
  10
  11 # Also, some time ago, sources where published on sf.net:
  12 # https://sourceforge.net/projects/gs-fonts/files/
  13 # At this point this package was published on a nuber of other sites
  14 # (gimp.org/cups.org) and media-fonts/gnu-gs-fonts-std was added to the tree.
  15 # But nobody use that old releases any mover and everybody syncs with
  16 # svn.ghostscript.com. The most recent tag there is:
  17 # http://svn.ghostscript.com/ghostscript/tags/urw-fonts-1.0.7pre44/
  18
  19 # But note that version we have is different from upstream tag. This happened
  20 # because we started to use redhat versions and followed their versioning. It's
  21 # hard to say why they use such strange version since they also sync with
  22 # svn.ghostscript.com. Redhat's ChangeLog states:
  23 # Tue Jan 8 23:00:00 2008 Than Ngo 2.4-2
  24 #  - update to 1.0.7pre44
  25
  26 inherit estack rpm font
  27
  28 MY_PV=$(ver_rs 2 -)
  29
  30 DESCRIPTION="free good quality fonts gpl'd by URW++"
  31 HOMEPAGE="http://www.urwpp.de/"
  32 SRC_URI="mirror://gentoo/${PN}-${MY_PV}.fc13.src.rpm"
  33
  34 LICENSE="GPL-2"
  35 SLOT="0"
  36 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
  37
  38 RDEPEND="
  39         !media-fonts/gnu-gs-fonts-std
  40         !media-fonts/gnu-gs-fonts-other"
  41
  42 S="${WORKDIR}"
  43
  44 DOCS="ChangeLog README*"
  45 FONT_S="${S}"
  46 FONT_SUFFIX="afm pfb pfm"
  47
  48 pkg_postinst() {
  49         font_pkg_postinst
  50
  51         elog "If you upgraded from ${PN}-2.1-r2 some fonts will look a bit"
  52         elog "different. Take a look at bug #208990 if interested."
  53 }