games-engines/onscripter-en/onscripter-en-20110930.ebuild

   1 # Copyright © 2015 Nick Bowler
   2 # License GPLv3+: GNU General Public License version 3 or later.
   3 # There is NO WARRANTY, to the extent permitted by law.
   4
   5 EAPI=5
   6
   7 inherit base games
   8
   9 DESCRIPTION="English-language fork of ONScripter: a free clone of NScripter"
  10 HOMEPAGE="http://unclemion.com/dev/projects/onscripter-en"
  11
  12 # This package has a hard dep on SDL_ttf-2.0.10, fonts do not work with
  13 # 2.0.11.  Download that release specifically.
  14 SRC_URI="http://unclemion.com/dev/attachments/download/36/$P-src.tar.bz2
  15         https://www.libsdl.org/projects/SDL_ttf/release/SDL_ttf-2.0.10.tar.gz
  16         "
  17
  18 LICENSE="GPL-2+ ZLIB"
  19 SLOT="0"
  20 KEYWORDS="~amd64"
  21
  22 DEPEND="app-arch/bzip2
  23         media-libs/libsdl
  24         media-libs/sdl-mixer[vorbis]
  25         media-libs/sdl-image
  26         media-libs/smpeg
  27         media-libs/freetype:2
  28         x11-libs/libXt
  29         "
  30 RDEPEND=$DEPEND
  31
  32 PATCHES=(
  33         "$FILESDIR/$P-fix-configure.patch"
  34         "$FILESDIR/$PN-respect-CXXFLAGS.patch"
  35         )
  36
  37 src_configure() {
  38         einfo "Configuring SDL_ttf"
  39         cd "$WORKDIR/SDL_ttf-2.0.10" || die
  40         econf --prefix="$S/onscrlib" --libdir='${prefix}/lib' \
  41                 --enable-static --disable-shared || die
  42
  43         einfo "Configuring $PN"
  44         cd "$S" || die
  45         econf --unsupported-compiler \
  46                 --onscrlib-path="$S" --with-internal-sdl-ttf
  47 }
  48
  49 src_compile() {
  50         einfo "Building SDL_ttf"
  51         cd "$WORKDIR/SDL_ttf-2.0.10" || die
  52         emake noinst_PROGRAMS= install || die
  53
  54         einfo "Building $PN"
  55         cd "$S" || die
  56         base_src_compile
  57 }
  58
  59 src_install() {
  60         dodoc README
  61
  62         dogamesbin onscripter-en
  63         prepgamesdirs
  64 }