src/parse.y

   1 %code top {
   2 /*
   3  *  Parser for C declarations.
   4  *  Copyright © 2011-2012, 2021, 2023-2024 Nick Bowler
   5  *
   6  *  This program is free software: you can redistribute it and/or modify
   7  *  it under the terms of the GNU General Public License as published by
   8  *  the Free Software Foundation, either version 3 of the License, or
   9  *  (at your option) any later version.
  10  *
  11  *  This program is distributed in the hope that it will be useful,
  12  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *  GNU General Public License for more details.
  15  *
  16  *  You should have received a copy of the GNU General Public License
  17  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18  */
  19 }
  20
  21 %name-prefix "cdecl__yy"
  22 %parse-param {void *scanner}
  23 %parse-param {struct cdecl **out}
  24 %lex-param {yyscan_t scanner}
  25 %define api.pure
  26 %error-verbose
  27 %locations
  28
  29 %{
  30 #include <config.h>
  31 #include <assert.h>
  32 #include <stdbool.h>
  33
  34 #include "scan.h"
  35 #include "cdecl.h"
  36 #include "cdecl-internal.h"
  37 #include "errmsg.h"
  38
  39 /*
  40  * Allocate a parse tree node via cdecl__alloc_item.
  41  *
  42  * - m1 specifies the item's union member to assign to ptr, which selects the
  43  *   type of node to allocate.
  44  *
  45  * - m2 specifies the "next" or "child" member, which is initialized to a null
  46  *   pointer.  The cdecl__alloc_item function sets the declarator.child member
  47  *   to null; we explicitly copy this null pointer to the returned union member
  48  *   to avoid type punning.  It is hoped that compilers will notice that these
  49  *   pointers are at the same offset therefore the assignment can be elided.
  50  *
  51  * The resulting pointer can be passed directly to free, as the union is the
  52  * first member of the parse_item structure.
  53  *
  54  * Use the wrapper macros below instead of this one.
  55  */
  56 #define ALLOC_ITEM(ptr, m1, m2) do { \
  57         struct parse_item *item; \
  58         if (!(item = cdecl__alloc_item(0))) \
  59                 YYERROR; \
  60         item->u.m1.m2 = (void *)item->u.declarator.child; \
  61         (ptr) = &item->u.m1; \
  62 } while (0)
  63
  64 /* Wrappers for ALLOC_ITEM to allocate various kinds of parser structures. */
  65 #define ALLOC_ITEM_DECLARATOR(ptr) ALLOC_ITEM(ptr, declarator, child)
  66 #define ALLOC_ITEM_DECLSPEC(ptr)   ALLOC_ITEM(ptr, declspec, next)
  67 #define ALLOC_ITEM_DECL(ptr)       ALLOC_ITEM(ptr, decl, next)
  68
  69 #define ALLOC_FUNCTION(ptr, parameters_, variadic_) do { \
  70         ALLOC_ITEM_DECLARATOR(ptr); \
  71         (ptr)->type = CDECL_DECL_FUNCTION; \
  72         (ptr)->u.function.parameters = parameters_; \
  73         (ptr)->u.function.variadic = variadic_; \
  74 } while (0)
  75
  76 #define ALLOC_ARRAY(ptr, length_) do { \
  77         ALLOC_ITEM_DECLARATOR(ptr); \
  78         (ptr)->type = CDECL_DECL_ARRAY; \
  79         (ptr)->u.array.vla = NULL; \
  80         (ptr)->u.array.length = length_; \
  81 } while (0)
  82
  83 #define ALLOC_POINTER(ptr, qualifiers_, child_) do { \
  84         ALLOC_ITEM_DECLARATOR(ptr); \
  85         (ptr)->child = child_; \
  86         (ptr)->type = CDECL_DECL_POINTER; \
  87         (ptr)->u.pointer.qualifiers = qualifiers_; \
  88 } while (0)
  89
  90 #define ALLOC_DECLSPEC(ptr, type_) do { \
  91         ALLOC_ITEM_DECLSPEC(ptr); \
  92         (ptr)->type = type_; \
  93         (ptr)->ident = NULL; \
  94 } while (0)
  95
  96 #define ALLOC_DECL(ptr, specifiers_, declarators_) do { \
  97         ALLOC_ITEM_DECL(ptr); \
  98         (ptr)->specifiers = specifiers_; \
  99         (ptr)->declarators = declarators_; \
 100 } while (0)
 101
 102 /*
 103  * With the postprocessing performed by fix-yytname.awk, all the symbol
 104  * name strings can be used directly in error messages and there is no
 105  * need for any string processing.
 106  */
 107 #define yytnamerr(a, b) ( (a) ? yytnamerr_copy(a, b) \
 108                               : strlen(b) )
 109
 110 static size_t yytnamerr_copy(char *dst, const char *src)
 111 {
 112         return cdecl__strlcpy(dst, src, strlen(src)+1);
 113 }
 114 %}
 115
 116 %code requires {
 117 #include <inttypes.h>
 118 #include <stdbool.h>
 119 }
 120
 121 %code provides {
 122 void cdecl__free(struct cdecl *);
 123 int cdecl__yyparse(void *scanner, struct cdecl **out);
 124 const char *cdecl__token_name(unsigned token);
 125 }
 126
 127 %union {
 128         uintmax_t uintval;
 129         unsigned spectype;
 130         bool boolval;
 131         struct cdecl_declspec *declspec;
 132         struct cdecl_declarator *declarator;
 133         struct cdecl *decl;
 134         struct parse_item *item;
 135 }
 136
 137 %{
 138 static void yyerror(YYLTYPE *, yyscan_t, struct cdecl **, const char *);
 139 static void free_decl(struct cdecl *);
 140
 141 static void free_declspec(struct cdecl_declspec *x)
 142 {
 143         struct cdecl_declspec *p;
 144         while (x) {
 145                 p = x->next;
 146                 free(x);
 147                 x = p;
 148         }
 149 }
 150
 151 static void free_declarator(struct cdecl_declarator *x)
 152 {
 153         struct cdecl_declarator *p;
 154
 155         while (x) {
 156                 p = x->child;
 157
 158                 switch (x->type) {
 159                 case CDECL_DECL_NULL:
 160                         x = NULL;
 161                 case CDECL_DECL_IDENT:
 162                 case CDECL_DECL_ARRAY:
 163                         break;
 164                 case CDECL_DECL_POINTER:
 165                         free_declspec(x->u.pointer.qualifiers);
 166                         break;
 167                 case CDECL_DECL_FUNCTION:
 168                         free_decl(x->u.function.parameters);
 169                         break;
 170                 default:
 171                         assert(0);
 172                 }
 173
 174                 free(x);
 175                 x = p;
 176         }
 177 }
 178
 179 static void free_decl(struct cdecl *x)
 180 {
 181         struct cdecl *p;
 182
 183         while (x) {
 184                 p = x->next;
 185
 186                 /* The specifiers may be shared by an entire chain. */
 187                 if (!p || p->specifiers != x->specifiers)
 188                         free_declspec(x->specifiers);
 189
 190                 free_declarator(x->declarators);
 191                 free(x);
 192                 x = p;
 193         }
 194 }
 195
 196 void cdecl__free(struct cdecl *decl)
 197 {
 198         free_decl(decl);
 199 }
 200
 201 /*
 202  * Join two declaration specifier lists into a single list, with "a" being the
 203  * head of the new list.
 204  *
 205  * The list "a" is assumed to be nonempty.
 206  */
 207 static void join_specs(struct cdecl_declspec *a, struct cdecl_declspec *b)
 208 {
 209         while (a->next)
 210                 a = a->next;
 211         a->next = b;
 212 }
 213
 214 /*
 215  * Alter an abstract declarator (type name) to declare an identifier instead,
 216  * used by the English parser rules to reduce "identifier as type" sequences.
 217  */
 218 static struct cdecl *insert_identifier(struct cdecl *decl, struct parse_item *ident)
 219 {
 220         struct cdecl_declarator *d, **p = &decl->declarators;
 221
 222         while ((d = *p)->child)
 223                 p = &d->child;
 224
 225         *p = &ident->u.declarator;
 226         return decl;
 227 }
 228
 229 static struct cdecl_declarator *nulldecl(void)
 230 {
 231         static const struct cdecl_declarator nulldecl = {0};
 232         return (void *)&nulldecl;
 233 }
 234 #define NULLDECL (nulldecl())
 235
 236 %}
 237
 238 %destructor { free($$); }            <item>
 239 %destructor { free_declspec($$); }   <declspec>
 240 %destructor { free_declarator($$); } <declarator>
 241 %destructor { free_decl($$); }       <decl>
 242
 243 /* Magic tokens */
 244 %token T_LEX_ERROR
 245
 246 %token <item>    T_IDENT "identifier"
 247 %token <uintval> T_UINT  "integer constant"
 248
 249 %token T_SEMICOLON ";"
 250 %token T_ASTERISK  "*"
 251 %token T_LPAREN    "("
 252 %token T_RPAREN    ")"
 253 %token T_LBRACKET  "["
 254 %token T_RBRACKET  "]"
 255 %token T_COMMA     ","
 256 %token T_ELLIPSIS  "..."
 257
 258 %token <spectype> T_TYPEDEF   "typedef"
 259 %token <spectype> T_EXTERN    "extern"
 260 %token <spectype> T_STATIC    "static"
 261 %token <spectype> T_AUTO      "auto"
 262 %token <spectype> T_REGISTER  "register"
 263
 264 %token <spectype> T_INLINE    "inline"
 265
 266 %token <spectype> T_RESTRICT  "restrict"
 267 %token <spectype> T_VOLATILE  "volatile"
 268 %token <spectype> T_CONST     "const"
 269
 270 %token <spectype> T_VOID      "void"
 271 %token <spectype> T_CHAR      "char"
 272 %token <spectype> T_SHORT     "short"
 273 %token <spectype> T_INT       "int"
 274 %token <spectype> T_LONG      "long"
 275 %token <spectype> T_FLOAT     "float"
 276 %token <spectype> T_DOUBLE    "double"
 277 %token <spectype> T_SIGNED    "signed"
 278 %token <spectype> T_UNSIGNED  "unsigned"
 279 %token <spectype> T_BOOL      "_Bool"
 280 %token <spectype> T_COMPLEX   "_Complex"
 281 %token <spectype> T_IMAGINARY "_Imaginary"
 282
 283 %token <spectype> T_STRUCT    "struct"
 284 %token <spectype> T_UNION     "union"
 285 %token <spectype> T_ENUM      "enum"
 286
 287 /*
 288  * English keywords.
 289  */
 290 %token T_TYPE      "type"
 291 %token T_DECLARE   "declare"
 292 %token T_POINTER   "pointer"
 293 %token T_FUNCTION  "function"
 294 %token T_RETURNING "returning"
 295 %token T_ARRAY     "array"
 296 %token T_TO        "to"
 297 %token T_OF        "of"
 298 %token T_AS        "as"
 299 %token T_VLA       "variable-length"
 300
 301 %type <item>       vla_ident
 302 %type <uintval>    array_length
 303 %type <boolval>    varargs
 304 %type <spectype>   declspec_simple qualifier_simple
 305 %type <spectype>   typespec_simple typespec_tagged
 306 %type <declspec>   declspec_notype declspec_noid typespec_noid typespec
 307 %type <declspec>   qualifier qualifiers
 308 %type <declspec>   declspecs declspecs_noid
 309 %type <declarator> direct_declarator declarator pointer array parens postfix
 310 %type <declarator> direct_declarator_ish declarator_ish parameter_type_list
 311 %type <decl>       cdecl declaration declarators declarator_wrap parameter
 312
 313 %type <item>       english_vla
 314 %type <declspec>   storage_func_specs post_specs
 315 %type <declspec>   type_qual_spec type_qual_specs typedef_name_qual
 316 %type <declarator> english_declarator english_array english_function
 317 %type <declarator> english_parameter_list null_decl
 318 %type <decl>       english english_declaration english_parameter
 319
 320 /* Precedence declaration to avoid conflict in english_parameter; see below. */
 321 %right T_TYPE
 322 %right T_IDENT
 323
 324 %%
 325
 326 input: cdecl { *out = $1; }
 327 cdecl: english | declaration
 328
 329 semi: | T_SEMICOLON
 330 declaration: declspecs declarators semi {
 331         $$ = $2;
 332         $$->specifiers = $1;
 333 };
 334
 335 /*
 336  * We support parsing declarations using arbitrary identifiers as type
 337  * specifiers (a la C typedef).  To avoid confusion with identifiers that
 338  * may also be used as declarators, note the following:
 339  *
 340  *  (a) Every valid C declaration must have at least one type specifier, and
 341  *  (b) Valid declarations with typedef names have exactly one type specifier.
 342  *
 343  * So the rule applied when parsing specifiers is: an identifier is a type
 344  * specifier only if we have not yet seen any type specifiers whatsoever
 345  * (within one declaration specifier list).
 346  *
 347  * Treating identifiers as type specifiers by default can lead to strange and
 348  * unexpected parses; libcdecl applies a simplification step to the resulting
 349  * parse tree afterwards.
 350  */
 351 declspecs: declspec_notype declspecs {
 352         $$ = $1;
 353         $$->next = $2;
 354 } | typespec declspecs_noid {
 355         $$ = $1;
 356         $$->next = $2;
 357 }
 358
 359 declspecs_noid: { $$ = NULL; } | declspec_noid declspecs_noid {
 360         $$ = $1;
 361         $$->next = $2;
 362 }
 363
 364 qualifiers: { $$ = NULL; } | qualifiers qualifier {
 365         $$ = $2;
 366         $$->next = $1;
 367 }
 368
 369 declarators: declarator_wrap | declarator_wrap T_COMMA declarators {
 370         $$ = $1;
 371         $$->next = $3;
 372 }
 373
 374 declarator_wrap: declarator {
 375         ALLOC_DECL($$, NULL, $1);
 376 }
 377
 378 declspec_simple: T_AUTO
 379         | T_TYPEDEF
 380         | T_EXTERN
 381         | T_STATIC
 382         | T_REGISTER
 383         | T_INLINE
 384
 385 typespec_simple: T_VOID
 386         | T_CHAR
 387         | T_SHORT
 388         | T_INT
 389         | T_LONG
 390         | T_FLOAT
 391         | T_DOUBLE
 392         | T_SIGNED
 393         | T_UNSIGNED
 394         | T_BOOL
 395         | T_COMPLEX
 396         | T_IMAGINARY
 397
 398 typespec_tagged: T_STRUCT | T_UNION | T_ENUM | { $$ = CDECL_TYPE_IDENT; }
 399
 400 qualifier_simple: T_CONST
 401         | T_RESTRICT
 402         | T_VOLATILE
 403
 404 declspec_notype: qualifier | declspec_simple { ALLOC_DECLSPEC($$, $1); }
 405 typespec_noid: typespec_simple { ALLOC_DECLSPEC($$, $1); }
 406 qualifier: qualifier_simple { ALLOC_DECLSPEC($$, $1); }
 407
 408 typespec: typespec_noid | typespec_tagged T_IDENT {
 409         /* Compiler should be able to elide this assignment. */
 410         $2->u.declspec.ident = $2->u.declarator.u.ident;
 411
 412         $$ = &$2->u.declspec;
 413         $$->type = $1;
 414 }
 415
 416 declspec_noid: declspec_notype | typespec_noid
 417
 418 vla_ident: T_IDENT | T_ASTERISK {
 419         if (!($$ = cdecl__alloc_item(1)))
 420                 YYERROR;
 421         *$$->s = 0;
 422 }
 423
 424 array: T_LBRACKET array_length T_RBRACKET {
 425         ALLOC_ARRAY($$, $2);
 426 } | T_LBRACKET vla_ident T_RBRACKET {
 427         $$ = &$2->u.declarator;
 428         $$->type = CDECL_DECL_ARRAY;
 429         $$->u.array.vla = $$->u.ident;
 430         $$->u.array.length = 0;
 431 }
 432
 433 parameter: declspecs declarator {
 434         ALLOC_DECL($$, $1, $2);
 435 }
 436
 437 varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }
 438
 439 parameter_type_list: parameter varargs {
 440         ALLOC_FUNCTION($$, $1, $2);
 441 } | parameter T_COMMA parameter_type_list {
 442         $$ = $3;
 443         $1->next = $$->u.function.parameters;
 444         $$->u.function.parameters = $1;
 445 }
 446
 447 parens: T_LPAREN parameter_type_list T_RPAREN {
 448         $$ = $2;
 449 } | T_LPAREN declarator_ish T_RPAREN {
 450         struct cdecl *fake_params;
 451
 452         ALLOC_DECL(fake_params, NULL, $2);
 453         ALLOC_FUNCTION($$, fake_params, false);
 454 }
 455
 456 pointer: T_ASTERISK qualifiers direct_declarator {
 457         ALLOC_POINTER($$, $2, $3);
 458 } | T_ASTERISK qualifiers pointer {
 459         ALLOC_POINTER($$, $2, $3);
 460 }
 461
 462 declarator: direct_declarator | pointer
 463 declarator_ish: direct_declarator_ish | pointer
 464 postfix: array | parens
 465
 466 direct_declarator_ish: {
 467         $$ = NULLDECL;
 468 } | direct_declarator_ish postfix {
 469         $$ = $2;
 470         $$->child = $1;
 471 }
 472
 473 direct_declarator: {
 474         $$ = NULLDECL;
 475 } | T_IDENT {
 476         $$ = &$1->u.declarator;
 477 } | direct_declarator postfix {
 478         $$ = $2;
 479         $$->child = $1;
 480 }
 481
 482 english: T_DECLARE T_IDENT T_AS english_declaration {
 483         $$ = insert_identifier($4, $2);
 484 } | T_TYPE english_declaration {
 485         $$ = $2;
 486 }
 487
 488 /*
 489  * We use a precedence declaration to prefer shifting an identifier
 490  * over reducing this empty rule; see below.
 491  */
 492 storage_func_specs: %prec T_TYPE { $$ = NULL; }
 493 storage_func_specs: declspec_simple storage_func_specs {
 494         ALLOC_DECLSPEC($$, $1);
 495         $$->next = $2;
 496 }
 497
 498 type_qual_spec: typespec_noid | qualifier
 499
 500 type_qual_specs: { $$ = NULL; } | type_qual_spec type_qual_specs {
 501         $$ = $1;
 502         $$->next = $2;
 503 }
 504
 505 /*
 506  * The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
 507  * conflicts with pointer declarators.  So we end up needing to stitch
 508  * together three different specifiers lists.
 509  */
 510 post_specs: qualifiers typespec type_qual_specs {
 511         $2->next = $3;
 512         join_specs($2, $1);
 513         $$ = $2;
 514 }
 515
 516 english_declaration: storage_func_specs english_declarator post_specs {
 517         join_specs($3, $1);
 518         ALLOC_DECL($$, $3, $2);
 519 }
 520
 521 english_declarator: {
 522         $$ = NULLDECL;
 523 } | english_declarator qualifiers T_POINTER T_TO {
 524         ALLOC_POINTER($$, $2, $1);
 525 } | english_declarator english_array {
 526         $$ = $2;
 527         $$->child = $1;
 528 } | english_declarator english_function {
 529         $$ = $2;
 530         $$->child = $1;
 531 }
 532
 533 english_function: T_FUNCTION T_RETURNING {
 534         ALLOC_FUNCTION($$, NULL, false);
 535 } | T_FUNCTION T_LPAREN english_parameter_list T_RPAREN T_RETURNING {
 536         $$ = $3;
 537 }
 538
 539 english_parameter_list: english_parameter varargs {
 540         ALLOC_FUNCTION($$, $1, $2);
 541 } | english_parameter T_COMMA english_parameter_list {
 542         $$ = $3;
 543         $1->next = $$->u.function.parameters;
 544         $$->u.function.parameters = $1;
 545 }
 546
 547 typedef_name_qual: T_IDENT qualifiers {
 548         /* Compiler should be able to elide this assignment. */
 549         $1->u.declspec.ident = $1->u.declarator.u.ident;
 550
 551         $$ = &$1->u.declspec;
 552         $$->type = CDECL_TYPE_IDENT;
 553         $$->next = $2;
 554 }
 555
 556 null_decl: {
 557         $$ = NULLDECL;
 558 }
 559
 560 /*
 561  * There is a shift/reduce conflict here when an identifier appears as the
 562  * first token.  The conflict is between shifting T_IDENT, or reducing the
 563  * empty production for storage_func_specs (cf. english_declaration).
 564  *
 565  *   - In either case, if we reduce, we won't match T_IDENT T_AS since the
 566  *     stack now has the extra storage_func_specs nonterminal symbol.
 567  *   - And if we shift, we won't match english_declaration since it is
 568  *     too late to add storage_func_specs to the stack.
 569  *
 570  * The only valid input affected by the conflict is a simple type names,
 571  * possibly followed by qualifiers.  So the conflict is adequately resolved
 572  * by shifting, so long as we have a special-case reduction to handle this.
 573  */
 574 english_parameter: english_declaration | typedef_name_qual null_decl {
 575         ALLOC_DECL($$, $1, $2);
 576 } | T_IDENT T_AS english_declaration {
 577         $$ = insert_identifier($3, $1);
 578 }
 579
 580 english_array: T_VLA T_ARRAY english_vla T_OF {
 581         $$ = &$3->u.declarator;
 582         $$->type = CDECL_DECL_ARRAY;
 583         $$->u.array.vla = $$->u.ident;
 584         $$->u.array.length = 0;
 585 } | T_ARRAY array_length T_OF {
 586         ALLOC_ARRAY($$, $2);
 587 }
 588
 589 array_length: { $$ = 0; }
 590 array_length: T_UINT {
 591         if (!($$ = $1)) {
 592                 cdecl__errmsg(CDECL__EZEROARRAY);
 593                 YYERROR;
 594         }
 595 }
 596
 597 english_vla: T_IDENT | {
 598         if (!($$ = cdecl__alloc_item(1)))
 599                 YYERROR;
 600         *$$->s = 0;
 601 }
 602
 603 %%
 604
 605 /*
 606  * Expose the token string table to the rest of the library, in order to
 607  * produce strings that match parser keywords.
 608  *
 609  * In order for this to work properly, the Bison output must be postprocessed
 610  * by fix-yytname.awk to remove pointless quotation marks from the keyword
 611  * strings.
 612  */
 613 const char *cdecl__token_name(unsigned token)
 614 {
 615         return yytname[YYTRANSLATE(token)];
 616 }
 617
 618 /*
 619  * Current versions of GCC (up to 13) want to inline this function into the
 620  * parser even when optimizing for size and the results are not great, so
 621  * try to prevent such inlining.
 622  */
 623 CDECL__NOINLINE static void
 624 yyerror(YYLTYPE *loc, yyscan_t scanner, struct cdecl **out, const char *err)
 625 {
 626         if (strstr(err, yytname[YYTRANSLATE(T_LEX_ERROR)]))
 627                 return;
 628
 629         cdecl__err("%s", err);
 630 }