x11-libs/libdrm/libdrm-9999.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=3
   6 inherit xorg-2
   7
   8 EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
   9
  10 DESCRIPTION="X.Org libdrm library"
  11 HOMEPAGE="http://dri.freedesktop.org/"
  12 if [[ ${PV} = 9999* ]]; then
  13         SRC_URI=""
  14 else
  15         SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
  16 fi
  17
  18 KEYWORDS=""
  19 VIDEO_CARDS="intel nouveau radeon vmware"
  20 for card in ${VIDEO_CARDS}; do
  21         IUSE_VIDEO_CARDS+=" video_cards_${card}"
  22 done
  23
  24 IUSE="${IUSE_VIDEO_CARDS} libkms"
  25 RESTRICT="test" # see bug #236845
  26
  27 RDEPEND="dev-libs/libpthread-stubs"
  28 DEPEND="${RDEPEND}"
  29
  30 pkg_setup() {
  31         CONFIGURE_OPTIONS="--enable-udev
  32                         $(use_enable video_cards_intel intel)
  33                         $(use_enable video_cards_nouveau nouveau-experimental-api)
  34                         $(use_enable video_cards_radeon radeon)
  35                         $(use_enable video_cards_vmware vmwgfx-experimental-api)
  36                         $(use_enable libkms)"
  37
  38         xorg-2_pkg_setup
  39 }
  40
  41 pkg_postinst() {
  42         xorg-2_pkg_postinst
  43
  44         ewarn "libdrm's ABI may have changed without change in library name"
  45         ewarn "Please rebuild media-libs/mesa, x11-base/xorg-server and"
  46         ewarn "your video drivers in x11-drivers/*."
  47 }