tests/macros.at

   1 dnl Copyright © 2014-2015, 2018-2019, 2021-2022 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AT_BANNER([Autoconf macros])
   8
   9 dnl Verify that the DX_BASEDIR macro expands correctly during argument
  10 dnl collection.  Crucially, the output must not contain any other text.
  11 AT_SETUP([DX_BASEDIR during argument collection])
  12 AT_KEYWORDS([DX_BASEDIR macro])
  13
  14 AT_DATA([test.in],
  15 [[@TEST@
  16 ]])
  17
  18 TEST_CONFIGURE_AC(
  19 [[AC_SUBST([TEST], 'm4@&t@_dquote(DX_BASEDIR)')
  20 AC_CONFIG_FILES([test])
  21 ]])
  22 TEST_AUTORECONF
  23 TEST_CONFIGURE
  24
  25 printf '%s\n' "$srcdir" | sed -e 's:/\./:/:g' -e 's:/\.$::g' \
  26                               -e 's:\(.\)//*:\1/:g' >expout
  27 AT_CHECK([cat test], [0], [expout])
  28
  29 AT_CLEANUP
  30
  31 dnl Verify that DX_BASEDIR is correctly AC_SUBSTed
  32 AT_SETUP([DX_BASEDIR output substitution])
  33 AT_KEYWORDS([DX_BASEDIR macro])
  34
  35 AT_DATA([test.in],
  36 [[@DX_BASEDIR@
  37 ]])
  38
  39 TEST_CONFIGURE_AC(
  40 [[DX_INIT
  41 AC_CONFIG_FILES([test])
  42 ]])
  43 TEST_AUTORECONF
  44 TEST_CONFIGURE
  45
  46 printf '${top_srcdir}/%s\n' "$srcdir" | sed -e 's:/\./:/:g' -e 's:/\.$::g' \
  47                                             -e 's:\(.\)//*:\1/:g' >expout
  48 AT_CHECK([cat test], [0], [expout])
  49
  50 AT_CLEANUP
  51
  52 dnl Verify that DX_BASEDIR is set correctly implicitly
  53 AT_SETUP([DX_BASEDIR implicit definition])
  54 AT_KEYWORDS([DX_BASEDIR macro])
  55
  56 AT_DATA([test.in],
  57 [[@DX_BASEDIR@
  58 ]])
  59
  60 TEST_CONFIGURE_AC(
  61 [[DX_EXPORTED_SH
  62 AC_CONFIG_FILES([test])
  63 ]])
  64 TEST_AUTORECONF
  65 TEST_CONFIGURE
  66
  67 AT_CLEANUP
  68
  69 AT_SETUP([DX_COMMAND_OUTPUT])
  70 AT_KEYWORDS([DX_COMMAND_OUTPUT macro])
  71
  72 AT_DATA([expout],
  73 [[   leading whitespace
  74 trailing whitespace     @&t@
  75 embedded\ backslashes
  76       @&t@
  77 backslash\
  78 newline
  79 ]])
  80
  81 TEST_CONFIGURE_AC(
  82 [[DX_COMMAND_OUTPUT([var], [cat expout])
  83 AS@&t@_ECHO(["$var"]) >test.out
  84 ]])
  85 TEST_AUTORECONF
  86 TEST_CONFIGURE
  87
  88 AT_CHECK([cat test.out], [0], [expout])
  89
  90 AT_CLEANUP
  91
  92 AT_SETUP([DX_DO quoting])
  93 AT_KEYWORDS([DX_DO macro])
  94
  95 TEST_CONFIGURE_AC(
  96 [[m4@&t@_define([FOO])
  97 :; { DX_DO([AS@&t@_ECHO_N(["[FOO]"])],
  98            [AS@&t@_ECHO_N(["[FOO]"])],
  99            [AS@&t@_ECHO(["[FOO]"])])
 100 } >test.out
 101 ]])
 102
 103 dnl TEST_CONFIGURE_AC(
 104 dnl [[DX_DO([AS@&t@_ECHO_N([hello,world])],[AS@&t@_ECHO_N([goodbye,world])])
 105 dnl ]])
 106 TEST_AUTORECONF
 107 TEST_CONFIGURE
 108 AT_CHECK([cat test.out], [0], [[FOOFOOFOO
 109 ]])
 110
 111 AT_CLEANUP
 112
 113 AT_SETUP([DX_LINGUAS unused country variants])
 114 AT_KEYWORDS([DX_LINGUAS macro])
 115
 116 echo : >config.rpath
 117 chmod +x config.rpath
 118
 119 mkdir po
 120 AT_DATA([po/LINGUAS], [[en
 121 ]])
 122
 123 AT_DATA([test.in], [[POFILES = @POFILES@
 124 MOFILES = @MOFILES@
 125 ]])
 126
 127 TEST_CONFIGURE_AC(
 128 [[m4@&t@_traceoff([AM_GNU_GETTEXT])
 129 AM_GNU_GETTEXT([external])
 130 DX_LINGUAS
 131 AC_CONFIG_FILES([test])
 132 ]])
 133
 134 TEST_AUTORECONF
 135 LINGUAS='en_CA en'; export LINGUAS; TEST_CONFIGURE
 136
 137 AT_CHECK([cat test], [0], [[POFILES = po/en.po
 138 MOFILES = po/en.mo
 139 ]])
 140
 141 AT_CLEANUP
 142
 143 AT_SETUP([DX_LINGUAS default install all])
 144 AT_KEYWORDS([DX_LINGUAS macro])
 145
 146 AS_UNSET([LINGUAS])
 147 AT_SKIP_IF([test ${LINGUAS+y}])
 148
 149 echo : >config.rpath
 150 chmod +x config.rpath
 151
 152 mkdir po
 153 AT_DATA([po/LINGUAS], [[en ja # a comment ko
 154 zh
 155 ]])
 156
 157 AT_DATA([test.in], [[POFILES = @POFILES@
 158 MOFILES = @MOFILES@
 159 ]])
 160
 161 TEST_CONFIGURE_AC(
 162 [[m4@&t@_traceoff([AM_GNU_GETTEXT])
 163 AM_GNU_GETTEXT([external])
 164 DX_LINGUAS
 165 AC_CONFIG_FILES([test])
 166 ]])
 167
 168 TEST_AUTORECONF
 169 TEST_CONFIGURE
 170
 171 AT_CHECK([cat test], [0],
 172 [[POFILES = po/en.po po/ja.po po/zh.po
 173 MOFILES = po/en.mo po/ja.mo po/zh.mo
 174 ]])
 175
 176 AT_CLEANUP
 177
 178 AT_SETUP([DX_LINGUAS selections])
 179 AT_KEYWORDS([DX_LINGUAS macro])
 180
 181 echo : >config.rpath
 182 chmod +x config.rpath
 183
 184 mkdir po
 185 AT_DATA([po/LINGUAS], [[en ja # a comment ko
 186 zh en_US
 187 ]])
 188
 189 AT_DATA([test.in], [[POFILES = @POFILES@
 190 MOFILES = @MOFILES@
 191 ]])
 192
 193 TEST_CONFIGURE_AC(
 194 [[m4@&t@_traceoff([AM_GNU_GETTEXT])
 195 AM_GNU_GETTEXT([external])
 196 DX_LINGUAS
 197 AC_CONFIG_FILES([test])
 198 ]])
 199 TEST_AUTORECONF
 200
 201 LINGUAS='en'; export LINGUAS; TEST_CONFIGURE
 202 AT_CHECK([cat test], [0],
 203 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 204 MOFILES = po/en.mo
 205 ]])
 206
 207 LINGUAS='en_US'; export LINGUAS; TEST_CONFIGURE
 208 AT_CHECK([cat test], [0],
 209 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 210 MOFILES = po/en.mo po/en_US.mo
 211 ]])
 212
 213 LINGUAS='en_CA'; export LINGUAS; TEST_CONFIGURE
 214 AT_CHECK([cat test], [0],
 215 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 216 MOFILES = po/en.mo
 217 ]])
 218
 219 LINGUAS='ja ko'; export LINGUAS; TEST_CONFIGURE
 220 AT_CHECK([cat test], [0],
 221 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 222 MOFILES = po/ja.mo
 223 ]])
 224
 225 LINGUAS='ja_JP ko_KR'; export LINGUAS; TEST_CONFIGURE
 226 AT_CHECK([cat test], [0],
 227 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 228 MOFILES = po/ja.mo
 229 ]])
 230
 231 LINGUAS=''; export LINGUAS; TEST_CONFIGURE
 232 AT_CHECK([cat test], [0],
 233 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 234 MOFILES = @&t@
 235 ]])
 236
 237 AT_CLEANUP
 238
 239 AT_SETUP([DX_LINGUAS with broken "join" utility])
 240 AT_KEYWORDS([DX_LINGUAS macro])
 241
 242 echo : >config.rpath
 243 chmod +x config.rpath
 244
 245 mkdir bin
 246 cat >bin/join <<EOF
 247 #!/bin/sh
 248 :
 249 EOF
 250 chmod +x bin/join
 251
 252 mkdir po
 253 AT_DATA([po/LINGUAS], [[en ja # a comment ko
 254 zh en_US
 255 ]])
 256
 257 AT_DATA([test.in], [[POFILES = @POFILES@
 258 MOFILES = @MOFILES@
 259 ]])
 260
 261 TEST_CONFIGURE_AC(
 262 [[m4@&t@_traceoff([AM_GNU_GETTEXT])
 263 AM_GNU_GETTEXT([external])
 264 DX_LINGUAS
 265 AC_CONFIG_FILES([test])
 266 ]])
 267 TEST_AUTORECONF
 268
 269 save_PATH=$PATH
 270 PATH=`pwd`/bin${PATH:+":$PATH"}
 271 LINGUAS='en_US'; export LINGUAS; TEST_CONFIGURE
 272
 273 AT_CHECK([cat test], [0],
 274 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 275 MOFILES = po/en.mo po/en_US.mo
 276 ]])
 277
 278 LINGUAS='en_US'; export LINGUAS; TEST_CONFIGURE([JOIN=false])
 279
 280 AT_CHECK([cat test], [0],
 281 [[POFILES = po/en.po po/en_US.po po/ja.po po/zh.po
 282 MOFILES = po/en.mo po/en_US.mo
 283 ]])
 284
 285 PATH=$save_PATH
 286
 287 AT_CLEANUP
 288
 289 AT_SETUP([DX_BASENAME])
 290 AT_KEYWORDS([DX_BASENAME macro])
 291
 292 AT_DATA([test.in], [[@base0@
 293 @base1@
 294 @base2@
 295 @base3@
 296 ]])
 297
 298 TEST_CONFIGURE_AC(
 299 [[DX_BASENAME([base0], ["hello"])
 300 DX_BASENAME([base1], ["foo/bar"])
 301 DX_BASENAME([base2], ["/foo/bar/baz"])
 302 DX_BASENAME([base3], ["hello world"])
 303 AC_SUBST([base0])
 304 AC_SUBST([base1])
 305 AC_SUBST([base2])
 306 AC_SUBST([base3])
 307 AC_CONFIG_FILES([test])
 308 ]])
 309 TEST_AUTORECONF
 310
 311 TEST_CONFIGURE
 312 AT_CHECK([cat test], [0], [hello
 313 bar
 314 baz
 315 hello world
 316 ])
 317
 318 AT_CLEANUP
 319
 320 AT_SETUP([DX_PROG_JOIN distribution])
 321 AT_KEYWORDS([DX_PROG_JOIN macro])
 322
 323 TEST_CONFIGURE_AC([[AM_INIT_AUTOMAKE([foreign])
 324 DX_PROG_JOIN
 325 AC_CONFIG_FILES([Makefile])
 326 ]])
 327
 328 AT_DATA([Makefile.am],
 329 [[foo: ; printf '%s\n' $(DX_BASEDIR) $(DISTFILES)
 330 ]])
 331 TEST_AUTORECONF
 332
 333 TEST_CONFIGURE
 334 AT_CHECK([make -s foo], [0], [stdout])
 335 AT_CHECK([exec 3<stdout
 336 read basedir <&3; while read f <&3; do
 337   test x"$f" = x"$basedir/scripts/join.awk" && exit
 338 done
 339 exit 1])
 340
 341 AT_CLEANUP
 342
 343 AT_SETUP([DX_GNULIB_SYMFILES])
 344 AT_KEYWORDS([DX_GNULIB_SYMFILES macro])
 345
 346 echo : >compile
 347 TEST_CONFIGURE_AC([[AM_INIT_AUTOMAKE([foreign])
 348 AM_PROG_CC_C_O
 349 AC_SUBST([GLSRC], [.])
 350 DX_AUTOMAKE_COMPAT
 351 DX_GNULIB_SYMFILES([symfiles.lst])
 352 AC_CONFIG_FILES([Makefile])
 353 ]])
 354
 355 AT_DATA([symfiles.lst],
 356 [[b.foo
 357 d.bar
 358 ]])
 359
 360 cp "$srcdir/snippet/glconfig.mk" .
 361 AT_DATA([Makefile.am],
 362 [[CLEANFILES =
 363 DISTCLEANFILES =
 364
 365 # automake won't emit this without sources but we expect it to be set
 366 am__depfiles_maybe = depfiles
 367 am__maybe_remake_depfiles = depfiles
 368
 369 gnulib_headers =
 370 gnulib_objects = a.o c.o b.o e.o d.o
 371 gnulib_all_symfiles = $(gnulib_objects:.o=.glsym)
 372 gnulib_symfiles = $(gnulib_all_symfiles)
 373
 374 do_test:
 375         printf '%s\n' $(gnulib_symfiles) | LC_ALL=C sort; \
 376           echo ///; printf '%s\n' $(gnulib_extra_objects) | LC_ALL=C sort
 377 .PHONY: do_test
 378
 379 include $(top_srcdir)/glconfig.mk
 380 ]])
 381 TEST_AUTORECONF
 382
 383 TEST_CONFIGURE
 384 AT_CHECK([make -s do_test], [0], [[b.glsym
 385 d.glsym
 386 ///
 387 a.o
 388 c.o
 389 e.o
 390 ]])
 391
 392 dnl verify rebuild rule insertion
 393 sed '/^gnulib_objects/s/b[[.]]o//' Makefile.in >tmp
 394 mv -f tmp Makefile.in
 395 AT_CHECK([make -s do_test >rebuild.out &&
 396   sed '/^config.status:/,$!d' rebuild.out], [0],
 397 [[config.status: creating Makefile
 398 config.status: executing depfiles commands
 399 config.status: executing gnulib-symfiles commands
 400 d.glsym
 401 ///
 402 a.o
 403 c.o
 404 e.o
 405 ]])
 406
 407 AT_CLEANUP
 408
 409 AT_SETUP([DX_GNULIB_SYMFILES distribution])
 410 AT_KEYWORDS([DX_GNULIB_SYMFILES macro])
 411
 412 TEST_CONFIGURE_AC([[AM_INIT_AUTOMAKE([foreign])
 413 DX_GNULIB_SYMFILES([symfiles.lst])
 414 AC_CONFIG_FILES([Makefile])
 415 ]])
 416
 417 AT_DATA([symfiles.lst])
 418 AT_DATA([Makefile.am],
 419 [[foo: ; printf '%s\n' $(top_srcdir) $(DISTFILES)
 420 ]])
 421 TEST_AUTORECONF
 422
 423 TEST_CONFIGURE
 424 AT_CHECK([make -s foo], [0], [stdout])
 425 AT_CHECK([exec 3<stdout
 426 read basedir <&3; while read f <&3; do
 427   test x"$f" = x"$basedir/symfiles.lst" && exit
 428 done
 429 exit 1])
 430
 431 AT_CLEANUP