dev-util/dialog/dialog-1.3.20201126.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DIA_P=${PN}-$(ver_cut 1-2)-$(ver_cut 3)
   7 DESCRIPTION="tool to display dialog boxes from a shell"
   8 HOMEPAGE="https://invisible-island.net/dialog/"
   9 SRC_URI="https://invisible-island.net/datafiles/release/$PN.tar.gz -> $DIA_P.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0/15"
  13 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86"
  14 IUSE="examples minimal nls static-libs unicode"
  15
  16 RDEPEND="
  17         >=sys-libs/ncurses-5.2-r5:=[unicode?]
  18 "
  19 DEPEND="
  20         ${RDEPEND}
  21         nls? ( sys-devel/gettext )
  22         !minimal? ( sys-devel/libtool )
  23 "
  24 S=${WORKDIR}/${DIA_P}
  25
  26 src_prepare() {
  27         default
  28         sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
  29         sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
  30 }
  31
  32 src_configure() {
  33         econf \
  34                 --disable-rpath-hack \
  35                 $(use_enable nls) \
  36                 $(use_with !minimal libtool) \
  37                 --with-libtool-opts=$(usex static-libs '' '-shared') \
  38                 --with-ncurses$(usex unicode w '')
  39 }
  40
  41 src_install() {
  42         use minimal && default || emake DESTDIR="${D}" install-full
  43
  44         use examples && dodoc -r samples
  45
  46         dodoc CHANGES README
  47
  48         find "${ED}" -name '*.la' -delete || die
  49 }