X-Git-Url: https://git.draconx.ca/gitweb/gentoo-fixes.git/blobdiff_plain/61d34839932871ffdac5cd29e5b5e89d51b50375..f7902a168f5da4feef0279066fcdf112bd12d24e:/dev-python/pycairo/pycairo-1.18.2-r4.ebuild

diff --git a/dev-python/pycairo/pycairo-1.18.2-r4.ebuild b/dev-python/pycairo/pycairo-1.18.2-r4.ebuild
new file mode 100644
index 0000000..6c2b8d1
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.18.2-r4.ebuild
@@ -0,0 +1,77 @@
+# Copyright © 2020-2021 Nick Bowler
+#
+# License GPLv2+: GNU General Public License version 2 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+#
+# This is a modified version of the original ebuild from Gentoo GNU/Linux,
+# covered by the following copyright and permission notice:
+#
+#   Copyright 1999-2020 Gentoo Authors
+#   Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+_PYTHON_ALLOW_PY27=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_USE_SETUPTOOLS=no
+DISTUTILS_OPTIONAL=yes
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="2"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples +python_targets_python2_7"
+
+# Strong block on old pycairo w/ python2 support because the merge will
+# otherwise not work properly due to replacing a directory with a file.
+
+DEPEND=">=x11-libs/cairo-1.13.1[svg]
+	!!dev-python/pycairo:0[python_targets_python2_7]"
+RDEPEND="$DEPEND
+	dev-lang/python:2.7"
+BDEPEND="dev-lang/python:2.7"
+
+REQUIRED_USE=$PYTHON_REQUIRED_USE
+
+PATCHES=(
+	"$FILESDIR/$P-no-setuptools.patch"
+	"$FILESDIR/$PN-1.19.1-py39.patch"
+)
+
+distutils_enable_tests setup.py
+
+src_prepare () { default; distutils-r1_src_prepare; }
+
+python_compile () {
+	_distutils-r1_copy_egg_info
+	esetup.py build "$@"
+}
+
+src_configure () { distutils-r1_src_configure; }
+src_compile ()   { distutils-r1_src_compile; }
+src_test ()      { distutils-r1_src_test; }
+src_install ()   { distutils-r1_src_install; }
+
+python_test() {
+	einfo "Skipping tests on Python 2 to unblock deps"
+}
+
+python_install() {
+	distutils-r1_python_install \
+		install_pkgconfig --pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}