configure.ac

   1 dnl Copyright © 2011 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AC_PREREQ([2.68])
   8 AC_INIT([cdecl99], [0.1], [nbowler@draconx.ca])
   9 AC_CONFIG_HEADER([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  13 AM_SILENT_RULES([yes])
  14
  15 AC_PROG_CC_C99
  16 AM_PROG_CC_C_O
  17 gl_EARLY
  18
  19 LT_INIT
  20 gl_INIT
  21
  22 m4_include([lib/gnulib.mk])
  23 DX_GLSYM_PREFIX([cdecl__])
  24
  25 dnl We provide our own makefile rules for gettext.  Disable tracing of
  26 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  27 dnl prevent automake from growing gratuitous error conditions.
  28 m4_traceoff([AM_GNU_GETTEXT])
  29 AM_GNU_GETTEXT([external])
  30 DX_LINGUAS
  31
  32 AC_ARG_VAR([FLEX], [Command to invoke flex.  Defaults to flex.])
  33 AC_ARG_VAR([FLEXFLAGS], [Additional options to pass to flex.])
  34 AC_CHECK_PROGS([FLEX], [flex], [flex])
  35
  36 AC_ARG_VAR([BISON], [Command to invoke GNU Bison.  Defaults to bison.])
  37 AC_ARG_VAR([BISONFLAGS], [Additional options to pass to Bison.])
  38 AC_CHECK_PROGS([BISON], [bison], [bison])
  39 BISON_I18N
  40
  41 GLOBAL_SYMBOL_PIPE=$lt_cv_sys_global_symbol_pipe
  42 AC_SUBST([GLOBAL_SYMBOL_PIPE])
  43
  44 AH_TOP([#include <conf_pre.h>])
  45 AH_BOTTOM([#include <conf_post.h>])
  46
  47 AC_ARG_WITH([gsl],
  48         [AS_HELP_STRING([--with-gsl],
  49                 [specify whether to build test programs requiring the GNU Scientific Library. [default=auto]]
  50         )], [with_gsl=$withval], [with_gsl=auto])
  51
  52 AS_CASE([$with_gsl],
  53         [no], [have_gsl=no],
  54         [yes], [DX_CHECK_GSL([1.0], [have_gsl=yes])],
  55         [DX_CHECK_GSL([1.0], [have_gsl=yes], [have_gsl=no])])
  56 AM_CONDITIONAL([HAVE_GSL], [test x"$have_gsl" = x"yes"])
  57
  58 AC_CONFIG_FILES([
  59         exported.sh
  60         Makefile
  61 ])
  62 AC_OUTPUT