testsuite.at

   1 AT_COPYRIGHT([Copyright © 2020-2021, 2023 Nick Bowler])
   2 #
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  15
  16 AT_INIT
  17 AT_COLOR_TESTS
  18
  19 m4_include([common/snippet/test-tap.at])
  20
  21 AT_TESTED([cdecl99])
  22
  23 AT_ARG_OPTION_ARG([random-seed],
  24   [AS_HELP_STRING([--random-seed=ARG],
  25     [Integer seed for randomized testing (default: auto)])],
  26   [random_seed=$at_optarg], [random_seed=$RANDOM$$])
  27
  28 AT_ARG_OPTION_ARG([random-iterations],
  29   [AS_HELP_STRING([--random-iterations=N],
  30     [Number of randomized testcases to perform (default: 500)])],
  31   [random_iter=$at_optarg], [random_iter=])
  32
  33 m4_define([RE_LOWER], [abcdefghijklmnopqrstuvwxyz])
  34 m4_define([RE_UPPER], m4_toupper(m4_defn([RE_LOWER])))
  35 m4_define([RE_ALPHA], m4_defn([RE_UPPER])m4_defn([RE_LOWER]))
  36 m4_define([RE_ALNUM], m4_defn([RE_ALPHA])[0-9])
  37
  38 m4_divert_push([PREPARE_TESTS])dnl
  39 : ${LIBTOOL="$SHELL $builddir/libtool"}
  40 random_seed=`printf '%s' "$random_seed" | tr -cd '0123456789'`
  41 random_seed=${random_seed:-0}
  42 random_iter=`printf '%s' "$random_iter" | tr -cd '0123456789'`
  43 random_iter=`expr "$random_iter" '|' 500`
  44 m4_divert_pop([PREPARE_TESTS])
  45
  46 m4_define([TEST_NEED_PROGRAM], [AT_KEYWORDS([$1])dnl
  47 AT_CHECK([for arg in $check_PROGRAMS; do
  48 test x"${arg##*/}" != x"$1$EXEEXT" || exit 0
  49 done
  50 exit 77])])
  51
  52 m4_include([tests/general.at])
  53 m4_include([tests/decl-good.at])
  54 m4_include([tests/decl-bad.at])
  55 m4_include([tests/internal.at])
  56 m4_include([tests/stress.at])