configure.ac

   1 dnl Copyright © 2022 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 dnl remove pointless gnulib warning flag check
   8 AC_DEFUN([gl_CC_GNULIB_WARNINGS])
   9
  10 AC_INIT([rrace], [0], [nbowler@draconx.ca])
  11 AC_CONFIG_HEADERS([config.h])
  12
  13 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects])
  14 AM_SILENT_RULES([yes])
  15 DX_AUTOMAKE_COMPAT
  16
  17 AC_PROG_CC_C99
  18 gl_EARLY
  19 LT_INIT
  20 gl_INIT
  21
  22 AC_CACHE_SAVE
  23 m4_include([lib/gnulib.mk])
  24
  25 dnl We will provide our own makefile rules for gettext.  Disable tracing of
  26 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  27 dnl prevent automake from growing gratuitous error conditions.
  28 m4_traceoff([AM_GNU_GETTEXT])
  29 AM_GNU_GETTEXT([external])
  30 AH_BOTTOM([#include <conf_post.h>])
  31
  32 AC_PATH_XTRA
  33 AS_IF([test x"$no_x" != x"yes"],
  34 [AC_CACHE_CHECK([for Motif], [dx_cv_have_motif],
  35 [save_CFLAGS=$CFLAGS save_LIBS=$LIBS
  36 dx_cv_motif_cflags="$X_CFLAGS"
  37 dx_cv_motif_libs="$X_LIBS $X_PRE_LIBS -lXm -lXt -lX11 $X_EXTRA_LIBS"
  38 CFLAGS="$dx_cv_motif_cflags $CFLAGS"
  39 LIBS="$dx_cv_motif_libs $LIBS"
  40 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <Xm/XmAll.h>],
  41   [XmCreateMainWindow(0, 0, 0, 0); XtAppSetExitFlag(0)])],
  42   [dx_cv_have_motif=yes], [dx_cv_have_motif=no])
  43 CFLAGS=$save_CFLAGS LIBS=$save_LIBS])])
  44
  45 AS_IF([test x"$with_x" = x"yes" && test "$dx_cv_have_motif" != x"yes"],
  46   [AC_MSG_FAILURE([--with-x requested but Motif was not found])])
  47
  48 AC_SUBST([MOTIF_CFLAGS], [@&t@])
  49 AC_SUBST([MOTIF_LIBS], [@&t@])
  50 AS_IF([test x"$dx_cv_have_motif" = x"yes"],
  51   [MOTIF_CFLAGS=$dx_cv_motif_cflags MOTIF_LIBS=$dx_cv_motif_libs],
  52   [AC_DEFINE([X_DISPLAY_MISSING])])
  53 AM_CONDITIONAL([HAVE_MOTIF], [test x"$dx_cv_have_motif" = x"yes"])
  54 AH_TEMPLATE([X11_RENDER_DEBUG],
  55   [Define to 1 to enable visual aids for debugging X11 rendering.])
  56
  57 AC_CONFIG_TESTDIR([.], [t:.])
  58 DX_PROG_AUTOTEST
  59 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  60
  61 AC_CHECK_PROGS([XPMTOPPM], [xpmtoppm])
  62 AC_CHECK_PROGS([PNMTOPNG], [pnmtopng])
  63 AC_CHECK_PROGS([CONVERT], [convert])
  64 AC_CHECK_PROGS([GM], [gm])
  65 AC_CACHE_CHECK([how to convert XPM to PNG], [dx_cv_xpm_to_png],
  66 [cat >conftest.xpm <<'EOF'
  67 /* XPM */
  68 static char *x[] = {
  69 "1 1 1 1",
  70 "x c #123456",
  71 "x"
  72 };
  73 EOF
  74 check_conftest_png () {
  75   od conftest.png | $AWK 'BEGIN { success=0; }
  76 NR == 1 && $2 == "050211" && $3 == "043516" { success=1; }
  77 NR == 1 && $2 == "104520" && $3 == "047107" { success=1; }
  78 END { exit(!success); }'
  79 }
  80 rm -f conftest.png
  81 for dx_cv_xpm_to_png in netpbm 'gm convert' convert unknown; do
  82 AS_CASE([$dx_cv_xpm_to_png],
  83
  84 [netpbm],
  85 [AS_IF([$XPMTOPPM conftest.xpm >conftest.ppm 2>&AS_MESSAGE_LOG_FD],
  86   [], [continue])
  87 AS_IF([$PNMTOPNG conftest.ppm >conftest.png 2>&AS_MESSAGE_LOG_FD],
  88   [], [continue])
  89 AS_IF([check_conftest_png], [break])],
  90
  91 [*convert],
  92 [AS_CASE([$dx_cv_xpm_to_png],
  93   [gm*], [test_convert="$GM convert"],
  94   [test_convert="$CONVERT"])
  95 AS_IF([$test_convert conftest.xpm conftest.png >&AS_MESSAGE_LOG_FD 2>&1],
  96   [], [continue])
  97 AS_IF([check_conftest_png], [break])])
  98 done
  99 rm -f conftest.xpm conftest.ppm conftest.png])
 100
 101 AM_CONDITIONAL([USE_NETPBM], [test x"$dx_cv_xpm_to_png" = x"netpbm"])
 102 AM_CONDITIONAL([USE_CONVERT],
 103   [AS_CASE([$dx_cv_xpm_to_png], [*convert], [], [false])])
 104
 105 AS_IF([test x"$dx_cv_xpm_to_png" = x"gm convert"],
 106   [CONVERT="$GM convert"])
 107
 108 AC_CHECK_PROGS([OPTIPNG], [optipng])
 109 : "${OPTIPNG:=:}"
 110
 111 AC_CONFIG_FILES([Makefile])
 112 AC_OUTPUT
 113
 114 have_ui=false
 115 AM_COND_IF([HAVE_MOTIF], [have_ui=:])
 116 AS_IF([$have_ui], [],
 117 [AC_MSG_WARN([No user interface is enabled.])
 118 AC_MSG_WARN([It will not be possible to play the game.])])