sys-apps/vbetest: Update to work with latest gentoo repo.

[gentoo-draconx.git] / sys-apps / vbetest / vbetest-0.10-r1.ebuild

diff --git a/sys-apps/vbetest/vbetest-0.10-r1.ebuild b/sys-apps/vbetest/vbetest-0.10-r1.ebuild
new file mode 100644 (file)
index 0000000..6851a61
--- /dev/null
+++ b/sys-apps/vbetest/vbetest-0.10-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright © 2009, 2012, 2021 Nick Bowler
+# License GPLv3+: GNU General Public License version 3 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_PN=lrmi
+MY_P=$MY_PN-$PV
+
+DESCRIPTION="Utility to display and test VESA BIOS Extensions (VBE) modes."
+HOMEPAGE="http://www.sourceforge.net/projects/lrmi/"
+SRC_URI="mirror://sourceforge/$MY_PN/$MY_P.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="lrmi"
+
+DEPEND="lrmi? ( =sys-libs/lrmi-${PV}* )
+       !lrmi? ( dev-libs/libx86 )"
+RDEPEND=$DEPEND
+
+PATCHES=(
+       "$FILESDIR/$P-external-include.patch"
+)
+
+S=$WORKDIR/$MY_P
+
+src_compile() {
+       local inc= lib=-llrmi CC=$(tc-getCC)
+       use lrmi || { inc='-DLRMI_INCLUDE=<libx86.h>' lib=-lx86; }
+
+       (set -x; $CC $inc $CPPFLAGS $CFLAGS -c vbetest.c; ) || die
+       (set -x; $CC $CFLAGS $LDFLAGS -o vbetest vbetest.o $lib ) || die
+}
+
+src_install() {
+       dobin vbetest
+}