AT_COPYRIGHT([dnl
Copyright © 2015,2019-2021 Nick Bowler
License WTFPL2: Do What The Fuck You Want To Public License, version 2.
This is free software: you are free to do what the fuck you want to.
There is NO WARRANTY, to the extent permitted by law.])

AT_INIT
AT_COLOR_TESTS

AT_TESTED([prove])

m4_divert_push([PREPARE_TESTS])dnl
# Reduce influence from the toplevel "make" invocation on test cases.
AS_UNSET([MAKEFLAGS])
AS_UNSET([MAKELEVEL])
AS_UNSET([MFLAGS])
m4_divert_pop([PREPARE_TESTS])

m4_define([TEST_CONFIGURE_AC], [AT_KEYWORDS([autoconf m4])dnl
AT_DATA([configure.ac],
[[AC_INIT([test], [0])
]$1[
AC_OUTPUT
]])
cp "$srcdir/install-sh" \
   "$srcdir/depcomp" \
   "$srcdir/missing" \
   "$srcdir/config.sub" \
   .
# Simplified config.guess script avoids some spurious testcase failures
# when using heirloom-sh on GNU/Linux.
config_guess=`"$srcdir/config.guess"`
cat >config.guess <<EOF
#!/bin/sh
cat <<'GUESS_EOF'
$config_guess
GUESS_EOF
EOF
chmod +x config.guess
])
m4_define([TEST_AUTORECONF], [AT_KEYWORDS([autoconf])dnl
AT_CHECK([autoreconf -I "$srcdir/m4"], [0], [], [stderr])])

m4_define([TEST_CONFIGURE], [AT_KEYWORDS([configure])dnl
AT_CHECK([export CC
CONFIG_SHELL=$TEST_SHELL $TEST_SHELL ./configure CONFIG_SHELL=$TEST_SHELL $1],
[0], [ignore])])

m4_include([tests/macros.at])
m4_include([tests/snippets.at])
m4_include([tests/functions.at])
m4_include([tests/programs.at])
m4_include([tests/libs.at])
m4_include([tests/scripts.at])