configure.ac

   1 dnl Copyright © 2011-2013, 2020-2024 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 DX_PATCH_GNULIB
   8
   9 AC_PREREQ([2.68])
  10 AC_INIT([cdecl99], [1.2a], [nbowler@draconx.ca])
  11 AC_CONFIG_HEADERS([config.h])
  12
  13 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects dist-xz])
  14 AM_SILENT_RULES([yes])
  15 DX_AUTOMAKE_COMPAT
  16
  17 AC_ARG_WITH([readline],
  18   [AS_HELP_STRING([--with-readline],
  19     [use GNU readline for line-editing functionality (default: auto)])],
  20   [], [with_readline=auto])
  21 AS_CASE([$with_readline],
  22   [no], [gl_cv_lib_readline=no],
  23   [yes|auto], [:],
  24   [*], [AC_MSG_ERROR([invalid option --with-readline=$with_readline])])
  25
  26 AC_PROG_CC_C99
  27 AM_PROG_CC_C_O
  28 gl_EARLY
  29
  30 AC_HEADER_ASSERT
  31 AC_TYPE_UNSIGNED_LONG_LONG_INT
  32 AC_C_FLEXIBLE_ARRAY_MEMBER
  33 AC_C_INLINE
  34 DX_C_FOR_DECLARATIONS
  35 AM_PROG_AR
  36
  37 LT_INIT
  38 gl_INIT
  39
  40 # As the mbrtowc replacement module is not used by the library, there is
  41 # no need for multithreaded mbrtowc (all programs are single threaded).
  42 AC_DEFINE([GNULIB_MBRTOWC_SINGLE_THREAD], [1], [Define to 1.])
  43
  44 # As the wcwidth replacement module is not used by the library, there is
  45 # no need to support varying locales (programs set locale once at startup).
  46 AC_DEFINE([GNULIB_WCHAR_SINGLE_LOCALE], [1], [Define to 1.])
  47
  48 AS_IF([test x"$gl_cv_lib_readline" = x"no"],
  49   [AS_IF([test x"$with_readline" = x"yes"],
  50     [AC_MSG_FAILURE([--with-readline requested but readline was not found])],
  51     [dx_cv_rl_add_history=no])])
  52 AC_CACHE_CHECK([if readline supports add_history], [dx_cv_rl_add_history], [dnl
  53 dx_cv_rl_add_history=no
  54 dx_save_libs=$LIBS
  55 LIBS="$LIBS $LIBREADLINE"
  56 AC_LINK_IFELSE([AC_LANG_PROGRAM([dnl
  57 #include <stdio.h>
  58 #if HAVE_READLINE_HISTORY_H
  59 #  include <readline/history.h>
  60 #endif
  61 ], [dnl
  62 (*add_history)("");
  63 ])], [dx_cv_rl_add_history=yes], [dx_cv_rl_add_history=no])
  64 LIBS=$dx_save_libs
  65 ])
  66
  67 AS_IF([test x"$dx_cv_rl_add_history" = x"yes"],
  68   [AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
  69     [Define to 1 if readline supports add_history.])])
  70
  71 m4_include([lib/gnulib.mk])
  72 DX_GLSYM_PREFIX([cdecl__gl_])
  73 DX_GNULIB_SYMFILES([lib/symfiles], [s])
  74 AM_CONDITIONAL([BUILD_STATIC], [test x"$enable_static" = x"yes"])
  75
  76 AM_CONDITIONAL([USE_NLS], [test x"$USE_NLS" = x"yes"])
  77
  78 DX_PROG_FLEX([], [have_flex=yes], [have_flex=no])
  79 AM_CONDITIONAL([HAVE_FLEX], [test x"$have_flex" = x"yes"])
  80
  81 DX_PROG_BISON([], [have_bison=yes], [have_bison=no])
  82 AM_CONDITIONAL([HAVE_BISON], [test x"$have_bison" = x"yes"])
  83
  84 DX_BISON_COMPAT
  85 BISON_I18N
  86
  87 BISON_COMPAT=
  88 AS_IF([test x"$dx_cv_bison_api_header_include" = x"yes"],
  89   [BISON_COMPAT="'--define=api.header.include={\"\$(*F).h\"}'"])
  90 AS_IF([test x"$dx_cv_bison_warn_no_deprecated" = x"yes"],
  91   [AS_VAR_APPEND([BISON_COMPAT], ["${BISON_COMPAT:+ }-Wno-deprecated"])])
  92 AC_SUBST([BISON_COMPAT])
  93
  94 AS_CASE([$dx_cv_bison_define_cmdline], [yes],
  95 [AC_CACHE_CHECK([whether $BISON supports api.token.raw],
  96   [dx_cv_bison_api_token_raw], [dx_cv_bison_api_token_raw=no
  97 cat >conftest.y <<'EOF'
  98 %token T_TEST
  99 %{
 100 int yylex(void) { return 0; }
 101 void yyerror(const char *msg) { }
 102 %}
 103 %%
 104 input:
 105 EOF
 106 AS_IF([$BISON --define api.token.raw conftest.y >&AS_MESSAGE_LOG_FD 2>&1],
 107 [AC_COMPUTE_INT([testval], [T_TEST], [#include "conftest.tab.c"
 108 ])
 109 AS_IF([test "$testval" -lt 256], [dx_cv_bison_api_token_raw=yes])])])
 110 AS_CASE([$dx_cv_bison_api_token_raw], [yes],
 111   [AS_VAR_APPEND([BISON_COMPAT], [" --define api.token.raw"])])])
 112
 113 AH_TOP([#include <conf_pre.h>])
 114 AH_BOTTOM([#include <conf_post.h>])
 115
 116 AC_CONFIG_TESTDIR([.], [t:.])
 117 DX_PROG_AUTOTEST_AM
 118
 119 AC_CACHE_CHECK([for getline], [dx_cv_have_getline],
 120   [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>
 121 ], [ssize_t (*x)() = getline;
 122 char *p = 0;
 123 size_t n = 0;
 124 return getline(&p, &n, stdin);
 125 ])], [dx_cv_have_getline=yes], [dx_cv_have_getline=no])])
 126 AS_CASE([$dx_cv_have_getline], [yes],
 127   [AC_DEFINE([HAVE_GETLINE], [1],
 128     [Define to 1 if the getline function is available.])])
 129
 130 AC_CONFIG_FILES([Makefile])
 131 AC_OUTPUT