%code top {
/*
 *  Parser for C declarations.
 *  Copyright © 2011-2012, 2021, 2023 Nick Bowler
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */
}

%name-prefix "cdecl__yy"
%parse-param {void *scanner}
%parse-param {struct cdecl **out}
%lex-param {yyscan_t scanner}
%define api.pure
%error-verbose
%locations

%{
#include <config.h>
#include <assert.h>
#include <stdbool.h>

#include "scan.h"
#include "cdecl.h"
#include "cdecl-internal.h"
#include "errmsg.h"

#define FAIL(msg) do { \
	yyerror(&yylloc, NULL, NULL, msg); \
	YYERROR; \
} while (0)

#define ALLOC(ptr, size) do { \
	(ptr) = malloc(size); \
	if (!(ptr)) { \
		cdecl__errmsg(CDECL__ENOMEM); \
		YYERROR; \
	} \
} while (0)

#define ALLOC_STRUCT(ptr, type, ...) do { \
	ALLOC(ptr, sizeof (type)); \
	*(ptr) = (type) { __VA_ARGS__ }; \
} while (0)
%}

%code requires {
#include <inttypes.h>
}

%code provides {
void cdecl__free(struct cdecl *);
int cdecl__yyparse(void *scanner, struct cdecl **out);
const char *cdecl__token_name(unsigned token);
}

%union {
	uintmax_t uintval;
	unsigned spectype;
	_Bool boolval;
	char *strval;
	struct cdecl_declspec *declspec;
	struct cdecl_declarator *declarator;
	struct cdecl *decl;
}

%{
static void yyerror(YYLTYPE *, yyscan_t, struct cdecl **, const char *);
static void free_decl(struct cdecl *);

static void free_declspec(struct cdecl_declspec *x)
{
	struct cdecl_declspec *p;
	while (x) {
		p = x->next;
		free(x->ident);
		free(x);
		x = p;
	}
}

static void free_declarator(struct cdecl_declarator *x)
{
	struct cdecl_declarator *p;

	while (x) {
		p = x->child;

		switch (x->type) {
		case CDECL_DECL_NULL:
			break;
		case CDECL_DECL_IDENT:
			free(x->u.ident);
			break;
		case CDECL_DECL_POINTER:
			free_declspec(x->u.pointer.qualifiers);
			break;
		case CDECL_DECL_ARRAY:
			free(x->u.array.vla);
			break;
		case CDECL_DECL_FUNCTION:
			free_decl(x->u.function.parameters);
			break;
		default:
			assert(0);
		}

		free(x);
		x = p;
	}
}

static void free_decl(struct cdecl *x)
{
	struct cdecl *p;

	while (x) {
		p = x->next;

		/* The specifiers may be shared by an entire chain. */
		if (!p || p->specifiers != x->specifiers)
			free_declspec(x->specifiers);

		free_declarator(x->declarators);
		free(x);
		x = p;
	}
}

void cdecl__free(struct cdecl *decl)
{
	free_decl(decl);
}

/*
 * Join two declaration specifier lists into a single list, with "a" being the
 * head of the new list.
 *
 * The list "a" is assumed to be nonempty.
 */
static void join_specs(struct cdecl_declspec *a, struct cdecl_declspec *b)
{
	while (a->next)
		a = a->next;
	a->next = b;
}

/*
 * Alter an abstract declarator (type name) to declare an identifier instead,
 * used by the English parser rules to reduce "identifier as type" sequences.
 */
static struct cdecl *insert_identifier(struct cdecl *decl, char *ident)
{
	struct cdecl_declarator *d = decl->declarators;

	while (d->child)
		d = d->child;

	d->type = CDECL_DECL_IDENT;
	d->u.ident = ident;

	return decl;
}
%}

%destructor { free($$); }            <strval>
%destructor { free_declspec($$); }   <declspec>
%destructor { free_declarator($$); } <declarator>
%destructor { free_decl($$); }       <decl>

/* Magic tokens */
%token T_LEX_ERROR
%token T_ENGLISH

%token <strval> T_IDENT "identifier"
%token <uintval> T_UINT "integer constant"

%token T_SEMICOLON ";"
%token T_ASTERISK  "*"
%token T_LPAREN    "("
%token T_RPAREN    ")"
%token T_LBRACKET  "["
%token T_RBRACKET  "]"
%token T_COMMA     ","
%token T_ELLIPSIS  "..."

%token <spectype> T_TYPEDEF   "typedef"
%token <spectype> T_EXTERN    "extern"
%token <spectype> T_STATIC    "static"
%token <spectype> T_AUTO      "auto"
%token <spectype> T_REGISTER  "register"

%token <spectype> T_INLINE    "inline"

%token <spectype> T_RESTRICT  "restrict"
%token <spectype> T_VOLATILE  "volatile"
%token <spectype> T_CONST     "const"

%token <spectype> T_VOID      "void"
%token <spectype> T_CHAR      "char"
%token <spectype> T_SHORT     "short"
%token <spectype> T_INT       "int"
%token <spectype> T_LONG      "long"
%token <spectype> T_FLOAT     "float"
%token <spectype> T_DOUBLE    "double"
%token <spectype> T_SIGNED    "signed"
%token <spectype> T_UNSIGNED  "unsigned"
%token <spectype> T_BOOL      "_Bool"
%token <spectype> T_COMPLEX   "_Complex"
%token <spectype> T_IMAGINARY "_Imaginary"

%token <spectype> T_STRUCT    "struct"
%token <spectype> T_UNION     "union"
%token <spectype> T_ENUM      "enum"

/*
 * English keywords.
 */
%token T_TYPE      "type"
%token T_DECLARE   "declare"
%token T_POINTER   "pointer"
%token T_FUNCTION  "function"
%token T_RETURNING "returning"
%token T_ARRAY     "array"
%token T_TO        "to"
%token T_OF        "of"
%token T_AS        "as"
%token T_VLA       "variable-length"

%type <strval>     vla_ident
%type <uintval>    array_length
%type <boolval>    varargs
%type <spectype>   declspec_simple qualifier_simple
%type <spectype>   typespec_simple typespec_tagged
%type <declspec>   declspec_notype declspec_noid typespec_noid typespec
%type <declspec>   qualifier qualifiers
%type <declspec>   declspecs declspecs_noid
%type <declarator> direct_declarator declarator pointer array parens postfix
%type <declarator> direct_declarator_ish declarator_ish parameter_type_list
%type <decl>       declaration declarators declarator_wrap
%type <decl>       parameter

%type <strval>     english_vla
%type <declspec>   storage_func_specs post_specs
%type <declspec>   type_qual_spec type_qual_specs typedef_name_qual
%type <declarator> english_declarator english_array english_function
%type <declarator> english_parameter_list null_decl
%type <decl>       english english_declaration
%type <decl>       english_parameter

/*
 * Harmless shift/reduce conflicts in english_parameter.  See comments below
 * for more details.
 */
%expect 2

%%

input: T_ENGLISH english {
	*out = $2;
} | declaration {
	*out = $1;
};

semi: | T_SEMICOLON

declaration: declspecs declarators semi {
	$$ = $2;
	$$->specifiers = $1;
};

/*
 * We support parsing declarations using arbitrary identifiers as type
 * specifiers (a la C typedef).  To avoid confusion with identifiers that
 * may also be used as declarators, note the following:
 *
 *  (a) Every valid C declaration must have at least one type specifier, and
 *  (b) Valid declarations with typedef names have exactly one type specifier.
 *
 * So the rule applied when parsing specifiers is: an identifier is a type
 * specifier only if we have not yet seen any type specifiers whatsoever
 * (within one declaration specifier list).
 *
 * Treating identifiers as type specifiers by default can lead to strange and
 * unexpected parses; libcdecl applies a simplification step to the resulting
 * parse tree afterwards.
 */
declspecs: declspec_notype declspecs {
	$$ = $1;
	$$->next = $2;
} | typespec declspecs_noid {
	$$ = $1;
	$$->next = $2;
}

declspecs_noid: { $$ = NULL; } | declspec_noid declspecs_noid {
	$$ = $1;
	$$->next = $2;
}

qualifiers: { $$ = NULL; } | qualifiers qualifier {
	$$ = $2;
	$$->next = $1;
}

declarators: declarator_wrap | declarator_wrap T_COMMA declarators {
	$$ = $1;
	$$->next = $3;
}

declarator_wrap: declarator {
	ALLOC_STRUCT($$, struct cdecl, .declarators = $1);
}

declspec_simple: T_AUTO
	| T_TYPEDEF
	| T_EXTERN
	| T_STATIC
	| T_REGISTER
	| T_INLINE

typespec_simple: T_VOID
	| T_CHAR
	| T_SHORT
	| T_INT
	| T_LONG
	| T_FLOAT
	| T_DOUBLE
	| T_SIGNED
	| T_UNSIGNED
	| T_BOOL
	| T_COMPLEX
	| T_IMAGINARY

typespec_tagged: T_STRUCT | T_UNION | T_ENUM | { $$ = CDECL_TYPE_IDENT; }

qualifier_simple: T_CONST
	| T_RESTRICT
	| T_VOLATILE

declspec_notype: qualifier | declspec_simple {
	ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}

typespec_noid: typespec_simple {
	ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}

qualifier: qualifier_simple {
	ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}

typespec: typespec_noid | typespec_tagged T_IDENT {
	ALLOC_STRUCT($$, struct cdecl_declspec,
		.type  = $1,
		.ident = $2);
}

declspec_noid: declspec_notype | typespec_noid

vla_ident: T_IDENT | T_ASTERISK {
	ALLOC($$, sizeof "");
	*$$ = 0;
}

array: T_LBRACKET array_length T_RBRACKET {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_ARRAY,
		.u.array.length = $2);
} | T_LBRACKET vla_ident T_RBRACKET {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_ARRAY,
		.u.array.vla = $2);
}

parameter: declspecs declarator {
	ALLOC_STRUCT($$, struct cdecl,
		.specifiers = $1,
		.declarators = $2);
}

varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }

parameter_type_list: parameter varargs {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_FUNCTION,
		.u.function.parameters = $1,
		.u.function.variadic = $2);
} | parameter T_COMMA parameter_type_list {
	$$ = $3;
	$1->next = $$->u.function.parameters;
	$$->u.function.parameters = $1;
}

parens: T_LPAREN parameter_type_list T_RPAREN {
	$$ = $2;
} | T_LPAREN declarator_ish T_RPAREN {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_FUNCTION);
	ALLOC_STRUCT($$->u.function.parameters, struct cdecl,
		.declarators = $2);
}

pointer: T_ASTERISK qualifiers direct_declarator {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_POINTER,
		.u.pointer.qualifiers = $2,
		.child = $3);
} | T_ASTERISK qualifiers pointer {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_POINTER,
		.u.pointer.qualifiers = $2,
		.child = $3);
}

declarator: direct_declarator | pointer
declarator_ish: direct_declarator_ish | pointer
postfix: array | parens

direct_declarator_ish: {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_NULL);
} | direct_declarator_ish postfix {
	$$ = $2;
	$$->child = $1;
}

direct_declarator: {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_NULL);
} | T_IDENT {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_IDENT,
		.u.ident = $1);
} | direct_declarator postfix {
	$$ = $2;
	$$->child = $1;
}

english: T_DECLARE T_IDENT T_AS english_declaration {
	$$ = insert_identifier($4, $2);
} | T_TYPE english_declaration {
	$$ = $2;
}

storage_func_specs: { $$ = NULL; } | declspec_simple storage_func_specs {
	ALLOC_STRUCT($$, struct cdecl_declspec,
		.type = $1,
		.next = $2);
}

type_qual_spec: typespec_noid | qualifier

type_qual_specs: { $$ = NULL; } | type_qual_spec type_qual_specs {
	$$ = $1;
	$$->next = $2;
}

/*
 * The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
 * conflicts with pointer declarators.  So we end up needing to stitch
 * together three different specifiers lists.
 */
post_specs: qualifiers typespec type_qual_specs {
	$2->next = $3;
	join_specs($2, $1);
	$$ = $2;
}

english_declaration: storage_func_specs english_declarator post_specs {
	join_specs($3, $1);
	ALLOC_STRUCT($$, struct cdecl,
		.specifiers = $3,
		.declarators = $2);
}

english_declarator: {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_NULL);
} | english_declarator qualifiers T_POINTER T_TO {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_POINTER,
		.child = $1,
		.u.pointer.qualifiers = $2);
} | english_declarator english_array {
	$$ = $2;
	$$->child = $1;
} | english_declarator english_function {
	$$ = $2;
	$$->child = $1;
}

english_function: T_FUNCTION T_RETURNING {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_FUNCTION,
		.u.function.parameters = NULL);
} | T_FUNCTION T_LPAREN english_parameter_list T_RPAREN T_RETURNING {
	$$ = $3;
}

english_parameter_list: english_parameter varargs {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_FUNCTION,
		.u.function.parameters = $1,
		.u.function.variadic = $2);
} | english_parameter T_COMMA english_parameter_list {
	$$ = $3;
	$1->next = $$->u.function.parameters;
	$$->u.function.parameters = $1;
}

typedef_name_qual: T_IDENT qualifiers {
	ALLOC_STRUCT($$, struct cdecl_declspec,
		.type = CDECL_TYPE_IDENT,
		.ident = $1,
		.next = $2);
}

null_decl: {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_NULL);
}

/*
 * There is a small shift/reduce conflict here.  An unadorned identifier
 * as the first thing in the parameter might be a typedef name deep in the
 * first english_declaration (thus empty storage_func_specs and empty
 * english_declarator need to be reduced) or it might be the identifier
 * before the "as" (thus the identifier should be shifted).
 *
 * The typedef name conflict is the only issue, so treating it as a special
 * case makes the shift harmless.
 */
english_parameter: english_declaration | typedef_name_qual null_decl {
	ALLOC_STRUCT($$, struct cdecl,
		.specifiers = $1,
		.declarators = $2);
} | T_IDENT T_AS english_declaration {
	$$ = insert_identifier($3, $1);
}

english_array: T_VLA T_ARRAY english_vla T_OF {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_ARRAY,
		.u.array.vla = $3);
} | T_ARRAY array_length T_OF {
	ALLOC_STRUCT($$, struct cdecl_declarator,
		.type = CDECL_DECL_ARRAY,
		.u.array.length = $2);
}

array_length: { $$ = 0; }
array_length: T_UINT {
	if (!($$ = $1))
		FAIL(_("array length must be positive"));
}

english_vla: T_IDENT | {
	ALLOC($$, sizeof "");
	*$$ = 0;
}

%%

/*
 * Expose the token string table to the rest of the library, in order to
 * produce strings that match parser keywords.
 *
 * In order for this to work properly, the Bison output must be postprocessed
 * by fix-yytname.awk to remove pointless quotation marks from the keyword
 * strings.
 */
const char *cdecl__token_name(unsigned token)
{
	return yytname[YYTRANSLATE(token)];
}

static void
yyerror(YYLTYPE *loc, yyscan_t scanner, struct cdecl **out, const char *err)
{
	if (strstr(err, yytname[YYTRANSLATE(T_LEX_ERROR)]))
		return;

	cdecl__err(CDECL_ENOPARSE, "%s", err);
}