configure.ac

   1 dnl Copyright © 2022 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 dnl remove pointless gnulib warning flag check
   8 AC_DEFUN([gl_CC_GNULIB_WARNINGS])
   9
  10 AC_INIT([rrace], [0], [nbowler@draconx.ca])
  11 AC_CONFIG_HEADERS([config.h])
  12
  13 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects])
  14 AM_SILENT_RULES([yes])
  15 DX_AUTOMAKE_COMPAT
  16
  17 AC_PROG_CC_C99
  18 gl_EARLY
  19 LT_INIT
  20 gl_INIT
  21
  22 AC_CACHE_SAVE
  23 m4_include([lib/gnulib.mk])
  24
  25 dnl We will provide our own makefile rules for gettext.  Disable tracing of
  26 dnl AM_GNU_GETTEXT to prevent autoreconf from running autopoint, and to
  27 dnl prevent automake from growing gratuitous error conditions.
  28 m4_traceoff([AM_GNU_GETTEXT])
  29 AM_GNU_GETTEXT([external])
  30 AH_BOTTOM([#include <conf_post.h>])
  31
  32 # Checks for curses
  33 AC_ARG_WITH([curses], [AS_HELP_STRING([--with-curses],
  34   [use curses for playing in text mode (default: auto)])],
  35   [], [with_curses=auto])
  36 AS_IF([test x"$with_curses" != x"no"],
  37   [DX_LIB_CURSES([have_curses=yes], [have_curses=no])])
  38 AS_IF([test x"$with_curses" = x"yes" && x"$have_curses" != x"yes"],
  39   [AC_MSG_FAILURE([--with-curses requested but curses was not found])])
  40 AM_CONDITIONAL([HAVE_CURSES], [test x"$have_curses" = x"yes"])
  41
  42 AM_COND_IF([HAVE_CURSES],
  43 [DX_CHECK_CURSES_FUNC([wresize], [0,0,0])
  44 DX_CHECK_CURSES_MOUSE_SUPPORT])
  45
  46 # Checks for X11
  47 AC_PATH_XTRA
  48 AS_IF([test x"$no_x" != x"yes"],
  49 [AC_CACHE_CHECK([for Motif], [dx_cv_have_motif],
  50 [save_CFLAGS=$CFLAGS save_LIBS=$LIBS
  51 dx_cv_motif_cflags="$X_CFLAGS"
  52 dx_cv_motif_libs="$X_LIBS $X_PRE_LIBS -lXm -lXt -lX11 $X_EXTRA_LIBS"
  53 CFLAGS="$dx_cv_motif_cflags $CFLAGS"
  54 LIBS="$dx_cv_motif_libs $LIBS"
  55 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <Xm/XmAll.h>],
  56   [XmCreateMainWindow(0, 0, 0, 0); XtAppSetExitFlag(0)])],
  57   [dx_cv_have_motif=yes], [dx_cv_have_motif=no])
  58 CFLAGS=$save_CFLAGS LIBS=$save_LIBS])])
  59
  60 AS_IF([test x"$with_x" = x"yes" && test "$dx_cv_have_motif" != x"yes"],
  61   [AC_MSG_FAILURE([--with-x requested but Motif was not found])])
  62
  63 AC_SUBST([MOTIF_CFLAGS], [@&t@])
  64 AC_SUBST([MOTIF_LIBS], [@&t@])
  65 AM_CONDITIONAL([HAVE_MOTIF],
  66   [test x"$with_x" != x"no" && test x"$dx_cv_have_motif" = x"yes"])
  67 AM_COND_IF([HAVE_MOTIF],
  68   [MOTIF_CFLAGS=$dx_cv_motif_cflags MOTIF_LIBS=$dx_cv_motif_libs],
  69   [AC_DEFINE([X_DISPLAY_MISSING])])
  70 AH_TEMPLATE([X11_RENDER_DEBUG],
  71   [Define to 1 to enable visual aids for debugging X11 rendering.])
  72
  73 # Check for XmPIXMAP_AND_STRING.
  74 #
  75 # Just checking for the existence of this identifier is sufficient, to ensure
  76 # that the C compiler accepts the name.  If it turns out to not actually be
  77 # supported by the library used at runtime, Motif itself will catch this
  78 # and set to the default (i.e., XmSTRING).
  79 AM_COND_IF([HAVE_MOTIF],
  80 [AC_CACHE_CHECK([whether Motif supports XmPIXMAP_AND_STRING],
  81 [dx_cv_motif_have_pixmap_and_string],
  82 [save_CFLAGS=$CFLAGS save_LIBS=$LIBS
  83 CFLAGS="$MOTIF_CFLAGS $CFLAGS" LIBS="$MOTIF_LIBS $LIBS"
  84 AC_COMPUTE_INT([dx_tmp],
  85   [XmPIXMAP != XmPIXMAP_AND_STRING && XmSTRING != XmPIXMAP_AND_STRING],
  86   [#include <Xm/Label.h>], [dx_tmp=0])
  87 AS_IF([test x"$dx_tmp" = x"1"],
  88   [dx_cv_motif_have_pixmap_and_string=yes],
  89   [dx_cv_motif_have_pixmap_and_string=no])
  90 CFLAGS=$save_CFLAGS LIBS=$save_LIBS])
  91 AS_IF([test x"$dx_cv_motif_have_pixmap_and_string" = x"yes"],
  92   [AC_DEFINE([HAVE_MOTIF_PIXMAP_AND_STRING], [1],
  93     [Define to 1 if Motif supports XmPIXMAP_AND_STRING])])
  94 ])
  95
  96 AC_CONFIG_TESTDIR([.], [t:.])
  97 DX_PROG_AUTOTEST
  98 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  99
 100 AC_CHECK_PROGS([XPMTOPPM], [xpmtoppm])
 101 AC_CHECK_PROGS([PNMTOPNG], [pnmtopng])
 102 AC_CHECK_PROGS([CONVERT], [convert])
 103 AC_CHECK_PROGS([GM], [gm])
 104 AC_CACHE_CHECK([how to convert XPM to PNG], [dx_cv_xpm_to_png],
 105 [cat >conftest.xpm <<'EOF'
 106 /* XPM */
 107 static char *x[] = {
 108 "1 1 1 1",
 109 "x c #123456",
 110 "x"
 111 };
 112 EOF
 113 check_conftest_png () {
 114   od conftest.png | $AWK 'BEGIN { success=0; }
 115 NR == 1 && $2 == "050211" && $3 == "043516" { success=1; }
 116 NR == 1 && $2 == "104520" && $3 == "047107" { success=1; }
 117 END { exit(!success); }'
 118 }
 119 rm -f conftest.png
 120 for dx_cv_xpm_to_png in netpbm 'gm convert' convert unknown; do
 121 AS_CASE([$dx_cv_xpm_to_png],
 122
 123 [netpbm],
 124 [AS_IF([$XPMTOPPM conftest.xpm >conftest.ppm 2>&AS_MESSAGE_LOG_FD],
 125   [], [continue])
 126 AS_IF([$PNMTOPNG conftest.ppm >conftest.png 2>&AS_MESSAGE_LOG_FD],
 127   [], [continue])
 128 AS_IF([check_conftest_png], [break])],
 129
 130 [*convert],
 131 [AS_CASE([$dx_cv_xpm_to_png],
 132   [gm*], [test_convert="$GM convert"],
 133   [test_convert="$CONVERT"])
 134 AS_IF([$test_convert conftest.xpm conftest.png >&AS_MESSAGE_LOG_FD 2>&1],
 135   [], [continue])
 136 AS_IF([check_conftest_png], [break])])
 137 done
 138 rm -f conftest.xpm conftest.ppm conftest.png])
 139
 140 AM_CONDITIONAL([USE_NETPBM], [test x"$dx_cv_xpm_to_png" = x"netpbm"])
 141 AM_CONDITIONAL([USE_CONVERT],
 142   [AS_CASE([$dx_cv_xpm_to_png], [*convert], [], [false])])
 143
 144 AS_IF([test x"$dx_cv_xpm_to_png" = x"gm convert"],
 145   [CONVERT="$GM convert"])
 146
 147 AC_CHECK_PROGS([OPTIPNG], [optipng])
 148 : "${OPTIPNG:=:}"
 149
 150 AC_CONFIG_FILES([Makefile])
 151 AC_OUTPUT
 152
 153 have_ui=false
 154 AM_COND_IF([HAVE_CURSES], [have_ui=:])
 155 AM_COND_IF([HAVE_MOTIF], [have_ui=:])
 156 AS_IF([$have_ui], [],
 157 [AC_MSG_WARN([No user interface is enabled.])
 158 AC_MSG_WARN([It will not be possible to play the game.])])