sys-apps/mosys/mosys-20170221.ebuild

   1 # Copyright © 2017 Nick Bowler
   2 # License GPLv3+: GNU General Public License version 3 or later.
   3 # There is NO WARRANTY, to the extent permitted by law.
   4
   5 EAPI=6
   6
   7 inherit toolchain-funcs
   8
   9 # Github repo has no release tags, and chromium repo has no stable
  10 # download archives.  Fun times.
  11 SHA1=04b5510716baccee8a3e4a502d6aab38ea35a6a3
  12 MY_P=$PN-$SHA1
  13
  14 DESCRIPTION="More Open System tool for ChromiumOS"
  15 HOMEPAGE="https://github.com/dhendrix/mosys"
  16 SRC_URI="https://github.com/dhendrix/$PN/archive/$SHA1.tar.gz -> $MY_P.tar.gz"
  17
  18 LICENSE="BSD"
  19 SLOT="0"
  20 KEYWORDS="~arm"
  21
  22 LIBDEPEND="sys-libs/flashmap
  23         sys-apps/util-linux"
  24 DEPEND="$LIBDEPEND
  25         sys-libs/ncurses:0
  26         virtual/pkgconfig"
  27 RDEPEND=$LIBDEPEND
  28
  29 PATCHES=(
  30         "$FILESDIR/$PN-verbose-library-tests.patch"
  31 )
  32
  33 S=$WORKDIR/$MY_P
  34
  35 my_emake () {
  36         emake V=1 CC_LDFLAGS="$LDFLAGS" EXTRA_CFLAGS="$CFLAGS" \
  37                 CC="$(tc-getCC)" LD="$(tc-getCC) -nostdlib" AR="$(tc-getAR)" \
  38                 HOSTCC="$(tc-getBUILD_CC)" "$@" || die
  39 }
  40
  41 src_configure () {
  42         my_emake defconfig
  43 }
  44
  45 src_compile () {
  46         my_emake
  47 }
  48
  49 src_install () {
  50         dosbin mosys
  51         dodoc README
  52 }