testsuite.at

   1 AT_COPYRIGHT([Copyright © 2022-2023 Nick Bowler])
   2 #
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  15
  16 AT_INIT
  17 AT_COLOR_TESTS
  18
  19 m4_divert_push([PREPARE_TESTS])dnl
  20 test_run_tap () {
  21   "$builddir/t/$1" > "$1.tap"
  22   status=$?
  23   cat "$1.tap"
  24   :; { echo 'print <<EOF'; cat "$1.tap"; echo 'EOF'; } >"$1.pl"
  25   prove "$1.pl" 2>&1
  26   return $status
  27 }
  28 m4_divert_pop([PREPARE_TESTS])
  29
  30 m4_define([TEST_TAP], [AT_CHECK([test_run_tap "$1"], [0], [ignore])])
  31 m4_define([TEST_TAP_SIMPLE], [dnl
  32 AT_SETUP([$1])
  33 AT_KEYWORDS([$4])dnl
  34 m4_n([$3])dnl
  35 TEST_TAP([$2])
  36 AT_CLEANUP])
  37
  38 m4_include([tests/game.at])
  39 m4_include([tests/gui.at])