configure.ac

   1 dnl Copyright © 2019-2022 Nick Bowler
   2 dnl
   3 dnl Based on original work Copyright © 1999-2013 Jiri (George) Lebl.
   4 dnl
   5 dnl License GPLv2+: GNU General Public License version 2 or any later version.
   6 dnl This is free software: you are free to change and redistribute it.
   7 dnl There is NO WARRANTY, to the extent permitted by law.
   8
   9 AC_INIT([GObject Builder], [2.0.20a], [nbowler@draconx.ca], [gob-dx])
  10 AC_CONFIG_SRCDIR([src/treefuncs.def])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability subdir-objects dist-xz])
  15 AM_SILENT_RULES([yes])
  16 DX_AUTOMAKE_COMPAT
  17
  18 AC_PROG_CC
  19 gl_EARLY
  20
  21 AC_PROG_CXX
  22 AC_PROG_YACC
  23
  24 LT_INIT
  25 gl_INIT
  26
  27 AC_CACHE_SAVE
  28
  29 m4_include([lib/gnulib.mk])
  30
  31 AC_ARG_VAR([PERL], [command to execute perl programs])
  32 AC_CHECK_PROGS([PERL], [perl], [false])
  33 AM_CONDITIONAL([HAVE_PERL], [$PERL -e 'my $x = 42; exit $x'; test $? = 42])
  34
  35 DX_PROG_FLEX([], [have_flex=yes], [have_flex=no])
  36 AM_CONDITIONAL([HAVE_FLEX], [test x"$have_flex" = x"yes"])
  37
  38 DX_LIB_GLIB2
  39
  40 dnl Dependencies for test suite
  41 DX_LIB_GLIB2([], [gobject], [HAVE_GOBJECT=true], [HAVE_GOBJECT=false])
  42 AC_SUBST([HAVE_GOBJECT])
  43
  44 save_LIBS=$LIBS
  45 LIBS="$LIBS $LIBGLIB_LIBS"
  46 AC_CHECK_FUNCS([g_string_append_printf g_ascii_strcasecmp])
  47 LIBS=$save_LIBS
  48
  49 AM_CONDITIONAL([GOB_STRCASE], [test x"$ac_cv_func_g_ascii_strcasecmp" = x"no"])
  50
  51 AS_IF([$HAVE_GOBJECT],
  52   [AC_CACHE_CHECK([whether libgobject supports private data members],
  53     [dx_cv_libgobject_privates],
  54 [save_CFLAGS=$CFLAGS
  55 CFLAGS="$CFLAGS $LIBGOBJECT_CFLAGS"
  56 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
  57 [#include <glib-object.h>
  58 #if defined(G_ADD_PRIVATE) || defined(G_TYPE_INSTANCE_GET_PRIVATE)
  59 #else
  60 DX_LIB_COMPILE_ERROR([private members not supported])
  61 #endif
  62 ])], [dx_cv_libgobject_privates=yes], [dx_cv_libgobject_privates=no])
  63 CFLAGS=$save_CFLAGS])])
  64
  65 AS_IF([test x"$dx_cv_libgobject_privates" = x"yes"],
  66   [HAVE_GOBJECT_PRIVATES=true], [HAVE_GOBJECT_PRIVATES=false])
  67 AC_SUBST([HAVE_GOBJECT_PRIVATES])
  68
  69 DX_LIB_GTK2([], [HAVE_GTK2=true], [HAVE_GTK2=false])
  70 AC_SUBST([HAVE_GTK2])
  71
  72 AC_CONFIG_TESTDIR([.], [t:.])
  73 DX_PROG_AUTOTEST
  74 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  75
  76 AC_CONFIG_FILES([Makefile gob2.spec doc/gob2.1])
  77 AC_OUTPUT