media-sound/picard/picard-2.0.4.ebuild

   1 # Copyright © 2018 Nick Bowler
   2 # License GPLv2+: GNU General Public License version 2 or later.
   3 # This is free software: you are free to change and redistribute it.
   4 # There is NO WARRANTY, to the extent permitted by law.
   5 #
   6 # This a modified version of the original ebuild from Gentoo GNU/Linux,
   7 # covered by the following copyright and permission notice:
   8 #
   9 #   Copyright 1999-2018 Gentoo Foundation
  10 #   Distributed under the terms of the GNU General Public License v2
  11
  12 EAPI=6
  13
  14 PYTHON_COMPAT=( python3_{5,6} )
  15 DISTUTILS_SINGLE_IMPL=1
  16 DISABLE_AUTOFORMATTING=true
  17
  18 inherit distutils-r1 gnome2-utils readme.gentoo-r1 xdg-utils
  19
  20 DESCRIPTION="A cross-platform music tagger"
  21 HOMEPAGE="https://picard.musicbrainz.org"
  22 SRC_URI="https://github.com/metabrainz/$PN/archive/release-$PV.tar.gz -> $P.tar.gz"
  23
  24 LICENSE="GPL-2+"
  25 SLOT="0"
  26 KEYWORDS="amd64 x86"
  27 IUSE="nls"
  28
  29 RDEPEND="dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
  30         >=media-libs/mutagen-1.38"
  31 DEPEND="$RDEPEND
  32         nls? ( dev-qt/linguist-tools:5 )"
  33
  34 RESTRICT="test" # doesn't work with ebuilds
  35
  36 S=$WORKDIR/picard-release-$PV
  37
  38 python_compile() {
  39         local build_args=(
  40                 --disable-autoupdate
  41         )
  42         if ! use nls; then
  43                 build_args+=( --disable-locales )
  44         fi
  45         distutils-r1_python_compile ${build_args[@]}
  46 }
  47
  48 python_install() {
  49         local install_args=(
  50                 --disable-autoupdate
  51                 --skip-build
  52         )
  53         if ! use nls; then
  54                 install_args+=( --disable-locales )
  55         fi
  56         distutils-r1_python_install ${install_args[@]}
  57 }
  58
  59 python_install_all() {
  60         distutils-r1_python_install_all
  61
  62         local DOC_CONTENTS="Install optional package media-libs/chromaprint[tools] to enable
  63 calculation and lookup of AcoustID fingerprints.
  64
  65 Install optional package dev-python/python-discid to enable
  66 calculation and lookup of compact disc identifiers (disc IDs).
  67
  68 If you are upgrading Picard and it does not start, try removing
  69 Picard's settings:
  70         rm ~/.config/MusicBrainz/Picard.conf"
  71         readme.gentoo_create_doc
  72 }
  73
  74 pkg_postinst() {
  75         readme.gentoo_print_elog
  76         xdg_desktop_database_update
  77         gnome2_icon_cache_update
  78 }
  79
  80 pkg_postrm() {
  81         xdg_desktop_database_update
  82         gnome2_icon_cache_update
  83 }