+input: cdecl { *out = $1; }
+cdecl: english | declaration
+
+semi: | T_SEMICOLON
+declaration: declspecs declarators semi {
+ $$ = reverse_decls($2);
+ $$->specifiers = $1;
+};
+
+/*
+ * We support parsing declarations using arbitrary identifiers as type
+ * specifiers (a la C typedef). To avoid confusion with identifiers that
+ * may also be used as declarators, note the following:
+ *
+ * (a) Every valid C declaration must have at least one type specifier, and
+ * (b) Valid declarations with typedef names have exactly one type specifier.
+ *
+ * So the rule applied when parsing specifiers is: an identifier is a type
+ * specifier only if we have not yet seen any type specifiers whatsoever
+ * (within one declaration specifier list).
+ *
+ * Treating identifiers as type specifiers by default can lead to strange and
+ * unexpected parses; libcdecl applies a simplification step to the resulting
+ * parse tree afterwards.
+ */
+declspecs: declspecs_notype typespec declspecs_noid {
+ $$ = join_specs3($1, $2, $3);
+}
+
+declspecs_notype: { $$ = NULL; } | declspecs_notype declspec_notype {
+ $$ = $2;
+ $$->next = $1;
+}
+
+declspecs_noid: { $$ = NULL; } | declspecs_noid declspec_noid {
+ $$ = $2;
+ $$->next = $1;
+}
+
+qualifiers: { $$ = NULL; } | qualifiers qualifier {
+ $$ = $2;
+ $$->next = $1;
+}
+
+declarators: declarator_wrap | declarators T_COMMA declarator_wrap {
+ $$ = $3;
+ $$->next = $1;
+}
+
+declarator_wrap: declarator {
+ ALLOC_DECL($$, NULL, $1);
+}
+
+declspec_simple: T_AUTO
+ | T_TYPEDEF
+ | T_EXTERN
+ | T_STATIC
+ | T_REGISTER
+ | T_INLINE
+
+typespec_simple: T_VOID
+ | T_CHAR
+ | T_SHORT
+ | T_INT
+ | T_LONG
+ | T_FLOAT
+ | T_DOUBLE
+ | T_SIGNED
+ | T_UNSIGNED
+ | T_BOOL
+ | T_COMPLEX
+ | T_IMAGINARY
+
+typespec_tagged: T_STRUCT | T_UNION | T_ENUM | { $$ = CDECL_TYPE_IDENT; }
+
+qualifier_simple: T_CONST
+ | T_RESTRICT
+ | T_VOLATILE
+
+declspec_notype: qualifier | declspec_simple { ALLOC_DECLSPEC($$, $1); }
+typespec_noid: typespec_simple { ALLOC_DECLSPEC($$, $1); }
+qualifier: qualifier_simple { ALLOC_DECLSPEC($$, $1); }
+
+typespec: typespec_noid | typespec_tagged T_IDENT {
+ /* Compiler should be able to elide this assignment. */
+ $2->u.declspec.ident = $2->u.declarator.u.ident;
+
+ $$ = &$2->u.declspec;
+ $$->type = $1;
+}
+
+declspec_noid: declspec_notype | typespec_noid
+
+vla_ident: T_IDENT | T_ASTERISK {
+ if (!($$ = cdecl__alloc_item(1)))
+ YYERROR;
+ *$$->s = 0;
+}
+
+array: T_LBRACKET array_length T_RBRACKET {
+ ALLOC_ARRAY($$, $2);
+} | T_LBRACKET vla_ident T_RBRACKET {
+ $$ = &$2->u.declarator;
+ $$->type = CDECL_DECL_ARRAY;
+ $$->u.array.vla = $$->u.ident;
+ $$->u.array.length = 0;
+}
+
+parameter: declspecs declarator {
+ ALLOC_DECL($$, $1, $2);
+}
+
+varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }
+
+parameter_type_list: parameter {
+ ALLOC_FUNCTION_($$, $1);
+} | parameter_type_list T_COMMA parameter {
+ $$ = $1;
+ $3->next = $$->u.function.parameters;
+ $$->u.function.parameters = $3;
+}
+
+parens: T_LPAREN parameter_type_list varargs T_RPAREN {
+ $2->u.function.parameters = reverse_decls($2->u.function.parameters);
+ $2->u.function.variadic = $3;
+ $$ = $2;
+} | T_LPAREN declarator_ish T_RPAREN {
+ struct cdecl *fake_params;
+
+ ALLOC_DECL(fake_params, NULL, $2);
+ ALLOC_FUNCTION_($$, fake_params);
+}
+
+pointer: T_ASTERISK qualifiers direct_declarator {
+ ALLOC_POINTER($$, $2, $3);
+} | T_ASTERISK qualifiers pointer {
+ ALLOC_POINTER($$, $2, $3);
+}
+
+declarator: direct_declarator | pointer
+declarator_ish: direct_declarator_ish | pointer
+postfix: array | parens
+
+direct_declarator_ish: {
+ $$ = NULLDECL;
+} | direct_declarator_ish postfix {
+ $$ = $2;
+ $$->child = $1;
+}
+
+direct_declarator: {
+ $$ = NULLDECL;
+} | T_IDENT {
+ $$ = &$1->u.declarator;
+} | direct_declarator postfix {
+ $$ = $2;
+ $$->child = $1;
+}
+
+english: T_DECLARE T_IDENT T_AS english_declaration {
+ $$ = insert_identifier($4, $2);
+} | T_TYPE english_declaration {
+ $$ = $2;
+}
+
+/*
+ * We use a precedence declaration to prefer shifting an identifier
+ * over reducing this empty rule; see below.
+ */
+storage_func_specs: %prec T_TYPE { $$ = NULL; }
+storage_func_specs: storage_func_specs declspec_simple {
+ ALLOC_DECLSPEC($$, $2);
+ $$->next = $1;
+}
+
+type_qual_spec: typespec_noid | qualifier
+
+type_qual_specs: { $$ = NULL; } | type_qual_specs type_qual_spec {
+ $$ = $2;
+ $$->next = $1;
+}
+
+/*
+ * The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
+ * conflicts with pointer declarators. So we end up needing to stitch
+ * together three different specifiers lists.
+ */
+post_specs: qualifiers typespec type_qual_specs {
+ $$ = join_specs3($1, $2, $3);
+}
+
+english_declaration: storage_func_specs english_declarator post_specs {
+ join_specs($3, $1);
+ ALLOC_DECL($$, $3, $2);
+}
+
+english_declarator: {
+ $$ = NULLDECL;
+} | english_declarator qualifiers T_POINTER T_TO {
+ ALLOC_POINTER($$, $2, $1);
+} | english_declarator english_array {
+ $$ = $2;
+ $$->child = $1;
+} | english_declarator english_function {
+ $$ = $2;
+ $$->child = $1;
+}
+
+english_function: T_FUNCTION T_RETURNING {
+ ALLOC_FUNCTION($$, NULL, false);
+} | T_FUNCTION T_LPAREN english_parameter_list varargs T_RPAREN T_RETURNING {
+ $3->u.function.parameters = reverse_decls($3->u.function.parameters);
+ $3->u.function.variadic = $4;
+ $$ = $3;
+}
+
+english_parameter_list: english_parameter {
+ ALLOC_FUNCTION_($$, $1);
+} | english_parameter_list T_COMMA english_parameter {
+ $$ = $1;
+ $3->next = $$->u.function.parameters;
+ $$->u.function.parameters = $3;
+}
+
+typedef_name_qual: T_IDENT qualifiers {
+ /* Compiler should be able to elide this assignment. */
+ $1->u.declspec.ident = $1->u.declarator.u.ident;
+
+ $$ = &$1->u.declspec;
+ $$->type = CDECL_TYPE_IDENT;
+ $$->next = $2;
+}
+
+null_decl: {
+ $$ = NULLDECL;
+}
+
+/*
+ * There is a shift/reduce conflict here when an identifier appears as the
+ * first token. The conflict is between shifting T_IDENT, or reducing the
+ * empty production for storage_func_specs (cf. english_declaration).
+ *
+ * - In either case, if we reduce, we won't match T_IDENT T_AS since the
+ * stack now has the extra storage_func_specs nonterminal symbol.
+ * - And if we shift, we won't match english_declaration since it is
+ * too late to add storage_func_specs to the stack.
+ *
+ * The only valid input affected by the conflict is a simple type names,
+ * possibly followed by qualifiers. So the conflict is adequately resolved
+ * by shifting, so long as we have a special-case reduction to handle this.
+ */
+english_parameter: english_declaration | typedef_name_qual null_decl {
+ ALLOC_DECL($$, $1, $2);
+} | T_IDENT T_AS english_declaration {
+ $$ = insert_identifier($3, $1);
+}
+
+english_array: T_VLA T_ARRAY english_vla T_OF {
+ $$ = &$3->u.declarator;
+ $$->type = CDECL_DECL_ARRAY;
+ $$->u.array.vla = $$->u.ident;
+ $$->u.array.length = 0;
+} | T_ARRAY array_length T_OF {
+ ALLOC_ARRAY($$, $2);
+}
+
+array_length: { $$ = 0; }
+array_length: T_UINT {
+ if (!($$ = $1)) {
+ cdecl__errmsg(CDECL__EZEROARRAY);
+ YYERROR;
+ }
+}
+
+english_vla: T_IDENT | {
+ if (!($$ = cdecl__alloc_item(1)))
+ YYERROR;
+ *$$->s = 0;
+}