configure.ac

   1 dnl Copyright © 2011-2013, 2020-2024 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 DX_PATCH_GNULIB
   8
   9 AC_PREREQ([2.68])
  10 AC_INIT([cdecl99], [1.2a], [nbowler@draconx.ca])
  11 AC_CONFIG_HEADERS([config.h])
  12
  13 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects dist-xz])
  14 AM_SILENT_RULES([yes])
  15 DX_AUTOMAKE_COMPAT
  16
  17 AC_ARG_WITH([readline],
  18   [AS_HELP_STRING([--with-readline],
  19     [use GNU readline for line-editing functionality (default: auto)])],
  20   [], [with_readline=auto])
  21 AS_CASE([$with_readline],
  22   [no], [gl_cv_lib_readline=no],
  23   [yes|auto], [:],
  24   [*], [AC_MSG_ERROR([invalid option --with-readline=$with_readline])])
  25
  26 AC_PROG_CC_C99
  27 AM_PROG_CC_C_O
  28 gl_EARLY
  29
  30 AC_HEADER_ASSERT
  31 AC_TYPE_UNSIGNED_LONG_LONG_INT
  32 AC_CHECK_TYPES([unsigned __int64])
  33 AC_C_FLEXIBLE_ARRAY_MEMBER
  34 AC_C_INLINE
  35 DX_C_FOR_DECLARATIONS
  36 AM_PROG_AR
  37
  38 LT_INIT
  39 gl_INIT
  40
  41 # As the mbrtowc replacement module is not used by the library, there is
  42 # no need for multithreaded mbrtowc (all programs are single threaded).
  43 AC_DEFINE([GNULIB_MBRTOWC_SINGLE_THREAD], [1], [Define to 1.])
  44
  45 # As the wcwidth replacement module is not used by the library, there is
  46 # no need to support varying locales (programs set locale once at startup).
  47 AC_DEFINE([GNULIB_WCHAR_SINGLE_LOCALE], [1], [Define to 1.])
  48
  49 AS_IF([test x"$gl_cv_lib_readline" = x"no"],
  50   [AS_IF([test x"$with_readline" = x"yes"],
  51     [AC_MSG_FAILURE([--with-readline requested but readline was not found])],
  52     [dx_cv_rl_add_history=no])])
  53 AC_CACHE_CHECK([if readline supports add_history], [dx_cv_rl_add_history], [dnl
  54 dx_cv_rl_add_history=no
  55 dx_save_libs=$LIBS
  56 LIBS="$LIBS $LIBREADLINE"
  57 AC_LINK_IFELSE([AC_LANG_PROGRAM([dnl
  58 #include <stdio.h>
  59 #if HAVE_READLINE_HISTORY_H
  60 #  include <readline/history.h>
  61 #endif
  62 ], [dnl
  63 (*add_history)("");
  64 ])], [dx_cv_rl_add_history=yes], [dx_cv_rl_add_history=no])
  65 LIBS=$dx_save_libs
  66 ])
  67
  68 AS_IF([test x"$dx_cv_rl_add_history" = x"yes"],
  69   [AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
  70     [Define to 1 if readline supports add_history.])])
  71
  72 m4_include([lib/gnulib.mk])
  73 DX_GLSYM_PREFIX([cdecl__gl_])
  74 DX_GNULIB_SYMFILES([lib/symfiles], [s])
  75 AM_CONDITIONAL([BUILD_STATIC], [test x"$enable_static" = x"yes"])
  76
  77 AM_CONDITIONAL([USE_NLS], [test x"$USE_NLS" = x"yes"])
  78
  79 DX_PROG_FLEX([], [have_flex=yes], [have_flex=no])
  80 AM_CONDITIONAL([HAVE_FLEX], [test x"$have_flex" = x"yes"])
  81
  82 DX_PROG_BISON([], [have_bison=yes], [have_bison=no])
  83 AM_CONDITIONAL([HAVE_BISON], [test x"$have_bison" = x"yes"])
  84
  85 DX_BISON_COMPAT
  86 BISON_I18N
  87
  88 BISON_COMPAT=
  89 AS_IF([test x"$dx_cv_bison_api_header_include" = x"yes"],
  90   [BISON_COMPAT="'--define=api.header.include={\"\$(*F).h\"}'"])
  91 AS_IF([test x"$dx_cv_bison_warn_no_deprecated" = x"yes"],
  92   [AS_VAR_APPEND([BISON_COMPAT], ["${BISON_COMPAT:+ }-Wno-deprecated"])])
  93 AC_SUBST([BISON_COMPAT])
  94
  95 AS_CASE([$dx_cv_bison_define_cmdline], [yes],
  96 [AC_CACHE_CHECK([whether $BISON supports api.token.raw],
  97   [dx_cv_bison_api_token_raw], [dx_cv_bison_api_token_raw=no
  98 cat >conftest.y <<'EOF'
  99 %token T_TEST
 100 %{
 101 int yylex(void) { return 0; }
 102 void yyerror(const char *msg) { }
 103 %}
 104 %%
 105 input:
 106 EOF
 107 AS_IF([$BISON --define api.token.raw conftest.y >&AS_MESSAGE_LOG_FD 2>&1],
 108 [AC_COMPUTE_INT([testval], [T_TEST], [#include "conftest.tab.c"
 109 ])
 110 AS_IF([test "$testval" -lt 256], [dx_cv_bison_api_token_raw=yes])])])
 111 AS_CASE([$dx_cv_bison_api_token_raw], [yes],
 112   [AS_VAR_APPEND([BISON_COMPAT], [" --define api.token.raw"])])])
 113
 114 AH_TOP([#include <conf_pre.h>])
 115 AH_BOTTOM([#include <conf_post.h>])
 116
 117 AC_CONFIG_TESTDIR([.], [t:.])
 118 DX_PROG_AUTOTEST_AM
 119
 120 AC_CACHE_CHECK([for getline], [dx_cv_have_getline],
 121   [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>
 122 ], [ssize_t (*x)() = getline;
 123 char *p = 0;
 124 size_t n = 0;
 125 return getline(&p, &n, stdin);
 126 ])], [dx_cv_have_getline=yes], [dx_cv_have_getline=no])])
 127 AS_CASE([$dx_cv_have_getline], [yes],
 128   [AC_DEFINE([HAVE_GETLINE], [1],
 129     [Define to 1 if the getline function is available.])])
 130
 131 AC_CONFIG_FILES([Makefile])
 132 AC_OUTPUT