X-Git-Url: https://git.draconx.ca/gitweb/gentoo-fixes.git/blobdiff_plain/9a3c8aed2930bc1f8761da033f53b2fdcca86307..3027c86c57bf24fe3327137136ce8a4d72f1abc1:/dev-python/python-musicbrainz-ngs/python-musicbrainz-ngs-0.6.ebuild

diff --git a/dev-python/python-musicbrainz-ngs/python-musicbrainz-ngs-0.6.ebuild b/dev-python/python-musicbrainz-ngs/python-musicbrainz-ngs-0.6.ebuild
new file mode 100644
index 0000000..f9a26cd
--- /dev/null
+++ b/dev-python/python-musicbrainz-ngs/python-musicbrainz-ngs-0.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright © 2020 Nick Bowler
+# License GPLv2+: GNU General Public License version 2 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+#
+# This is a modified version of the original ebuild from Gentoo GNU/Linux,
+# covered by the following copyright and permission notice:
+#
+#   Copyright 2019-2020 Gentoo Authors
+#   Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7} )
+
+inherit distutils-r1
+
+MY_PN=${PN%-ngs}ngs
+MY_P=$MY_PN-$PV
+
+DESCRIPTION="Python bindings for the MusicBrainz NGS and the Cover Art Archive webservices"
+HOMEPAGE="https://github.com/alastair/python-musicbrainzngs"
+SRC_URI="https://github.com/alastair/$MY_PN/archive/v$PV.tar.gz -> $MY_P.tar.gz"
+
+LICENSE="BSD-2 ISC"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+S=$WORKDIR/$MY_P
+
+PATCHES="$FILESDIR/$PN-0.6-fix-test-submit.patch"
+
+DEPEND="dev-python/setuptools[$PYTHON_USEDEP]
+	doc? ( dev-python/sphinx[$PYTHON_USEDEP] )"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/^ *'sphinx.ext.intersphinx'//" -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test --verbosity=2
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x "/usr/share/doc/$PF/examples"
+	fi
+
+	distutils-r1_python_install_all
+}