configure.ac

   1 dnl Copyright © 2019-2020 Nick Bowler
   2 dnl
   3 dnl Based on original work Copyright © 1999-2013 Jiri (George) Lebl.
   4 dnl
   5 dnl License GPLv2+: GNU General Public License version 2 or any later version.
   6 dnl This is free software: you are free to change and redistribute it.
   7 dnl There is NO WARRANTY, to the extent permitted by law.
   8
   9 AC_INIT([gob-dx], [2.0.20a], [nbowler@draconx.ca])
  10 AC_CONFIG_SRCDIR([src/treefuncs.def])
  11 AC_CONFIG_HEADERS([config.h])
  12
  13 AM_INIT_AUTOMAKE([-Wall subdir-objects dist-xz])
  14 AM_SILENT_RULES([yes])
  15 DX_AUTOMAKE_COMPAT
  16
  17 AC_PROG_CC
  18 AC_PROG_CXX
  19 AC_PROG_LEX
  20 AC_PROG_YACC
  21
  22 AC_ARG_VAR([PERL], [command to execute perl programs])
  23 AC_CHECK_PROGS([PERL], [perl], [false])
  24 AM_CONDITIONAL([HAVE_PERL], [$PERL -e 'my $x = 42; exit $x'; test $? = 42])
  25
  26 LT_INIT
  27
  28 DX_LIB_GLIB2
  29
  30 dnl Dependencies for test suite
  31 DX_LIB_GLIB2([], [gobject], [HAVE_GOBJECT=true], [HAVE_GOBJECT=false])
  32 AC_SUBST([HAVE_GOBJECT])
  33
  34 DX_LIB_GTK2([], [HAVE_GTK2=true], [HAVE_GTK2=false])
  35 AC_SUBST([HAVE_GTK2])
  36
  37 AC_CONFIG_TESTDIR([.], [t:.])
  38 DX_PROG_AUTOTEST
  39 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  40
  41 AC_CONFIG_FILES([Makefile gob2.spec doc/gob2.1 atlocal])
  42 AC_OUTPUT