layouts/default.xsl

   1 <?xml version='1.0' encoding='UTF-8' ?>
   2 <!--
   3   Nick's web site: XHTML output stage
   4
   5   Copyright © 2018-2019 Nick Bowler
   6
   7   This program is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program.  If not, see <https://www.gnu.org/licenses/>
  19 -->
  20 <xsl:stylesheet version='1.0'
  21   xmlns='http://www.w3.org/1999/xhtml'
  22   xmlns:xhtml='http://www.w3.org/1999/xhtml'
  23   xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
  24   xmlns:func='http://exslt.org/functions'
  25   xmlns:f='http://draconx.ca/my-functions'
  26   extension-element-prefixes='func f'
  27   exclude-result-prefixes='xhtml'>
  28
  29 <xsl:import href='layouts/functions.xsl' />
  30
  31 <xsl:output method='xml' encoding='UTF-8' indent='yes'
  32   doctype-public='-//W3C//DTD XHTML 1.1//EN'
  33   doctype-system='http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd' />
  34
  35 <xsl:param name='source-uri'
  36   select='"//git.draconx.ca/gitweb/homepage.git/blob/"' />
  37 <xsl:param name='site-title' select='"The Citrine Citadel"' />
  38
  39 <func:function name='f:ends-with'>
  40   <xsl:param name='a' />
  41   <xsl:param name='b' />
  42   <func:result
  43     select='substring($a, string-length($a)-string-length($b)+1)=$b' />
  44 </func:function>
  45
  46 <xsl:template match='node()|@*'>
  47   <xsl:copy><xsl:apply-templates select='node()|@*' /></xsl:copy>
  48 </xsl:template>
  49
  50 <!--
  51   Nokogiri's pretty-printer is a bit weird.  Regardless of the indentation
  52   setting, if an element has no child text nodes then it will be pretty-
  53   printed.  This works by adding arbitrary whitespace to that element, and
  54   then all of its children are eligible to be pretty-printed.
  55
  56   If an element has any text nodes at all, then it is not pretty-printed and
  57   neither are any of its descendents.
  58
  59   Adding arbitrary whitespace to <pre> is bad, so we inject zero-width non-
  60   breaking spaces to prevent this.  This will render fine but the spaces
  61   should be removed before final output to avoid problems with copy+paste.
  62 -->
  63 <xsl:template match='xhtml:pre'>
  64   <xsl:copy>
  65     <xsl:apply-templates select='node()|@*' />
  66     <xsl:text>&#x2060;</xsl:text>
  67   </xsl:copy>
  68 </xsl:template>
  69
  70 <!--
  71   Likewise, adding spaces between consecutive span-level elements where
  72   none existed before won't go over well.
  73 -->
  74 <xsl:template name='glue-preceding-span'>
  75   <xsl:if test='f:element-is-span(preceding-sibling::node()[1])'>
  76     <xsl:text>&#x2060;</xsl:text>
  77   </xsl:if>
  78 </xsl:template>
  79
  80 <xsl:template match='*[f:element-is-span()]'>
  81   <xsl:call-template name='glue-preceding-span' />
  82   <xsl:copy>
  83     <xsl:apply-templates select='node()|@*' />
  84     <xsl:text>&#x2060;</xsl:text> <!-- avoid breaking within a span element -->
  85   </xsl:copy>
  86 </xsl:template>
  87
  88 <!--
  89   Manually strip whitespace-only text nodes so the pretty printer can do its
  90   thing on remaining elements.
  91 -->
  92 <xsl:template match='text()[normalize-space(.) = ""]'>
  93   <xsl:choose>
  94     <!-- preserve anything according to xml:space -->
  95     <xsl:when test='ancestor::*[@xml:space][1][@xml:space="preserve"]'>
  96       <xsl:copy />
  97     </xsl:when>
  98     <!-- preserve anything under <pre> -->
  99     <xsl:when test='ancestor::xhtml:pre'><xsl:copy /></xsl:when>
 100   </xsl:choose>
 101 </xsl:template>
 102
 103 <!-- Clean up whitespace where harmless to do so -->
 104 <xsl:template match='xhtml:p/node()[1][self::text()]'>
 105   <xsl:value-of select='f:strip-leading()' />
 106 </xsl:template>
 107 <xsl:template match='xhtml:p/node()[position()=last()][self::text()]'>
 108   <xsl:value-of select='f:strip-trailing()' />
 109 </xsl:template>
 110
 111 <!-- Add rel attributes to external links -->
 112 <xsl:template match='xhtml:a[starts-with(@href,"http://")
 113                           or starts-with(@href,"https://")
 114                           or starts-with(@href,"//")]'>
 115   <xsl:variable name='domain'
 116     select='substring-before(
 117               concat(translate(substring-after(@href, "//"), ":", "/"), "/"),
 118               "/")' />
 119
 120   <xsl:copy>
 121     <xsl:apply-templates select='@*' />
 122     <xsl:if test='not($domain="draconx.ca"
 123                       or f:ends-with($domain, ".draconx.ca"))'>
 124       <xsl:attribute name='rel'>
 125         <xsl:if test='@rel'>
 126           <xsl:value-of select='@rel' />
 127           <xsl:text> </xsl:text>
 128         </xsl:if>
 129         <xsl:text>external noopener noreferrer</xsl:text>
 130       </xsl:attribute>
 131     </xsl:if>
 132     <xsl:apply-templates select='node()' />
 133   </xsl:copy>
 134 </xsl:template>
 135
 136 <xsl:template match='xhtml:h2[@id]'>
 137   <xsl:variable name='fragment' select='concat("#", @id)' />
 138   <xsl:copy>
 139     <xsl:apply-templates select='node()|@*' />
 140     <xsl:text> </xsl:text>
 141     <small class='permalink'>
 142       (<a href='{$fragment}'><xsl:value-of select='$fragment' /></a>)
 143     </small>
 144   </xsl:copy>
 145 </xsl:template>
 146
 147 <xsl:template match='copyright'>
 148   <p>
 149     <xsl:text>Copyright © </xsl:text>
 150     <xsl:value-of select='text()' />
 151     <xsl:text>.</xsl:text>
 152   </p>
 153 </xsl:template>
 154
 155 <xsl:template match='license'>
 156   <p>
 157     <xsl:text>Copying and distribution of this material</xsl:text>
 158     <xsl:if test='normalize-space(modification-allowed)="yes"'>
 159       <xsl:text>, with or without modification,</xsl:text>
 160     </xsl:if>
 161     <xsl:text> is permitted under the terms of the </xsl:text>
 162     <a rel='license'>
 163       <xsl:attribute name='href'>
 164         <xsl:value-of select='normalize-space(uri)' />
 165       </xsl:attribute>
 166       <xsl:value-of select='name' />
 167     </a>
 168     <xsl:text>.</xsl:text>
 169   </p>
 170 </xsl:template>
 171
 172 <xsl:template match='source'>
 173   <p>
 174     <xsl:text>This document was compiled from </xsl:text>
 175     <a href='{concat($source-uri, revision, ":", file)}'>
 176       <xsl:value-of select='file' />
 177     </a>
 178     <xsl:text> on </xsl:text>
 179     <xsl:value-of select='compiletime' />
 180     <xsl:text>.</xsl:text>
 181   </p>
 182 </xsl:template>
 183
 184 <xsl:template match='/'>
 185   <html>
 186     <head>
 187       <meta name='viewport' content='width=device-width, initial-scale=1' />
 188       <link rel='stylesheet' type='text/css' href='/style.css' />
 189       <title>
 190         <xsl:variable name='page-title' select='string(/document/title)' />
 191         <xsl:if test='$page-title and $site-title != $page-title'>
 192           <xsl:value-of select='concat($page-title, " – ")' />
 193         </xsl:if>
 194         <xsl:value-of select='$site-title' />
 195       </title>
 196     </head>
 197     <body>
 198       <xsl:apply-templates select='/document/xhtml:html/@*' />
 199       <xsl:apply-templates select='/document/xhtml:html/node()' />
 200
 201       <hr />
 202       <div id='footer'>
 203         <xsl:apply-templates select='/document/copyright' />
 204         <xsl:apply-templates select='/document/license' />
 205         <xsl:apply-templates select='/document/source' />
 206       </div>
 207     </body>
 208   </html>
 209 </xsl:template>
 210
 211 </xsl:stylesheet>