libcdecl: Use macros for packing tokens into bytes.

[cdecl99.git] / src / scan.l

diff --git a/src/scan.l b/src/scan.l
index 5c1a960651d591f4cfd75bcc10658a55b260df95..67183815da48e97642536c72e7dd131e050bf744 100644 (file)
--- a/src/scan.l
+++ b/src/scan.l
@@ -1,7 +1,7 @@
 %top{
 /*
  *  Scanner for C declarations.
- *  Copyright © 2011 Nick Bowler
+ *  Copyright © 2011, 2021, 2023 Nick Bowler
  *
  *  This program is free software: you can redistribute it and/or modify
  *  it under the terms of the GNU General Public License as published by
@@ -17,10 +17,188 @@
  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  */
 
- #include "parse.h"
+#include <config.h>
+#include "parse.h"
 }
 
-%option noyywrap bison-locations
+%option nodefault noyywrap bison-locations reentrant never-interactive
+%option extra-type="int"
+%option prefix="cdecl__yy"
+
+%{
+#include <ctype.h>
+#include "cdecl-internal.h"
+#include "cdecl.h"
+#include "errmsg.h"
+
+#if HAVE_STRTOUMAX
+/* Best case, implementation provides strtoumax. */
+#  define STRTOUMAX strtoumax
+#elif HAVE_STRTOULL
+/* Fall back to strtoull, with possibly reduced range. */
+#define STRTOUMAX strtoull
+#elif HAVE___STRTOULL
+/* HP-UX 11 has __strtoull in <inttypes.h> */
+#define STRTOUMAX __strtoull
+#else
+/* Fall back to strtoul, with possibly reduced range. */
+#define STRTOUMAX strtoul
+#endif
+
+#define dup_token() do { \
+       yylval->strval = malloc(yyleng+1); \
+       if (!yylval->strval) { \
+               cdecl__errmsg(CDECL__ENOMEM); \
+               return T_LEX_ERROR; \
+       } \
+       memcpy(yylval->strval, yytext, yyleng); \
+       yylval->strval[yyleng] = 0; \
+} while(0)
+
+static char *to_octal(char *dst, unsigned val)
+{
+       unsigned i;
+
+       for (i = 0; i < 3; i++) {
+               *dst++ = '0' + ((val >> 6) & 7u);
+               val <<= 3;
+       }
+
+       return dst;
+}
+
+/*
+ * Convert a single character to a C-style character constant, including quote
+ * characters.  At most 7 bytes are written to the buffer for the longest
+ * octal encoding, e.g., '\177'
+ */
+static void to_readable_ch(char *dst, char c)
+{
+       unsigned char uc = c;
+       unsigned i;
+       char esc;
+
+       /*
+        * The 7 standard C control characters are contiguous in ASCII,
+        * permitting a simple and compact lookup table; separating their
+        * handling from backslash and quote characters hopefully allows
+        * the compiler to recognize that.
+        */
+       switch (c) {
+       case '\a': i = 0; break;
+       case '\b': i = 1; break;
+       case '\t': i = 2; break;
+       case '\n': i = 3; break;
+       case '\v': i = 4; break;
+       case '\f': i = 5; break;
+       case '\r': i = 6; break;
+       default:   i = 7; break;
+       }
+       esc = "abtnvfr"[i];
+
+       /* Otherwise printable characters that should still be escaped. */
+       switch (c) {
+       case '\\': case '\'': esc = c; break;
+       }
+
+       *dst++ = '\'';
+       if (esc) {
+               *dst++ = '\\';
+               *dst++ = esc;
+       } else if (isprint(uc)) {
+               *dst++ = c;
+       } else {
+               *dst++ = '\\';
+               dst = to_octal(dst, uc);
+       }
+       *dst++ = '\'';
+       *dst++ = 0;
+}
+
+%}
+
+IDENT [_[:alpha:]][-_[:alnum:]]*
+INTEGER 0x[[:xdigit:]]+|0[0-7]+|[[:digit:]]+
 
 %%
 
+%{
+       char *c;
+
+       if (yyextra > 0) {
+               yyextra = -yyextra;
+               return T_ENGLISH;
+       }
+%}
+
+"..."|[][;*(),] {
+       unsigned char *match;
+       static const unsigned char tab[2][8] = {
+               "*[](),.;",
+               {
+                       PACK_TOKEN(T_ASTERISK),
+                       PACK_TOKEN(T_LBRACKET),
+                       PACK_TOKEN(T_RBRACKET),
+                       PACK_TOKEN(T_LPAREN),
+                       PACK_TOKEN(T_RPAREN),
+                       PACK_TOKEN(T_COMMA),
+                       PACK_TOKEN(T_ELLIPSIS),
+                       PACK_TOKEN(T_SEMICOLON)
+               }
+       };
+
+       match = memchr(&tab, yytext[0], sizeof tab[0]);
+       return UNPACK_TOKEN(match[sizeof tab[0]]);
+}
+
+{INTEGER} {
+       char *end;
+
+       errno = 0;
+       yylval->uintval = STRTOUMAX(yytext, &end, 0);
+       if (errno == ERANGE) {
+               cdecl__errmsg(CDECL__ERANGE);
+               return T_LEX_ERROR;
+       }
+       if (*end) {
+               cdecl__errmsg(CDECL__EBADINT);
+               return T_LEX_ERROR;
+       }
+
+       return T_UINT;
+}
+
+{IDENT} {
+       int ret = cdecl__to_keyword(yytext, yyleng, yyextra);
+       if (ret == T_IDENT) {
+               /*
+                * Our IDENT pattern includes hyphens so we can match
+                * "variable-length" as a keyword.  In all other cases a
+                * hyphen is an error.
+                *
+                * We could use yyless to re-scan the hyphen and hit the
+                * error catch-all, but jumping straight to the error code
+                * seems to produce better results with gcc with no obvious
+                * downsides.
+                */
+#if 1
+               if ((c = strchr(yytext, '-')))
+                       goto invalid_char;
+#else
+               yyless(strcspn(yytext, "-"));
+#endif
+               dup_token();
+       }
+       return ret;
+}
+
+[[:space:]]+
+. {
+       char buf[8];
+
+       c = yytext;
+invalid_char:
+       to_readable_ch(buf, *c);
+       cdecl__err(CDECL_ENOPARSE, _("syntax error, unexpected %s"), buf);
+       return T_LEX_ERROR;
+}