configure.ac

   1 dnl Copyright © 2009-2012, 2015, 2019-2020, 2022-2023 Nick Bowler
   2 dnl
   3 dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
   4 dnl This is free software: you are free to do what the fuck you want to.
   5 dnl There is NO WARRANTY, to the extent permitted by law.
   6
   7 DX_PATCH_GNULIB
   8
   9 AC_INIT([upkg],[0.1],[nbowler@draconx.ca])
  10 AC_CONFIG_SRCDIR([src/libupkg.c])
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects])
  15 AM_SILENT_RULES([yes])
  16 DX_AUTOMAKE_COMPAT
  17
  18 AC_PROG_CC_C99
  19 gl_EARLY
  20
  21 AC_C_FLEXIBLE_ARRAY_MEMBER
  22
  23 LT_CONFIG_LTDL_DIR([libltdl])
  24 LT_INIT([dlopen])
  25 LTDL_INIT([nonrecursive])
  26
  27 gl_INIT
  28
  29 AC_CACHE_SAVE
  30
  31 m4_include([lib/gnulib.mk])
  32
  33 DX_LIB_GLIB2([], [gobject])
  34 AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
  35   [Define to shut up glib deprecation silliness.])
  36
  37 AC_ARG_WITH([modlib],
  38         [AS_HELP_STRING([--with-modlib],
  39                 [specify which module decoding library to use - one of modplug, none or auto. [default=auto]]
  40         )],
  41         [with_modlib=$withval],
  42         [with_modlib=auto])
  43
  44 use_modlib=none
  45 AS_CASE([$with_modlib],
  46   [no|none], [:],
  47   [modplug], [DX_LIB_LIBMODPLUG([use_modlib=modplug])],
  48   [auto], [DX_LIB_LIBMODPLUG([use_modlib=modplug], [:])],
  49   [AC_MSG_ERROR([Invalid argument to --with-modlib: $with_modlib])])
  50
  51 AC_MSG_CHECKING([which module library to use])
  52 AC_MSG_RESULT([$use_modlib])
  53
  54 AM_CONDITIONAL([USE_LIBMODPLUG], [test x$use_modlib = xmodplug])
  55 AM_CONDITIONAL([USE_DUMMYMOD],   [test x$use_modlib = xnone])
  56
  57 DX_PROG_GOB2([2.0.0], [have_gob2=yes], [have_gob2=no])
  58 AM_CONDITIONAL([HAVE_GOB2], [test x"$have_gob2" = x"yes"])
  59
  60 AS_IF([test x"$have_gob2" != x"yes"], [dx_cv_gob2_dynamic_types=no])
  61 AC_CACHE_CHECK([Whether $GOB2 supports dynamic types],
  62   [dx_cv_gob2_dynamic_types], [cat >conftest.gob <<'EOF'
  63 class :Conftest from G:Object (dynamic)
  64 {
  65   public void test(void)
  66   {
  67   }
  68 }
  69 EOF
  70 dx_cv_gob2_dynamic_types=no
  71 AS_IF([$GOB2 conftest.gob >/dev/null 2>&1],
  72 [mv conftest.c conftest.inc
  73 save_CFLAGS=$CFLAGS save_LIBS=$LIBS
  74 CFLAGS="$GLIB_CFLAGS $CFLAGS"
  75 LIBS="$LIBS $GLIB_LIBS"
  76 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#]include "conftest.inc"],
  77 [conftest_register_type(0);])], [dx_cv_gob2_dynamic_types=yes])
  78 CFLAGS=$save_CFLAGS LIBS=$save_LIBS])
  79 ])
  80 AM_CONDITIONAL([HAVE_GOB2_DYN], [test x"$dx_cv_gob2_dynamic_types" = x"yes"])
  81
  82 AC_CONFIG_TESTDIR([.], [test:.])
  83 DX_PROG_AUTOTEST
  84 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
  85
  86 AC_CONFIG_FILES([Makefile libuobject.pc])
  87 AC_OUTPUT