From 69c30a8d92b2744be5315536a6b311fd3a0149b6 Mon Sep 17 00:00:00 2001
From: Nick Bowler <nbowler@draconx.ca>
Date: Sun, 17 Jan 2021 23:05:52 -0500
Subject: [PATCH] dev-util/dialog: bump to 1.3.20201126

---
 dev-util/dialog/Manifest                   |  2 +
 dev-util/dialog/dialog-1.3.20201126.ebuild | 49 ++++++++++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 dev-util/dialog/Manifest
 create mode 100644 dev-util/dialog/dialog-1.3.20201126.ebuild

diff --git a/dev-util/dialog/Manifest b/dev-util/dialog/Manifest
new file mode 100644
index 0000000..222e023
--- /dev/null
+++ b/dev-util/dialog/Manifest
@@ -0,0 +1,2 @@
+DIST dialog-1.3-20201126.tar.gz 555473 BLAKE2B 6a271fd3bd02b312f1f9ccbae2ee4d2a282298515da1924c3aec831f19e994870e82517ffe09dbdb6f5dae86708b5404a348ae91183e0b91bf530485fa2670aa SHA512 a094a209338ffc8ec775f2ad361ac187b07c13d2e079d00f96640f2a938f0f593bd0c4dc19abb1cbaac69049029da146097036e8795d1f04894aa955fa0ce913
+EBUILD dialog-1.3.20201126.ebuild 1210 BLAKE2B 390cef056a1871aff5b1a0f426de27af92ea75b3c5030c67ef57f33ee7d680dd2a13bb15f3af509542b7029db097b2e446653373600246238b4f090a3bc1021a SHA512 0c331627bf795a8bafbdea6bdd3aa7fa58c977ea068688b0fde994ae9c89faf8cfe27cb6db1cb3b6e129e4be2c228d67967bd4e89a9b90f1810c9daa94457064
diff --git a/dev-util/dialog/dialog-1.3.20201126.ebuild b/dev-util/dialog/dialog-1.3.20201126.ebuild
new file mode 100644
index 0000000..3810201
--- /dev/null
+++ b/dev-util/dialog/dialog-1.3.20201126.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIA_P=${PN}-$(ver_cut 1-2)-$(ver_cut 3)
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="https://invisible-island.net/dialog/"
+SRC_URI="https://invisible-island.net/datafiles/release/$PN.tar.gz -> $DIA_P.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/15"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.2-r5:=[unicode?]
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	!minimal? ( sys-devel/libtool )
+"
+S=${WORKDIR}/${DIA_P}
+
+src_prepare() {
+	default
+	sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
+	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-rpath-hack \
+		$(use_enable nls) \
+		$(use_with !minimal libtool) \
+		--with-libtool-opts=$(usex static-libs '' '-shared') \
+		--with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+	use minimal && default || emake DESTDIR="${D}" install-full
+
+	use examples && dodoc -r samples
+
+	dodoc CHANGES README
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
2.43.0