configure.ac

   1 dnl Copyright © 2011-2012 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AC_PREREQ([2.68])
   8 AC_INIT([cdecl99], [0.1], [nbowler@draconx.ca])
   9 AC_CONFIG_HEADER([config.h])
  10
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12 AM_SILENT_RULES([yes])
  13
  14 AC_PROG_CC_C99
  15 AM_PROG_CC_C_O
  16 gl_EARLY
  17
  18 LT_INIT
  19 gl_INIT
  20
  21 m4_include([lib/gnulib.mk])
  22 DX_GLSYM_PREFIX([cdecl__])
  23
  24 dnl We provide our own makefile rules for gettext.  Disable tracing of
  25 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  26 dnl prevent automake from growing gratuitous error conditions.
  27 m4_traceoff([AM_GNU_GETTEXT])
  28 AM_GNU_GETTEXT([external])
  29 DX_LINGUAS
  30
  31 AC_ARG_VAR([FLEX], [Command to invoke flex.  Defaults to flex.])
  32 AC_ARG_VAR([FLEXFLAGS], [Additional options to pass to flex.])
  33 AC_CHECK_PROGS([FLEX], [flex], [flex])
  34
  35 AC_ARG_VAR([BISON], [Command to invoke GNU Bison.  Defaults to bison.])
  36 AC_ARG_VAR([BISONFLAGS], [Additional options to pass to Bison.])
  37 AC_CHECK_PROGS([BISON], [bison], [bison])
  38 BISON_I18N
  39
  40 GLOBAL_SYMBOL_PIPE=$lt_cv_sys_global_symbol_pipe
  41 AC_SUBST([GLOBAL_SYMBOL_PIPE])
  42
  43 AH_TOP([#include <conf_pre.h>])
  44 AH_BOTTOM([#include <conf_post.h>])
  45
  46 AC_ARG_WITH([gsl],
  47         [AS_HELP_STRING([--with-gsl],
  48                 [specify whether to build test programs requiring the GNU Scientific Library. [default=auto]]
  49         )], [with_gsl=$withval], [with_gsl=auto])
  50
  51 AS_CASE([$with_gsl],
  52         [no], [have_gsl=no],
  53         [yes], [DX_CHECK_GSL([1.0], [have_gsl=yes])],
  54         [DX_CHECK_GSL([1.0], [have_gsl=yes], [have_gsl=no])])
  55 AM_CONDITIONAL([HAVE_GSL], [test x"$have_gsl" = x"yes"])
  56
  57 AC_CONFIG_FILES([
  58         exported.sh
  59         Makefile
  60 ])
  61 AC_OUTPUT