media-sound/picard/picard-2.4.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{7,8,9} )
   7 DISTUTILS_SINGLE_IMPL=1
   8 DISABLE_AUTOFORMATTING=true
   9 inherit distutils-r1 xdg
  10
  11 if [[ ${PV} = *9999* ]]; then
  12         EGIT_REPO_URI="https://github.com/metabrainz/picard"
  13         inherit git-r3
  14 else
  15         SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
  16         KEYWORDS="amd64 x86"
  17         S="${WORKDIR}/${PN}-release-${PV}"
  18 fi
  19
  20 DESCRIPTION="Cross-platform music tagger"
  21 HOMEPAGE="https://picard.musicbrainz.org"
  22
  23 LICENSE="GPL-2+"
  24 SLOT="0"
  25 IUSE="discid fingerprints nls"
  26
  27 BDEPEND="
  28         nls? ( dev-qt/linguist-tools:5 )
  29 "
  30 RDEPEND="
  31         $(python_gen_cond_dep '
  32                 dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_MULTI_USEDEP}]
  33                 dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
  34                 media-libs/mutagen[${PYTHON_MULTI_USEDEP}]
  35                 discid? ( dev-python/python-discid[${PYTHON_MULTI_USEDEP}] )
  36         ')
  37         dev-qt/qtgui:5
  38         fingerprints? ( media-libs/chromaprint[tools] )
  39 "
  40
  41 RESTRICT="test" # doesn't work with ebuilds
  42
  43 python_compile() {
  44         local build_args=(
  45                 --disable-autoupdate
  46         )
  47         if ! use nls; then
  48                 build_args+=( --disable-locales )
  49         fi
  50         distutils-r1_python_compile ${build_args[@]}
  51 }
  52
  53 python_install() {
  54         local install_args=(
  55                 --disable-autoupdate
  56                 --skip-build
  57         )
  58         if ! use nls; then
  59                 install_args+=( --disable-locales )
  60         fi
  61         distutils-r1_python_install ${install_args[@]}
  62 }
  63
  64 python_install_all() {
  65         distutils-r1_python_install_all
  66
  67         elog "If you are upgrading Picard and it does not start, try removing"
  68         elog "Picard's settings:"
  69         elog "        rm ~/.config/MusicBrainz/Picard.conf"
  70 }