media-plugins/gimp-python: Remove python eclass usage.

[gentoo-draconx.git] / media-plugins / gimp-python / gimp-python-2.10.32.ebuild

diff --git a/media-plugins/gimp-python/gimp-python-2.10.32.ebuild b/media-plugins/gimp-python/gimp-python-2.10.32.ebuild
new file mode 100644 (file)
index 0000000..8045319
--- /dev/null
+++ b/media-plugins/gimp-python/gimp-python-2.10.32.ebuild
@@ -0,0 +1,65 @@
+# Copyright © 2020-2022 Nick Bowler
+# License GPLv3+: GNU General Public License version 3 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+
+EAPI=8
+
+inherit autotools
+
+MY_P=${P/-python/}
+
+DESCRIPTION="Python plugin support for GIMP"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.10/$MY_P.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
+
+DEPEND="dev-lang/python:2.7
+       >=media-gfx/gimp-$PV
+       >=dev-python/pycairo-1.0.2:2[python_targets_python2_7(+)]
+       >=dev-python/pygtk-2.10.4:2[python_targets_python2_7(+)]
+       !media-gfx/gimp[python(-)]"
+RDEPEND=$DEPEND
+
+S=$WORKDIR/$MY_P
+
+PATCHES=(
+       "$FILESDIR/2.10.20-no-mypaint-brushes.patch"
+)
+
+src_prepare () {
+       sed -i '/^libgimp/s|[^ ]*/lib\(gimp[^-]*\)-[^ ]*\.la|-l\1-2.0|' \
+               plug-ins/pygimp/Makefile.am
+
+       default
+
+       eautoreconf
+}
+
+src_configure () {
+       local myconf=(
+               GDBUS_CODEGEN="/bin/false"
+               GEGL="$EPREFIX/usr/bin/gegl-0.4"
+
+               $(use_enable cpu_flags_ppc_altivec altivec)
+               $(use_enable cpu_flags_x86_mmx mmx)
+               $(use_enable cpu_flags_x86_sse sse)
+               --enable-python
+               PYTHON=python2.7
+       )
+
+       econf "${myconf[@]}"
+}
+
+src_compile () {
+       cd plug-ins/pygimp && emake
+}
+
+src_install () {
+       cd plug-ins/pygimp && emake DESTDIR="$D" install
+       find "$D" -name '*.la' -delete
+}