configure.ac

   1 dnl Copyright © 2011-2013, 2020-2023 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 AC_PREREQ([2.68])
   8 AC_INIT([cdecl99], [1.2a], [nbowler@draconx.ca])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects dist-xz])
  12 AM_SILENT_RULES([yes])
  13 DX_AUTOMAKE_COMPAT
  14
  15 AC_ARG_WITH([readline],
  16   [AS_HELP_STRING([--with-readline],
  17     [use GNU readline for line-editing functionality (default: auto)])],
  18   [], [with_readline=auto])
  19 AS_CASE([$with_readline],
  20   [no], [gl_cv_lib_readline=no],
  21   [yes|auto], [:],
  22   [*], [AC_MSG_ERROR([invalid option --with-readline=$with_readline])])
  23
  24 AC_PROG_CC_C99
  25 AM_PROG_CC_C_O
  26 gl_EARLY
  27
  28 LT_INIT
  29 gl_INIT
  30
  31 AC_C_FLEXIBLE_ARRAY_MEMBER
  32
  33 # Work around quoting bug in Gnulib threadlib.m4 which prevents
  34 # correct detection on e.g., Solaris 8.  These platforms require
  35 # PTHREAD_IN_USE_DETECTION_HARD to be set otherwise cdecl99 will
  36 # crash when reporting an error as initialization is not done.
  37 #
  38 # If this gets fixed in Gnulib, we can remove this.
  39 AS_CASE([$host_os],
  40   [[solaris2.[1-9] | solaris2.[1-9].*]],
  41     [AC_DEFINE([PTHREAD_IN_USE_DETECTION_HARD])])
  42
  43 # As the mbrtowc replacement module is not used by the library, there is
  44 # no need for multithreaded mbrtowc (all programs are single threaded).
  45 AC_DEFINE([GNULIB_MBRTOWC_SINGLE_THREAD], [1], [Define to 1.])
  46
  47 AS_IF([test x"$gl_cv_lib_readline" = x"no"],
  48   [AS_IF([test x"$with_readline" = x"yes"],
  49     [AC_MSG_FAILURE([--with-readline requested but readline was not found])],
  50     [dx_cv_rl_add_history=no])])
  51 AC_CACHE_CHECK([if readline supports add_history], [dx_cv_rl_add_history], [dnl
  52 dx_cv_rl_add_history=no
  53 dx_save_libs=$LIBS
  54 LIBS="$LIBS $LIBREADLINE"
  55 AC_LINK_IFELSE([AC_LANG_PROGRAM([dnl
  56 #include <stdio.h>
  57 #if HAVE_READLINE_HISTORY_H
  58 #  include <readline/history.h>
  59 #endif
  60 ], [dnl
  61 (*add_history)("");
  62 ])], [dx_cv_rl_add_history=yes], [dx_cv_rl_add_history=no])
  63 LIBS=$dx_save_libs
  64 ])
  65
  66 AS_IF([test x"$dx_cv_rl_add_history" = x"yes"],
  67   [AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
  68     [Define to 1 if readline supports add_history.])])
  69
  70 m4_include([lib/gnulib.mk])
  71 DX_GLSYM_PREFIX([cdecl__gl_])
  72 DX_GNULIB_SYMFILES([lib/symfiles], [s])
  73 AM_CONDITIONAL([BUILD_STATIC], [test x"$enable_static" = x"yes"])
  74
  75 dnl We provide our own makefile rules for gettext.  Disable tracing of
  76 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  77 dnl prevent automake from growing gratuitous error conditions.
  78 m4_traceoff([AM_GNU_GETTEXT])
  79 AM_GNU_GETTEXT([external])
  80 DX_LINGUAS
  81
  82 AM_CONDITIONAL([USE_NLS], [test x"$USE_NLS" = x"yes"])
  83
  84 DX_PROG_FLEX([], [have_flex=yes], [have_flex=no])
  85 AM_CONDITIONAL([HAVE_FLEX], [test x"$have_flex" = x"yes"])
  86
  87 DX_PROG_BISON([], [have_bison=yes], [have_bison=no])
  88 AM_CONDITIONAL([HAVE_BISON], [test x"$have_bison" = x"yes"])
  89
  90 DX_BISON_COMPAT
  91 BISON_I18N
  92
  93 BISON_COMPAT=
  94 AS_IF([test x"$dx_cv_bison_api_header_include" = x"yes"],
  95   [BISON_COMPAT="'--define=api.header.include={\"\$(*F).h\"}'"])
  96 AS_IF([test x"$dx_cv_bison_warn_no_deprecated" = x"yes"],
  97   [AS_VAR_APPEND([BISON_COMPAT], ["${BISON_COMPAT:+ }-Wno-deprecated"])])
  98 AC_SUBST([BISON_COMPAT])
  99
 100 AH_TOP([#include <conf_pre.h>])
 101 AH_BOTTOM([#include <conf_post.h>])
 102
 103 AC_CONFIG_TESTDIR([.], [t:.])
 104 DX_PROG_AUTOTEST
 105 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
 106 AC_CHECK_FUNCS_ONCE([strtoumax strtoull __strtoull])
 107
 108 AC_CONFIG_FILES([
 109         Makefile
 110 ])
 111 AC_OUTPUT