libdrm: Add live ebuild.

[gentoo-draconx.git] / x11-libs / libdrm / libdrm-9999.ebuild

diff --git a/x11-libs/libdrm/libdrm-9999.ebuild b/x11-libs/libdrm/libdrm-9999.ebuild
new file mode 100644 (file)
index 0000000..b2d7b55
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=3
+inherit xorg-2
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="http://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+       SRC_URI=""
+else
+       SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
+fi
+
+KEYWORDS=""
+VIDEO_CARDS="intel nouveau radeon vmware"
+for card in ${VIDEO_CARDS}; do
+       IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms"
+RESTRICT="test" # see bug #236845
+
+RDEPEND="dev-libs/libpthread-stubs"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+       CONFIGURE_OPTIONS="--enable-udev
+                       $(use_enable video_cards_intel intel)
+                       $(use_enable video_cards_nouveau nouveau-experimental-api)
+                       $(use_enable video_cards_radeon radeon)
+                       $(use_enable video_cards_vmware vmwgfx-experimental-api)
+                       $(use_enable libkms)"
+
+       xorg-2_pkg_setup
+}
+
+pkg_postinst() {
+       xorg-2_pkg_postinst
+
+       ewarn "libdrm's ABI may have changed without change in library name"
+       ewarn "Please rebuild media-libs/mesa, x11-base/xorg-server and"
+       ewarn "your video drivers in x11-drivers/*."
+}