testsuite.at

   1 AT_COPYRIGHT([dnl
   2 Copyright © 2015,2019-2021 Nick Bowler
   3 License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 This is free software: you are free to do what the fuck you want to.
   5 There is NO WARRANTY, to the extent permitted by law.])
   6
   7 AT_INIT
   8 AT_COLOR_TESTS
   9
  10 AT_TESTED([prove])
  11
  12 m4_divert_push([PREPARE_TESTS])dnl
  13 # Reduce influence from the toplevel "make" invocation on test cases.
  14 AS_UNSET([MAKEFLAGS])
  15 AS_UNSET([MAKELEVEL])
  16 AS_UNSET([MFLAGS])
  17 m4_divert_pop([PREPARE_TESTS])
  18
  19 m4_define([TEST_CONFIGURE_AC], [AT_KEYWORDS([autoconf m4])dnl
  20 AT_DATA([configure.ac],
  21 [[AC_INIT([test], [0])
  22 ]$1[
  23 AC_OUTPUT
  24 ]])
  25 cp "$srcdir/install-sh" \
  26    "$srcdir/depcomp" \
  27    "$srcdir/missing" \
  28    "$srcdir/config.sub" \
  29    .
  30 # Simplified config.guess script avoids some spurious testcase failures
  31 # when using heirloom-sh on GNU/Linux.
  32 config_guess=`"$srcdir/config.guess"`
  33 cat >config.guess <<EOF
  34 #!/bin/sh
  35 cat <<'GUESS_EOF'
  36 $config_guess
  37 GUESS_EOF
  38 EOF
  39 chmod +x config.guess
  40 ])
  41 m4_define([TEST_AUTORECONF], [AT_KEYWORDS([autoconf])dnl
  42 AT_CHECK([autoreconf -I "$srcdir/m4"], [0], [], [stderr])])
  43
  44 m4_define([TEST_CONFIGURE], [AT_KEYWORDS([configure])dnl
  45 AT_CHECK([export CC
  46 CONFIG_SHELL=$TEST_SHELL $TEST_SHELL ./configure CONFIG_SHELL=$TEST_SHELL $1],
  47 [0], [ignore])])
  48
  49 m4_include([tests/macros.at])
  50 m4_include([tests/snippets.at])
  51 m4_include([tests/functions.at])
  52 m4_include([tests/programs.at])
  53 m4_include([tests/libs.at])
  54 m4_include([tests/scripts.at])