From: Nick Bowler <nbowler@draconx.ca>
Date: Fri, 5 Mar 2021 00:15:37 +0000 (-0500)
Subject: Add configure option to disable readline.
X-Git-Tag: v1.1~13
X-Git-Url: https://git.draconx.ca/gitweb/cdecl99.git/commitdiff_plain/41e93dfe1f8302927246aa8802b57d46c996703c

Add configure option to disable readline.

Apparently the Gnulib readline module does not provide any obvious way
for users to disable it.  Setting the gl_cv_lib_readline cache variable
works but probably only Autoconfers will know how to discover that.

Add an explicit --with-readline (and --without-readline) option which
internally sets this.  Since this option shows up in configure's help
output it is hopefully more obvious.
---

diff --git a/configure.ac b/configure.ac
index 5fd17d6..e1609cb 100644
--- a/configure.ac
+++ b/configure.ac
@@ -12,6 +12,15 @@ AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects dist-xz])
 AM_SILENT_RULES([yes])
 DX_AUTOMAKE_COMPAT
 
+AC_ARG_WITH([readline],
+  [AS_HELP_STRING([--with-readline],
+    [use GNU readline for line-editing functionality (default: auto)])],
+  [], [with_readline=auto])
+AS_CASE([$with_readline],
+  [no], [gl_cv_lib_readline=no],
+  [yes|auto], [:],
+  [*], [AC_MSG_ERROR([invalid option --with-readline=$with_readline])])
+
 AC_PROG_CC_C99
 AM_PROG_CC_C_O
 gl_EARLY
@@ -19,6 +28,10 @@ gl_EARLY
 LT_INIT
 gl_INIT
 
+AS_IF([test x"$gl_cv_lib_readline" = x"no"],
+  [AS_IF([test x"$with_readline" = x"yes"],
+    [AC_MSG_FAILURE([--with-readline requested but readline was not found])],
+    [dx_cv_rl_add_history=no])])
 AC_CACHE_CHECK([if readline supports add_history], [dx_cv_rl_add_history], [dnl
 dx_cv_rl_add_history=no
 dx_save_libs=$LIBS
@@ -35,8 +48,8 @@ LIBS=$dx_save_libs
 ])
 
 AS_IF([test x"$dx_cv_rl_add_history" = x"yes"],
-	[AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
-		[Define to 1 if readline supports add_history.])])
+  [AC_DEFINE([HAVE_RL_ADD_HISTORY], [1],
+    [Define to 1 if readline supports add_history.])])
 
 m4_include([lib/gnulib.mk])
 DX_GLSYM_PREFIX([cdecl__])