configure.ac

   1 dnl Copyright © 2011-2013, 2020-2022 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AC_PREREQ([2.68])
   8 AC_INIT([cdecl99], [1.1a], [nbowler@draconx.ca])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects dist-xz])
  12 AM_SILENT_RULES([yes])
  13 DX_AUTOMAKE_COMPAT
  14
  15 AC_ARG_WITH([readline],
  16   [AS_HELP_STRING([--with-readline],
  17     [use GNU readline for line-editing functionality (default: auto)])],
  18   [], [with_readline=auto])
  19 AS_CASE([$with_readline],
  20   [no], [gl_cv_lib_readline=no],
  21   [yes|auto], [:],
  22   [*], [AC_MSG_ERROR([invalid option --with-readline=$with_readline])])
  23
  24 AC_PROG_CC_C99
  25 AM_PROG_CC_C_O
  26 gl_EARLY
  27
  28 LT_INIT
  29 gl_INIT
  30
  31 AS_IF([test x"$gl_cv_lib_readline" = x"no"],
  32   [AS_IF([test x"$with_readline" = x"yes"],
  33     [AC_MSG_FAILURE([--with-readline requested but readline was not found])],
  34     [dx_cv_rl_add_history=no])])
  35 AC_CACHE_CHECK([if readline supports add_history], [dx_cv_rl_add_history], [dnl
  36 dx_cv_rl_add_history=no
  37 dx_save_libs=$LIBS
  38 LIBS="$LIBS $LIBREADLINE"
  39 AC_LINK_IFELSE([AC_LANG_PROGRAM([dnl
  40 #include <stdio.h>
  41 #if HAVE_READLINE_HISTORY_H
  42 #  include <readline/history.h>
  43 #endif
  44 ], [dnl
  45 (*add_history)("");
  46 ])], [dx_cv_rl_add_history=yes], [dx_cv_rl_add_history=no])
  47 LIBS=$dx_save_libs
  48 ])
  49
  50 AS_IF([test x"$dx_cv_rl_add_history" = x"yes"],
  51   [AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
  52     [Define to 1 if readline supports add_history.])])
  53
  54 m4_include([lib/gnulib.mk])
  55 DX_GLSYM_PREFIX([cdecl__gl_])
  56 DX_GNULIB_SYMFILES([lib/symfiles])
  57 AM_CONDITIONAL([BUILD_STATIC], [test x"$enable_static" = x"yes"])
  58
  59 dnl We provide our own makefile rules for gettext.  Disable tracing of
  60 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  61 dnl prevent automake from growing gratuitous error conditions.
  62 m4_traceoff([AM_GNU_GETTEXT])
  63 AM_GNU_GETTEXT([external])
  64 DX_LINGUAS
  65
  66 AM_CONDITIONAL([USE_NLS], [test x"$USE_NLS" = x"yes"])
  67
  68 DX_PROG_FLEX([], [have_flex=yes], [have_flex=no])
  69 AM_CONDITIONAL([HAVE_FLEX], [test x"$have_flex" = x"yes"])
  70
  71 DX_PROG_BISON([], [have_bison=yes], [have_bison=no])
  72 AM_CONDITIONAL([HAVE_BISON], [test x"$have_bison" = x"yes"])
  73
  74 DX_BISON_COMPAT
  75 BISON_I18N
  76
  77 BISON_COMPAT=
  78 AS_IF([test x"$dx_cv_bison_api_header_include" = x"yes"],
  79   [BISON_COMPAT="'--define=api.header.include={\"\$(*F).h\"}'"])
  80 AS_IF([test x"$dx_cv_bison_warn_no_deprecated" = x"yes"],
  81   [AS_VAR_APPEND([BISON_COMPAT], ["${BISON_COMPAT:+ }-Wno-deprecated"])])
  82 AC_SUBST([BISON_COMPAT])
  83
  84 AH_TOP([#include <conf_pre.h>])
  85 AH_BOTTOM([#include <conf_post.h>])
  86
  87 AC_CONFIG_TESTDIR([.], [test:.])
  88 DX_PROG_AUTOTEST
  89 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  90 AC_CHECK_FUNCS_ONCE([strtoull __strtoull])
  91
  92 AC_CONFIG_FILES([
  93         Makefile
  94 ])
  95 AC_OUTPUT