games-puzzle/osmos/osmos-1.6.1.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit eutils games
   8
   9 MY_PN="Osmos"
  10 MY_P="${MY_PN}_${PV}"
  11
  12 DESCRIPTION="Play as a single-celled organism absorbing others"
  13 HOMEPAGE="http://www.hemispheregames.com/osmos/"
  14 SRC_URI="${MY_P}.tar.gz"
  15
  16 LICENSE="OSMOS"
  17 SLOT="0"
  18 KEYWORDS="-* ~amd64 ~x86"
  19 IUSE=""
  20 RESTRICT="fetch strip"
  21 PROPERTIES="interactive"
  22
  23 RDEPEND="virtual/opengl
  24         virtual/glu
  25         x11-libs/libX11
  26         media-libs/freetype:2
  27         sys-libs/glibc
  28         media-libs/openal
  29         media-libs/libvorbis"
  30 DEPEND="${RDEPEND}"
  31
  32 S=${WORKDIR}/${MY_PN}
  33
  34 GAMES_CHECK_LICENSE="yes"
  35
  36 pkg_nofetch() {
  37         einfo "Please download ${MY_P}.tar.gz and place it into ${DISTDIR}"
  38 }
  39
  40 src_install() {
  41         local dir="${GAMES_PREFIX_OPT}/${PN}"
  42
  43         exeinto "${dir}"
  44         doexe ${MY_PN}
  45         if use amd64 ; then
  46                 doexe ${MY_PN}.bin64 || die "doexe"
  47         fi
  48         if use x86 ; then
  49                 doexe ${MY_PN}.bin32 || die "doexe"
  50         fi
  51         dohtml readme.html
  52         insinto "${dir}"
  53         doins -r Fonts/ Sounds/ Textures/ Osmos-* *.cfg || die "doins failed"
  54
  55         newicon Icons/256x256.png ${PN}.png
  56
  57         games_make_wrapper ${PN} ./${MY_PN} "${dir}"
  58         make_desktop_entry ${PN} "Osmos"
  59
  60         prepgamesdirs
  61 }