net-libs/libmapi/libmapi-2.3-r1.ebuild

   1 # Copyright © 2016, 2022 Nick Bowler
   2 # License GPLv3+: GNU General Public License version 3 or any later version.
   3 # This is free software: you are free to change and redistribute it.
   4 # There is NO WARRANTY, to the extent permitted by law.
   5
   6 EAPI=8
   7
   8 inherit autotools
   9
  10 MY_P=openchange-$PV-VULCAN
  11
  12 DESCRIPTION="Library implementing the Microsoft Exchange protocol"
  13 HOMEPAGE="http://openchange.org"
  14 SRC_URI="https://github.com/openchange/openchange/archive/$MY_P.tar.gz"
  15
  16 LICENSE="GPL-3+"
  17 KEYWORDS="~amd64"
  18 IUSE="cxx"
  19 SLOT="0"
  20
  21 RDEPEND=">=net-fs/samba-4"
  22 DEPEND="dev-util/pidl
  23         $RDEPEND"
  24
  25 PATCHES=(
  26         "$FILESDIR/$P-no-automake.patch"
  27         "$FILESDIR/$P-no-useless-cflags.patch"
  28         "$FILESDIR/$P-no-recompile-on-install.patch"
  29         "$FILESDIR/$P-no-build-tests.patch"
  30         "$FILESDIR/$P-configure-bashisms.patch"
  31         "$FILESDIR/$P-update-credentials-api.patch"
  32         "$FILESDIR/$P-update-ndr-api.patch"
  33         "$FILESDIR/$P-fix-pidl-compilation.patch"
  34 )
  35
  36 S=$WORKDIR/openchange-$MY_P
  37
  38 src_prepare() {
  39         default_src_prepare
  40         eautoreconf
  41 }
  42
  43 src_configure() {
  44         econf MYSQL_CONFIG=/bin/true \
  45               NANOMSG_CFLAGS=' ' NANOMSG_LIBS=' ' \
  46               MEMCACHED_CFLAGS=' ' MEMCACHED_LIBS=' ' \
  47               MANUALLY_CREATE_SYMLINKS=yes \
  48               --disable-pyopenchange
  49 }
  50
  51 src_compile() {
  52         emake libmapi$(usex cxx xx '')
  53 }
  54
  55 src_install() {
  56         emake DESTDIR="$D" libmapi-install $(usex cxx libmapixx-install '')
  57 }