configure.ac

   1 dnl Copyright © 2011 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AC_PREREQ([2.68])
   8 AC_INIT([cdecl99], [0.1], [nbowler@draconx.ca])
   9 AC_CONFIG_HEADER([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  13 AM_SILENT_RULES([yes])
  14
  15 AC_PROG_CC_C99
  16 gl_EARLY
  17
  18 LT_INIT
  19 gl_INIT
  20
  21 DX_FIX_GNULIB([cdecl__])
  22
  23 dnl We provide our own makefile rules for gettext.  Disable tracing of
  24 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  25 dnl prevent automake from growing gratuitous error conditions.
  26 m4_traceoff([AM_GNU_GETTEXT])
  27 AM_GNU_GETTEXT([external])
  28 DX_LINGUAS
  29
  30 AC_ARG_VAR([FLEX], [Command to invoke flex.  Defaults to flex.])
  31 AC_ARG_VAR([FLEXFLAGS], [Additional options to pass to flex.])
  32 AC_CHECK_PROGS([FLEX], [flex], [flex])
  33
  34 AC_ARG_VAR([BISON], [Command to invoke GNU Bison.  Defaults to bison.])
  35 AC_ARG_VAR([BISONFLAGS], [Additional options to pass to Bison.])
  36 AC_CHECK_PROGS([BISON], [bison], [bison])
  37 BISON_I18N
  38
  39 GLOBAL_SYMBOL_PIPE=$lt_cv_sys_global_symbol_pipe
  40 AC_SUBST([GLOBAL_SYMBOL_PIPE])
  41
  42 AH_BOTTOM([#include <cfgtail.h>])
  43
  44 AC_CONFIG_FILES([
  45         exported.sh
  46         Makefile
  47 ])
  48 AC_OUTPUT