src/parse.y

   1 %code top {
   2 /*
   3  *  Parser for C declarations.
   4  *  Copyright © 2011-2012, 2021, 2023 Nick Bowler
   5  *
   6  *  This program is free software: you can redistribute it and/or modify
   7  *  it under the terms of the GNU General Public License as published by
   8  *  the Free Software Foundation, either version 3 of the License, or
   9  *  (at your option) any later version.
  10  *
  11  *  This program is distributed in the hope that it will be useful,
  12  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *  GNU General Public License for more details.
  15  *
  16  *  You should have received a copy of the GNU General Public License
  17  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18  */
  19 }
  20
  21 %name-prefix "cdecl__yy"
  22 %parse-param {void *scanner}
  23 %parse-param {struct cdecl **out}
  24 %lex-param {yyscan_t scanner}
  25 %define api.pure
  26 %error-verbose
  27 %locations
  28
  29 %{
  30 #include <config.h>
  31 #include <assert.h>
  32 #include <stdbool.h>
  33
  34 #include "scan.h"
  35 #include "cdecl.h"
  36 #include "cdecl-internal.h"
  37 #include "errmsg.h"
  38
  39 #define FAIL(msg) do { \
  40         yyerror(&yylloc, NULL, NULL, msg); \
  41         YYERROR; \
  42 } while (0)
  43
  44 #define ALLOC(ptr, size) do { \
  45         (ptr) = malloc(size); \
  46         if (!(ptr)) { \
  47                 cdecl__errmsg(CDECL__ENOMEM); \
  48                 YYERROR; \
  49         } \
  50 } while (0)
  51
  52 #define ALLOC_STRUCT(ptr, type, ...) do { \
  53         ALLOC(ptr, sizeof (type)); \
  54         *(ptr) = (type) { __VA_ARGS__ }; \
  55 } while (0)
  56 %}
  57
  58 %code requires {
  59 #include <inttypes.h>
  60 }
  61
  62 %code provides {
  63 void cdecl__free(struct cdecl *);
  64 int cdecl__yyparse(void *scanner, struct cdecl **out);
  65 const char *cdecl__token_name(unsigned token);
  66 }
  67
  68 %union {
  69         uintmax_t uintval;
  70         unsigned spectype;
  71         _Bool boolval;
  72         char *strval;
  73         struct cdecl_declspec *declspec;
  74         struct cdecl_declarator *declarator;
  75         struct cdecl *decl;
  76 }
  77
  78 %{
  79 static void yyerror(YYLTYPE *, yyscan_t, struct cdecl **, const char *);
  80 static void free_decl(struct cdecl *);
  81
  82 static void free_declspec(struct cdecl_declspec *x)
  83 {
  84         struct cdecl_declspec *p;
  85         while (x) {
  86                 p = x->next;
  87                 free(x->ident);
  88                 free(x);
  89                 x = p;
  90         }
  91 }
  92
  93 static void free_declarator(struct cdecl_declarator *x)
  94 {
  95         struct cdecl_declarator *p;
  96
  97         while (x) {
  98                 p = x->child;
  99
 100                 switch (x->type) {
 101                 case CDECL_DECL_NULL:
 102                         break;
 103                 case CDECL_DECL_IDENT:
 104                         free(x->u.ident);
 105                         break;
 106                 case CDECL_DECL_POINTER:
 107                         free_declspec(x->u.pointer.qualifiers);
 108                         break;
 109                 case CDECL_DECL_ARRAY:
 110                         free(x->u.array.vla);
 111                         break;
 112                 case CDECL_DECL_FUNCTION:
 113                         free_decl(x->u.function.parameters);
 114                         break;
 115                 default:
 116                         assert(0);
 117                 }
 118
 119                 free(x);
 120                 x = p;
 121         }
 122 }
 123
 124 static void free_decl(struct cdecl *x)
 125 {
 126         struct cdecl *p;
 127
 128         while (x) {
 129                 p = x->next;
 130
 131                 /* The specifiers may be shared by an entire chain. */
 132                 if (!p || p->specifiers != x->specifiers)
 133                         free_declspec(x->specifiers);
 134
 135                 free_declarator(x->declarators);
 136                 free(x);
 137                 x = p;
 138         }
 139 }
 140
 141 void cdecl__free(struct cdecl *decl)
 142 {
 143         free_decl(decl);
 144 }
 145
 146 /*
 147  * Join two declaration specifier lists into a single list, with "a" being the
 148  * head of the new list.
 149  *
 150  * The list "a" is assumed to be nonempty.
 151  */
 152 static void join_specs(struct cdecl_declspec *a, struct cdecl_declspec *b)
 153 {
 154         while (a->next)
 155                 a = a->next;
 156         a->next = b;
 157 }
 158
 159 /*
 160  * Alter an abstract declarator (type name) to declare an identifier instead,
 161  * used by the English parser rules to reduce "identifier as type" sequences.
 162  */
 163 static struct cdecl *insert_identifier(struct cdecl *decl, char *ident)
 164 {
 165         struct cdecl_declarator *d = decl->declarators;
 166
 167         while (d->child)
 168                 d = d->child;
 169
 170         d->type = CDECL_DECL_IDENT;
 171         d->u.ident = ident;
 172
 173         return decl;
 174 }
 175 %}
 176
 177 %destructor { free($$); }            <strval>
 178 %destructor { free_declspec($$); }   <declspec>
 179 %destructor { free_declarator($$); } <declarator>
 180 %destructor { free_decl($$); }       <decl>
 181
 182 /* Magic tokens */
 183 %token T_LEX_ERROR
 184 %token T_ENGLISH
 185
 186 %token <strval> T_IDENT "identifier"
 187 %token <uintval> T_UINT "integer constant"
 188
 189 %token T_SEMICOLON ";"
 190 %token T_ASTERISK  "*"
 191 %token T_LPAREN    "("
 192 %token T_RPAREN    ")"
 193 %token T_LBRACKET  "["
 194 %token T_RBRACKET  "]"
 195 %token T_COMMA     ","
 196 %token T_ELLIPSIS  "..."
 197
 198 %token <spectype> T_TYPEDEF   "typedef"
 199 %token <spectype> T_EXTERN    "extern"
 200 %token <spectype> T_STATIC    "static"
 201 %token <spectype> T_AUTO      "auto"
 202 %token <spectype> T_REGISTER  "register"
 203
 204 %token <spectype> T_INLINE    "inline"
 205
 206 %token <spectype> T_RESTRICT  "restrict"
 207 %token <spectype> T_VOLATILE  "volatile"
 208 %token <spectype> T_CONST     "const"
 209
 210 %token <spectype> T_VOID      "void"
 211 %token <spectype> T_CHAR      "char"
 212 %token <spectype> T_SHORT     "short"
 213 %token <spectype> T_INT       "int"
 214 %token <spectype> T_LONG      "long"
 215 %token <spectype> T_FLOAT     "float"
 216 %token <spectype> T_DOUBLE    "double"
 217 %token <spectype> T_SIGNED    "signed"
 218 %token <spectype> T_UNSIGNED  "unsigned"
 219 %token <spectype> T_BOOL      "_Bool"
 220 %token <spectype> T_COMPLEX   "_Complex"
 221 %token <spectype> T_IMAGINARY "_Imaginary"
 222
 223 %token <spectype> T_STRUCT    "struct"
 224 %token <spectype> T_UNION     "union"
 225 %token <spectype> T_ENUM      "enum"
 226
 227 /*
 228  * English keywords.
 229  */
 230 %token T_TYPE      "type"
 231 %token T_DECLARE   "declare"
 232 %token T_POINTER   "pointer"
 233 %token T_FUNCTION  "function"
 234 %token T_RETURNING "returning"
 235 %token T_ARRAY     "array"
 236 %token T_TO        "to"
 237 %token T_OF        "of"
 238 %token T_AS        "as"
 239 %token T_VLA       "variable-length"
 240
 241 %type <strval>     vla_ident
 242 %type <boolval>    varargs
 243 %type <spectype>   declspec_simple qualifier_simple
 244 %type <spectype>   typespec_simple typespec_tagged
 245 %type <declspec>   declspec_notype declspec_noid typespec_noid typespec
 246 %type <declspec>   qualifier qualifiers
 247 %type <declspec>   declspecs declspecs_noid
 248 %type <declarator> direct_declarator declarator pointer array parens postfix
 249 %type <declarator> direct_declarator_ish declarator_ish parameter_type_list
 250 %type <decl>       declaration declarators declarator_wrap
 251 %type <decl>       parameter
 252
 253 %type <strval>     english_vla
 254 %type <declspec>   storage_func_specs post_specs
 255 %type <declspec>   type_qual_spec type_qual_specs typedef_name_qual
 256 %type <declarator> english_declarator english_array english_function
 257 %type <declarator> english_parameter_list null_decl
 258 %type <decl>       english english_declaration
 259 %type <decl>       english_parameter
 260
 261 /*
 262  * Harmless shift/reduce conflicts in english_parameter.  See comments below
 263  * for more details.
 264  */
 265 %expect 2
 266
 267 %%
 268
 269 input: T_ENGLISH english {
 270         *out = $2;
 271 } | declaration {
 272         *out = $1;
 273 };
 274
 275 semi: | T_SEMICOLON
 276
 277 declaration: declspecs declarators semi {
 278         $$ = $2;
 279         $$->specifiers = $1;
 280 };
 281
 282 /*
 283  * We support parsing declarations using arbitrary identifiers as type
 284  * specifiers (a la C typedef).  To avoid confusion with identifiers that
 285  * may also be used as declarators, note the following:
 286  *
 287  *  (a) Every valid C declaration must have at least one type specifier, and
 288  *  (b) Valid declarations with typedef names have exactly one type specifier.
 289  *
 290  * So the rule applied when parsing specifiers is: an identifier is a type
 291  * specifier only if we have not yet seen any type specifiers whatsoever
 292  * (within one declaration specifier list).
 293  *
 294  * Treating identifiers as type specifiers by default can lead to strange and
 295  * unexpected parses; libcdecl applies a simplification step to the resulting
 296  * parse tree afterwards.
 297  */
 298 declspecs: declspec_notype declspecs {
 299         $$ = $1;
 300         $$->next = $2;
 301 } | typespec declspecs_noid {
 302         $$ = $1;
 303         $$->next = $2;
 304 }
 305
 306 declspecs_noid: { $$ = NULL; } | declspec_noid declspecs_noid {
 307         $$ = $1;
 308         $$->next = $2;
 309 }
 310
 311 qualifiers: { $$ = NULL; } | qualifiers qualifier {
 312         $$ = $2;
 313         $$->next = $1;
 314 }
 315
 316 declarators: declarator_wrap | declarator_wrap T_COMMA declarators {
 317         $$ = $1;
 318         $$->next = $3;
 319 }
 320
 321 declarator_wrap: declarator {
 322         ALLOC_STRUCT($$, struct cdecl, .declarators = $1);
 323 }
 324
 325 declspec_simple: T_AUTO
 326         | T_TYPEDEF
 327         | T_EXTERN
 328         | T_STATIC
 329         | T_REGISTER
 330         | T_INLINE
 331
 332 typespec_simple: T_VOID
 333         | T_CHAR
 334         | T_SHORT
 335         | T_INT
 336         | T_LONG
 337         | T_FLOAT
 338         | T_DOUBLE
 339         | T_SIGNED
 340         | T_UNSIGNED
 341         | T_BOOL
 342         | T_COMPLEX
 343         | T_IMAGINARY
 344
 345 typespec_tagged: T_STRUCT | T_UNION | T_ENUM
 346
 347 qualifier_simple: T_CONST
 348         | T_RESTRICT
 349         | T_VOLATILE
 350
 351 declspec_notype: qualifier | declspec_simple {
 352         ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
 353 }
 354
 355 typespec_noid: typespec_simple {
 356         ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
 357 }
 358
 359 qualifier: qualifier_simple {
 360         ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
 361 }
 362
 363 typespec: typespec_noid | typespec_tagged T_IDENT {
 364         ALLOC_STRUCT($$, struct cdecl_declspec,
 365                 .type  = $1,
 366                 .ident = $2);
 367 } | T_IDENT {
 368         ALLOC_STRUCT($$, struct cdecl_declspec,
 369                 .type = CDECL_TYPE_IDENT,
 370                 .ident = $1);
 371 }
 372
 373 declspec_noid: declspec_notype | typespec_noid
 374
 375 vla_ident: T_IDENT | T_ASTERISK {
 376         ALLOC($$, sizeof "");
 377         strcpy($$, "");
 378 }
 379
 380 array: T_LBRACKET T_UINT T_RBRACKET {
 381         if ($2 == 0)
 382                 FAIL(_("array length must be positive"));
 383
 384         ALLOC_STRUCT($$, struct cdecl_declarator,
 385                 .type = CDECL_DECL_ARRAY,
 386                 .u.array.length = $2);
 387 } | T_LBRACKET vla_ident T_RBRACKET {
 388         ALLOC_STRUCT($$, struct cdecl_declarator,
 389                 .type = CDECL_DECL_ARRAY,
 390                 .u.array.vla = $2);
 391 } | T_LBRACKET T_RBRACKET {
 392         ALLOC_STRUCT($$, struct cdecl_declarator,
 393                 .type = CDECL_DECL_ARRAY);
 394 }
 395
 396 parameter: declspecs declarator {
 397         ALLOC_STRUCT($$, struct cdecl,
 398                 .specifiers = $1,
 399                 .declarators = $2);
 400 }
 401
 402 varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }
 403
 404 parameter_type_list: parameter varargs {
 405         ALLOC_STRUCT($$, struct cdecl_declarator,
 406                 .type = CDECL_DECL_FUNCTION,
 407                 .u.function.parameters = $1,
 408                 .u.function.variadic = $2);
 409 } | parameter T_COMMA parameter_type_list {
 410         $$ = $3;
 411         $1->next = $$->u.function.parameters;
 412         $$->u.function.parameters = $1;
 413 }
 414
 415 parens: T_LPAREN parameter_type_list T_RPAREN {
 416         $$ = $2;
 417 } | T_LPAREN declarator_ish T_RPAREN {
 418         ALLOC_STRUCT($$, struct cdecl_declarator,
 419                 .type = CDECL_DECL_FUNCTION);
 420         ALLOC_STRUCT($$->u.function.parameters, struct cdecl,
 421                 .declarators = $2);
 422 }
 423
 424 pointer: T_ASTERISK qualifiers direct_declarator {
 425         ALLOC_STRUCT($$, struct cdecl_declarator,
 426                 .type = CDECL_DECL_POINTER,
 427                 .u.pointer.qualifiers = $2,
 428                 .child = $3);
 429 } | T_ASTERISK qualifiers pointer {
 430         ALLOC_STRUCT($$, struct cdecl_declarator,
 431                 .type = CDECL_DECL_POINTER,
 432                 .u.pointer.qualifiers = $2,
 433                 .child = $3);
 434 }
 435
 436 declarator: direct_declarator | pointer
 437 declarator_ish: direct_declarator_ish | pointer
 438 postfix: array | parens
 439
 440 direct_declarator_ish: {
 441         ALLOC_STRUCT($$, struct cdecl_declarator,
 442                 .type = CDECL_DECL_NULL);
 443 } | direct_declarator_ish postfix {
 444         $$ = $2;
 445         $$->child = $1;
 446 }
 447
 448 direct_declarator: {
 449         ALLOC_STRUCT($$, struct cdecl_declarator,
 450                 .type = CDECL_DECL_NULL);
 451 } | T_IDENT {
 452         ALLOC_STRUCT($$, struct cdecl_declarator,
 453                 .type = CDECL_DECL_IDENT,
 454                 .u.ident = $1);
 455 } | direct_declarator postfix {
 456         $$ = $2;
 457         $$->child = $1;
 458 }
 459
 460 english: T_DECLARE T_IDENT T_AS english_declaration {
 461         $$ = insert_identifier($4, $2);
 462 } | T_TYPE english_declaration {
 463         $$ = $2;
 464 }
 465
 466 storage_func_specs: { $$ = NULL; } | declspec_simple storage_func_specs {
 467         ALLOC_STRUCT($$, struct cdecl_declspec,
 468                 .type = $1,
 469                 .next = $2);
 470 }
 471
 472 type_qual_spec: typespec_noid | qualifier
 473
 474 type_qual_specs: { $$ = NULL; } | type_qual_spec type_qual_specs {
 475         $$ = $1;
 476         $$->next = $2;
 477 }
 478
 479 /*
 480  * The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
 481  * conflicts with pointer declarators.  So we end up needing to stitch
 482  * together three different specifiers lists.
 483  */
 484 post_specs: qualifiers typespec type_qual_specs {
 485         $2->next = $3;
 486         join_specs($2, $1);
 487         $$ = $2;
 488 }
 489
 490 english_declaration: storage_func_specs english_declarator post_specs {
 491         join_specs($3, $1);
 492         ALLOC_STRUCT($$, struct cdecl,
 493                 .specifiers = $3,
 494                 .declarators = $2);
 495 }
 496
 497 english_declarator: {
 498         ALLOC_STRUCT($$, struct cdecl_declarator,
 499                 .type = CDECL_DECL_NULL);
 500 } | english_declarator qualifiers T_POINTER T_TO {
 501         ALLOC_STRUCT($$, struct cdecl_declarator,
 502                 .type = CDECL_DECL_POINTER,
 503                 .child = $1,
 504                 .u.pointer.qualifiers = $2);
 505 } | english_declarator english_array {
 506         $$ = $2;
 507         $$->child = $1;
 508 } | english_declarator english_function {
 509         $$ = $2;
 510         $$->child = $1;
 511 }
 512
 513 english_function: T_FUNCTION T_RETURNING {
 514         ALLOC_STRUCT($$, struct cdecl_declarator,
 515                 .type = CDECL_DECL_FUNCTION,
 516                 .u.function.parameters = NULL);
 517 } | T_FUNCTION T_LPAREN english_parameter_list T_RPAREN T_RETURNING {
 518         $$ = $3;
 519 }
 520
 521 english_parameter_list: english_parameter varargs {
 522         ALLOC_STRUCT($$, struct cdecl_declarator,
 523                 .type = CDECL_DECL_FUNCTION,
 524                 .u.function.parameters = $1,
 525                 .u.function.variadic = $2);
 526 } | english_parameter T_COMMA english_parameter_list {
 527         $$ = $3;
 528         $1->next = $$->u.function.parameters;
 529         $$->u.function.parameters = $1;
 530 }
 531
 532 typedef_name_qual: T_IDENT qualifiers {
 533         ALLOC_STRUCT($$, struct cdecl_declspec,
 534                 .type = CDECL_TYPE_IDENT,
 535                 .ident = $1,
 536                 .next = $2);
 537 }
 538
 539 null_decl: {
 540         ALLOC_STRUCT($$, struct cdecl_declarator,
 541                 .type = CDECL_DECL_NULL);
 542 }
 543
 544 /*
 545  * There is a small shift/reduce conflict here.  An unadorned identifier
 546  * as the first thing in the parameter might be a typedef name deep in the
 547  * first english_declaration (thus empty storage_func_specs and empty
 548  * english_declarator need to be reduced) or it might be the identifier
 549  * before the "as" (thus the identifier should be shifted).
 550  *
 551  * The typedef name conflict is the only issue, so treating it as a special
 552  * case makes the shift harmless.
 553  */
 554 english_parameter: english_declaration | typedef_name_qual null_decl {
 555         ALLOC_STRUCT($$, struct cdecl,
 556                 .specifiers = $1,
 557                 .declarators = $2);
 558 } | T_IDENT T_AS english_declaration {
 559         $$ = insert_identifier($3, $1);
 560 }
 561
 562 english_array: T_VLA T_ARRAY english_vla T_OF {
 563         ALLOC_STRUCT($$, struct cdecl_declarator,
 564                 .type = CDECL_DECL_ARRAY,
 565                 .u.array.vla = $3);
 566 } | T_ARRAY T_UINT T_OF {
 567         if ($2 == 0)
 568                 FAIL(_("array length must be positive"));
 569
 570         ALLOC_STRUCT($$, struct cdecl_declarator,
 571                 .type = CDECL_DECL_ARRAY,
 572                 .u.array.length = $2);
 573 } | T_ARRAY T_OF {
 574         ALLOC_STRUCT($$, struct cdecl_declarator,
 575                 .type = CDECL_DECL_ARRAY,
 576                 .u.array.length = 0);
 577 }
 578
 579 english_vla: T_IDENT | {
 580         ALLOC($$, sizeof "");
 581         strcpy($$, "");
 582 }
 583
 584 %%
 585
 586 /*
 587  * Expose the token string table to the rest of the library, in order to
 588  * produce strings that match parser keywords.
 589  *
 590  * In order for this to work properly, the Bison output must be postprocessed
 591  * by fix-yytname.awk to remove pointless quotation marks from the keyword
 592  * strings.
 593  */
 594 const char *cdecl__token_name(unsigned token)
 595 {
 596         return yytname[YYTRANSLATE(token)];
 597 }
 598
 599 static void
 600 yyerror(YYLTYPE *loc, yyscan_t scanner, struct cdecl **out, const char *err)
 601 {
 602         if (strstr(err, yytname[YYTRANSLATE(T_LEX_ERROR)]))
 603                 return;
 604
 605         cdecl__err(CDECL_ENOPARSE, "%s", err);
 606 }