configure.ac

   1 dnl Copyright © 2009-2012, 2015, 2019-2020, 2022-2023 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 DX_PATCH_GNULIB
   8
   9 AC_INIT([upkg],[0.1],[nbowler@draconx.ca])
  10 AC_CONFIG_SRCDIR([src/libupkg.c])
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects])
  15 AM_SILENT_RULES([yes])
  16 DX_AUTOMAKE_COMPAT
  17
  18 AC_PROG_CC_C99
  19 gl_EARLY
  20
  21 LT_CONFIG_LTDL_DIR([libltdl])
  22 LT_INIT([dlopen])
  23 LTDL_INIT([nonrecursive])
  24
  25 gl_INIT
  26
  27 AC_CACHE_SAVE
  28
  29 m4_include([lib/gnulib.mk])
  30
  31 DX_LIB_GLIB2([], [gobject])
  32 AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
  33   [Define to shut up glib deprecation silliness.])
  34
  35 AC_ARG_WITH([modlib],
  36         [AS_HELP_STRING([--with-modlib],
  37                 [specify which module decoding library to use - one of modplug, none or auto. [default=auto]]
  38         )],
  39         [with_modlib=$withval],
  40         [with_modlib=auto])
  41
  42 use_modlib=none
  43 AS_CASE([$with_modlib],
  44   [no|none], [:],
  45   [modplug], [DX_LIB_LIBMODPLUG([use_modlib=modplug])],
  46   [auto], [DX_LIB_LIBMODPLUG([use_modlib=modplug], [:])],
  47   [AC_MSG_ERROR([Invalid argument to --with-modlib: $with_modlib])])
  48
  49 AC_MSG_CHECKING([which module library to use])
  50 AC_MSG_RESULT([$use_modlib])
  51
  52 AM_CONDITIONAL([USE_LIBMODPLUG], [test x$use_modlib = xmodplug])
  53 AM_CONDITIONAL([USE_DUMMYMOD],   [test x$use_modlib = xnone])
  54
  55 DX_PROG_GOB2([2.0.0], [have_gob2=yes], [have_gob2=no])
  56 AM_CONDITIONAL([HAVE_GOB2], [test x"$have_gob2" = x"yes"])
  57
  58 AS_IF([test x"$have_gob2" != x"yes"], [dx_cv_gob2_dynamic_types=no])
  59 AC_CACHE_CHECK([Whether $GOB2 supports dynamic types],
  60   [dx_cv_gob2_dynamic_types], [cat >conftest.gob <<'EOF'
  61 class :Conftest from G:Object (dynamic)
  62 {
  63   public void test(void)
  64   {
  65   }
  66 }
  67 EOF
  68 dx_cv_gob2_dynamic_types=no
  69 AS_IF([$GOB2 conftest.gob >/dev/null 2>&1],
  70 [mv conftest.c conftest.inc
  71 save_CFLAGS=$CFLAGS save_LIBS=$LIBS
  72 CFLAGS="$GLIB_CFLAGS $CFLAGS"
  73 LIBS="$LIBS $GLIB_LIBS"
  74 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#]include "conftest.inc"],
  75 [conftest_register_type(0);])], [dx_cv_gob2_dynamic_types=yes])
  76 CFLAGS=$save_CFLAGS LIBS=$save_LIBS])
  77 ])
  78 AM_CONDITIONAL([HAVE_GOB2_DYN], [test x"$dx_cv_gob2_dynamic_types" = x"yes"])
  79
  80 AC_CONFIG_TESTDIR([.], [test:.])
  81 DX_PROG_AUTOTEST
  82 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  83
  84 AC_CONFIG_FILES([Makefile libuobject.pc])
  85 AC_OUTPUT