mpdbetter.sed

   1 #!/bin/sed -f
   2
   3 # Nick's mpdbetter `configuration file'.  Input a list of track titles, and
   4 # substitute each with the title of the best version of that song.
   5
   6 # Handle special cases first
   7 / -extra hot mix-/{s///;b}
   8 / -Raven fly edit-/{s///;b}
   9 / -2006 memorial mix-/{s///;b}
  10 / -Practice Track-/{s///;b}
  11 / On Air Ver\./{s///;b}
  12 /-\[instrumental\]/{s///;b}
  13 /ちいさなヘミソフィア/{s//ヘミソフィア/;b}
  14 /愛のメロディー/{s/\((.*)\)\?$/(soundtrack ver.)/;b}
  15 /COLORS -.*/{s//COLORS/;b}
  16 / without NATSUMI/{s///;b}
  17
  18 # Some literal replacements
  19 /松澤由美 - SNOW/c\
  20 島みやえい子 - SNOW -Album Mix-
  21 /詩月カオリ - Senecio/c\
  22 詩月カオリ - Senecio -Album Mix-
  23 /AKI - Pure Heart〜世界で一番アナタが好き〜/c\
  24 詩月カオリ - Pure Heart 〜世界で一番アナタが好き〜 -Remix-
  25 /open〜オルゴールバージョン〜/c\
  26 詩月カオリ - open
  27 /euphoric field/c\
  28 ELISA - euphoric field (Japanese)
  29 /La Clef 〜迷宮の鍵〜/c\
  30 KOTOKO - La Clef 〜迷宮の鍵〜
  31
  32 # Sanitization
  33 s/「\(The Sore Feet Song\)」/\1/
  34
  35 # General rules get most tracks
  36 /\s*[~〜<〈[(ー–−-]\s\?inst.*/I          {s///;b}
  37 /\s*[~〜<〈[(ー–−-]\s\?tv.*/I            {s///;b}
  38 /\s*[~〜<〈[(ー–−-]\s\?without.*/I       {s///;b}
  39 /\s*[~〜<〈[(ー–−-]\s\?w\/o.*/I          {s///;b}
  40 /\s*[~〜<〈[(ー–−-]\s\?off.*/I           {s///;b}
  41 /\s*[~〜<〈[(ー–−-]\s\?back.*/I          {s///;b}
  42 /\s*[~〜<〈[(ー–−-]\s\?short.*/I         {s///;b}
  43 /\s*[~〜<〈[(ー–−-]\s\?karaoke.*/I       {s///;b}
  44 /\s*[~〜<〈[(ー–−-]\s\?game.*/I          {s///;b}
  45 /\s*[~〜<〈[(ー–−-]\s\?[^ ]*カラオケ.*/I {s///;b}
  46
  47 # When we lack brackets we match more specific strings
  48 / instrumental.*/I {s///;b}
  49 / off vocal.*/I    {s///;b}
  50 / short.*/I        {s///;b}
  51 / tv-\w\+/I        {s///;b}
  52 / anime ver\./I    {s///;b}