sys-apps/vbetest/vbetest-0.10-r1.ebuild

   1 # Copyright © 2009, 2012, 2021 Nick Bowler
   2 # License GPLv3+: GNU General Public License version 3 or any later version.
   3 # This is free software: you are free to change and redistribute it.
   4 # There is NO WARRANTY, to the extent permitted by law.
   5
   6 EAPI=7
   7
   8 inherit toolchain-funcs
   9
  10 MY_PN=lrmi
  11 MY_P=$MY_PN-$PV
  12
  13 DESCRIPTION="Utility to display and test VESA BIOS Extensions (VBE) modes."
  14 HOMEPAGE="http://www.sourceforge.net/projects/lrmi/"
  15 SRC_URI="mirror://sourceforge/$MY_PN/$MY_P.tar.gz"
  16
  17 LICENSE="public-domain"
  18 SLOT="0"
  19 KEYWORDS="~x86 ~amd64"
  20 IUSE="lrmi"
  21
  22 DEPEND="lrmi? ( =sys-libs/lrmi-${PV}* )
  23         !lrmi? ( dev-libs/libx86 )"
  24 RDEPEND=$DEPEND
  25
  26 PATCHES=(
  27         "$FILESDIR/$P-external-include.patch"
  28 )
  29
  30 S=$WORKDIR/$MY_P
  31
  32 src_compile() {
  33         local inc= lib=-llrmi CC=$(tc-getCC)
  34         use lrmi || { inc='-DLRMI_INCLUDE=<libx86.h>' lib=-lx86; }
  35
  36         (set -x; $CC $inc $CPPFLAGS $CFLAGS -c vbetest.c; ) || die
  37         (set -x; $CC $CFLAGS $LDFLAGS -o vbetest vbetest.o $lib ) || die
  38 }
  39
  40 src_install() {
  41         dobin vbetest
  42 }