sys-devel/gcc/gcc-4.3.4.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/gcc-4.3.4.ebuild,v 1.9 2009/11/10 17:58:55 ranger Exp $
   4
   5 GENTOO_PATCH_EXCLUDE="69_all_gcc43-pr39013.patch" #262567
   6
   7 PATCH_VER="1.0"
   8 UCLIBC_VER="1.0"
   9
  10 ETYPE="gcc-compiler"
  11
  12 # Hardened gcc 4 stuff
  13 PIE_VER="10.1.5"
  14 SPECS_VER="0.9.4"
  15
  16 # arch/libc configurations known to be stable or untested with {PIE,SSP,FORTIFY}-by-default
  17 PIE_GLIBC_STABLE="x86 amd64 ~ppc ~ppc64 ~arm ~sparc"
  18 PIE_UCLIBC_STABLE="x86 arm"
  19 #SSP_STABLE="amd64 x86 ppc ppc64 ~arm ~sparc"
  20 #SSP_UCLIBC_STABLE=""
  21
  22 # whether we should split out specs files for multiple {PIE,SSP}-by-default
  23 # and vanilla configurations.
  24 SPLIT_SPECS=no #${SPLIT_SPECS-true} hard disable until #106690 is fixed
  25
  26 inherit toolchain
  27
  28 DESCRIPTION="The GNU Compiler Collection.  Includes C/C++, java compilers, pie+ssp extensions, Haj Ten Brugge runtime bounds checking"
  29
  30 LICENSE="GPL-3 LGPL-3 libgcc libstdc++"
  31 KEYWORDS="alpha amd64 arm -hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~x86-fbsd"
  32
  33 RDEPEND=">=sys-libs/zlib-1.1.4
  34         >=sys-devel/gcc-config-1.4
  35         virtual/libiconv
  36         >=dev-libs/gmp-4.2.1
  37         >=dev-libs/mpfr-2.3
  38         !build? (
  39                 gcj? (
  40                         gtk? (
  41                                 x11-libs/libXt
  42                                 x11-libs/libX11
  43                                 x11-libs/libXtst
  44                                 x11-proto/xproto
  45                                 x11-proto/xextproto
  46                                 >=x11-libs/gtk+-2.2
  47                                 x11-libs/pango
  48                         )
  49                         >=media-libs/libart_lgpl-2.1
  50                         app-arch/zip
  51                         app-arch/unzip
  52                 )
  53                 >=sys-libs/ncurses-5.2-r2
  54                 nls? ( sys-devel/gettext )
  55         )"
  56 DEPEND="${RDEPEND}
  57         test? ( sys-devel/autogen dev-util/dejagnu )
  58         >=sys-apps/texinfo-4.2-r4
  59         >=sys-devel/bison-1.875
  60         sys-devel/flex
  61         elibc_glibc? ( >=sys-libs/glibc-2.8 )
  62         amd64? ( multilib? ( gcj? ( app-emulation/emul-linux-x86-xlibs ) ) )
  63         ppc? ( >=${CATEGORY}/binutils-2.17 )
  64         ppc64? ( >=${CATEGORY}/binutils-2.17 )
  65         >=${CATEGORY}/binutils-2.15.94"
  66 PDEPEND=">=sys-devel/gcc-config-1.4"
  67 if [[ ${CATEGORY} != cross-* ]] ; then
  68         PDEPEND="${PDEPEND} elibc_glibc? ( >=sys-libs/glibc-2.8 )"
  69 fi
  70
  71 src_unpack() {
  72         gcc_src_unpack
  73
  74         use vanilla && return 0
  75
  76         sed -i 's/use_fixproto=yes/:/' gcc/config.gcc #PR33200
  77
  78         [[ ${CHOST} == ${CTARGET} ]] && epatch "${FILESDIR}"/gcc-spec-env.patch
  79
  80         [[ ${CTARGET} == *-softfloat-* ]] && epatch "${FILESDIR}"/4.3.2/gcc-4.3.2-softfloat.patch
  81
  82         epatch "${FILESDIR}"/gcc-pod-deps.patch
  83 }