dev-util/lcov: Fix prefix installation.

[gentoo-fixes.git] / dev-util / lcov / lcov-1.15.ebuild

diff --git a/dev-util/lcov/lcov-1.15.ebuild b/dev-util/lcov/lcov-1.15.ebuild
new file mode 100644 (file)
index 0000000..391a710
--- /dev/null
+++ b/dev-util/lcov/lcov-1.15.ebuild
@@ -0,0 +1,54 @@
+# Copyright © 2020 Nick Bowler
+#
+# License GPLv2+: GNU General Public License version 2 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+#
+# This is a modified version of the original ebuild from Gentoo GNU/Linux,
+# covered by the following copyright and permission notice:
+#
+#   Copyright 1999-2020 Gentoo Authors
+#   Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == "9999" ]] ; then
+       EGIT_REPO_URI="https://github.com/linux-test-project/lcov.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/linux-test-project/lcov/releases/download/v${PV}/${P}.tar.gz"
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-linux ~x64-macos"
+fi
+
+inherit optfeature prefix
+
+DESCRIPTION="A graphical front-end for GCC's coverage testing tool gcov"
+HOMEPAGE="http://ltp.sourceforge.net/coverage/lcov.php"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND="
+       dev-lang/perl
+       dev-perl/JSON
+       dev-perl/PerlIO-gzip
+"
+
+src_prepare() {
+       default
+       if use prefix; then
+               hprefixify bin/*.{pl,sh}
+       fi
+}
+
+src_compile() { :; }
+
+src_install() {
+       emake -j1 PREFIX="${ED}/usr" CFG_DIR="${ED}/etc" \
+               LCOV_PERL_PATH="${EPREFIX%/}/usr/bin/perl" install
+}
+
+pkg_postinst() {
+       elog "Optional features:"
+       optfeature "png output support" dev-perl/GD[png]
+}