%code top {
/*
 *  Parser for C declarations.
 *  Copyright © 2011-2012, 2021, 2023-2024 Nick Bowler
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */
}

%name-prefix "cdecl__yy"
%parse-param {void *scanner}
%parse-param {struct cdecl **out}
%lex-param {yyscan_t scanner}
%define api.pure
%error-verbose
%locations

%{
#include <config.h>
#include <assert.h>
#include <stdbool.h>

#include "scan.h"
#include "cdecl-internal.h"
#include "errmsg.h"

/*
 * Allocate a parse tree node via cdecl__alloc_item.
 *
 * - m1 specifies the item's union member to assign to ptr, which selects the
 *   type of node to allocate.
 *
 * - m2 specifies the "next" or "child" member, which is initialized to a null
 *   pointer.  The cdecl__alloc_item function sets the declarator.child member
 *   to null; we explicitly copy this null pointer to the returned union member
 *   to avoid type punning.  It is hoped that compilers will notice that these
 *   pointers are at the same offset therefore the assignment can be elided.
 *
 * The resulting pointer can be passed directly to free, as the union is the
 * first member of the parse_item structure.
 *
 * Use the wrapper macros below instead of this one.
 */
#define ALLOC_ITEM(ptr, m1, m2) do { \
	struct parse_item *item; \
	if (!(item = cdecl__alloc_item(0))) \
		YYERROR; \
	item->u.m1.m2 = (void *)item->u.declarator.child; \
	(ptr) = &item->u.m1; \
} while (0)

/* Wrappers for ALLOC_ITEM to allocate various kinds of parser structures. */
#define ALLOC_ITEM_DECLARATOR(ptr) ALLOC_ITEM(ptr, declarator, child)
#define ALLOC_ITEM_DECLSPEC(ptr)   ALLOC_ITEM(ptr, declspec, next)
#define ALLOC_ITEM_DECL(ptr)       ALLOC_ITEM(ptr, decl, next)

#define ALLOC_FUNCTION_(ptr, parameters_) do { \
	ALLOC_ITEM_DECLARATOR(ptr); \
	(ptr)->type = CDECL_DECL_FUNCTION; \
	(ptr)->u.function.parameters = parameters_; \
} while (0)

#define ALLOC_FUNCTION(ptr, parameters_, variadic_) do { \
	ALLOC_FUNCTION_(ptr, parameters_); \
	(ptr)->u.function.variadic = variadic_; \
} while (0)

#define ALLOC_ARRAY(ptr, length_) do { \
	ALLOC_ITEM_DECLARATOR(ptr); \
	(ptr)->type = CDECL_DECL_ARRAY; \
	(ptr)->u.array.vla = NULL; \
	(ptr)->u.array.length = length_; \
} while (0)

#define ALLOC_POINTER(ptr, qualifiers_, child_) do { \
	ALLOC_ITEM_DECLARATOR(ptr); \
	(ptr)->child = child_; \
	(ptr)->type = CDECL_DECL_POINTER; \
	(ptr)->u.pointer.qualifiers = qualifiers_; \
} while (0)

#define ALLOC_DECLSPEC(ptr, type_) do { \
	ALLOC_ITEM_DECLSPEC(ptr); \
	(ptr)->type = type_; \
	(ptr)->ident = NULL; \
} while (0)

#define ALLOC_DECL(ptr, specifiers_, declarators_) do { \
	ALLOC_ITEM_DECL(ptr); \
	(ptr)->specifiers = specifiers_; \
	(ptr)->declarators = declarators_; \
} while (0)

/*
 * With the postprocessing performed by fix-yytname.awk, all the symbol
 * name strings can be used directly in error messages and there is no
 * need for any string processing.
 */
#define yytnamerr(a, b) ( (a) ? cdecl__strlcpy(a, b, -1) : strlen(b) )
%}

%code requires {
#include <inttypes.h>
#include <stdbool.h>
#include "cdecl.h"
}

%code provides {
void cdecl__free(struct cdecl *);
int cdecl__yyparse(void *scanner, struct cdecl **out);
const char *cdecl__token_name(unsigned token);
}

%union {
	cdecl_uintmax uintval;
	unsigned spectype;
	bool boolval;
	struct cdecl_declspec *declspec;
	struct cdecl_declarator *declarator;
	struct cdecl *decl;
	struct parse_item *item;
}

%{
static void yyerror(YYLTYPE *, yyscan_t, struct cdecl **, const char *);
static void free_decl(struct cdecl *);

static void free_declspec(struct cdecl_declspec *x)
{
	struct cdecl_declspec *p;
	while (x) {
		p = x->next;
		free(x);
		x = p;
	}
}

static void free_declarator(struct cdecl_declarator *x)
{
	struct cdecl_declarator *p;

	while (x) {
		p = x->child;

		switch (x->type) {
		case CDECL_DECL_NULL:
			x = NULL;
		case CDECL_DECL_IDENT:
		case CDECL_DECL_ARRAY:
			break;
		case CDECL_DECL_POINTER:
			free_declspec(x->u.pointer.qualifiers);
			break;
		case CDECL_DECL_FUNCTION:
			free_decl(x->u.function.parameters);
			break;
		default:
			assert(0);
		}

		free(x);
		x = p;
	}
}

static void free_decl(struct cdecl *x)
{
	struct cdecl *p;

	while (x) {
		p = x->next;

		/* The specifiers may be shared by an entire chain. */
		if (!p || p->specifiers != x->specifiers)
			free_declspec(x->specifiers);

		free_declarator(x->declarators);
		free(x);
		x = p;
	}
}

void cdecl__free(struct cdecl *decl)
{
	free_decl(decl);
}

/*
 * Join two declaration specifier lists into a single list, with "a" being the
 * head of the new list.
 *
 * The list "a" is assumed to be nonempty.
 */
static void join_specs(struct cdecl_declspec *a, struct cdecl_declspec *b)
{
	while (a->next)
		a = a->next;
	a->next = b;
}

/*
 * Join three specifier lists into a single list, and returns the head of
 * the new list.
 *
 * The list "b" is assumed to be a singleton list.
 */
static struct cdecl_declspec *join_specs3(struct cdecl_declspec *a,
                                          struct cdecl_declspec *b,
                                          struct cdecl_declspec *c)
{
	b->next = c;
	join_specs(b, a);
	return b;
}

/*
 * Reverse the order of a "struct cdecl" list, and return the new first
 * element of the list (i.e., the last element of the original list).
 */
static struct cdecl *reverse_decls(struct cdecl *decl)
{
	struct cdecl *prev, *next;

	for (prev = NULL; decl; decl = next) {
		next = decl->next;
		decl->next = prev;
		prev = decl;
	}

	return prev;
}

/*
 * Alter an abstract declarator (type name) to declare an identifier instead,
 * used by the English parser rules to reduce "identifier as type" sequences.
 */
static struct cdecl *
insert_identifier(struct cdecl *decl, struct parse_item *ident)
{
	struct cdecl_declarator *d, **p = &decl->declarators;

	while ((d = *p)->child)
		p = &d->child;

	*p = &ident->u.declarator;
	return decl;
}

static struct cdecl_declarator *nulldecl(void)
{
	static const struct cdecl_declarator nulldecl = {0};
	return (void *)&nulldecl;
}
#define NULLDECL (nulldecl())

%}

%destructor { free($$); }            <item>
%destructor { free_declspec($$); }   <declspec>
%destructor { free_declarator($$); } <declarator>
%destructor { free_decl($$); }       <decl>

/* Magic tokens */
%token T_LEX_ERROR "@@@"

%token <item>    T_IDENT "identifier"
%token <uintval> T_UINT  "integer constant"

%token T_SEMICOLON ";"
%token T_ASTERISK  "*"
%token T_LPAREN    "("
%token T_RPAREN    ")"
%token T_LBRACKET  "["
%token T_RBRACKET  "]"
%token T_COMMA     ","
%token T_ELLIPSIS  "..."

%token <spectype> T_TYPEDEF   "typedef"
%token <spectype> T_EXTERN    "extern"
%token <spectype> T_STATIC    "static"
%token <spectype> T_AUTO      "auto"
%token <spectype> T_REGISTER  "register"

%token <spectype> T_INLINE    "inline"

%token <spectype> T_RESTRICT  "restrict"
%token <spectype> T_VOLATILE  "volatile"
%token <spectype> T_CONST     "const"

%token <spectype> T_VOID      "void"
%token <spectype> T_CHAR      "char"
%token <spectype> T_SHORT     "short"
%token <spectype> T_INT       "int"
%token <spectype> T_LONG      "long"
%token <spectype> T_FLOAT     "float"
%token <spectype> T_DOUBLE    "double"
%token <spectype> T_SIGNED    "signed"
%token <spectype> T_UNSIGNED  "unsigned"
%token <spectype> T_BOOL      "_Bool"
%token <spectype> T_COMPLEX   "_Complex"
%token <spectype> T_IMAGINARY "_Imaginary"

%token <spectype> T_STRUCT    "struct"
%token <spectype> T_UNION     "union"
%token <spectype> T_ENUM      "enum"

/*
 * English keywords.
 */
%token T_TYPE      "type"
%token T_DECLARE   "declare"
%token T_POINTER   "pointer"
%token T_FUNCTION  "function"
%token T_RETURNING "returning"
%token T_ARRAY     "array"
%token T_TO        "to"
%token T_OF        "of"
%token T_AS        "as"
%token T_VLA       "variable-length"

%type <item>       vla_ident
%type <uintval>    array_length
%type <boolval>    varargs
%type <spectype>   declspec_simple qualifier_simple
%type <spectype>   typespec_simple typespec_tagged
%type <declspec>   declspec_notype declspec_noid typespec_noid typespec
%type <declspec>   qualifier qualifiers
%type <declspec>   declspecs declspecs_notype declspecs_noid
%type <declarator> direct_declarator declarator pointer array parens postfix
%type <declarator> direct_declarator_ish declarator_ish parameter_type_list
%type <decl>       cdecl declaration declarators declarator_wrap parameter

%type <item>       english_vla
%type <declspec>   storage_func_specs post_specs
%type <declspec>   type_qual_spec type_qual_specs typedef_name_qual
%type <declarator> english_declarator english_array english_function
%type <declarator> english_parameter_list null_decl
%type <decl>       english english_declaration english_parameter

/* Precedence declaration to avoid conflict in english_parameter; see below. */
%right T_TYPE
%right T_IDENT

%%

input: cdecl { *out = $1; }
cdecl: english | declaration

semi: | T_SEMICOLON
declaration: declspecs declarators semi {
	$$ = reverse_decls($2);
	$$->specifiers = $1;
};

/*
 * We support parsing declarations using arbitrary identifiers as type
 * specifiers (a la C typedef).  To avoid confusion with identifiers that
 * may also be used as declarators, note the following:
 *
 *  (a) Every valid C declaration must have at least one type specifier, and
 *  (b) Valid declarations with typedef names have exactly one type specifier.
 *
 * So the rule applied when parsing specifiers is: an identifier is a type
 * specifier only if we have not yet seen any type specifiers whatsoever
 * (within one declaration specifier list).
 *
 * Treating identifiers as type specifiers by default can lead to strange and
 * unexpected parses; libcdecl applies a simplification step to the resulting
 * parse tree afterwards.
 */
declspecs: declspecs_notype typespec declspecs_noid {
	$$ = join_specs3($1, $2, $3);
}

declspecs_notype: { $$ = NULL; } | declspecs_notype declspec_notype {
	$$ = $2;
	$$->next = $1;
}

declspecs_noid: { $$ = NULL; } | declspecs_noid declspec_noid {
	$$ = $2;
	$$->next = $1;
}

qualifiers: { $$ = NULL; } | qualifiers qualifier {
	$$ = $2;
	$$->next = $1;
}

declarators: declarator_wrap | declarators T_COMMA declarator_wrap {
	$$ = $3;
	$$->next = $1;
}

declarator_wrap: declarator {
	ALLOC_DECL($$, NULL, $1);
}

declspec_simple: T_AUTO
	| T_TYPEDEF
	| T_EXTERN
	| T_STATIC
	| T_REGISTER
	| T_INLINE

typespec_simple: T_VOID
	| T_CHAR
	| T_SHORT
	| T_INT
	| T_LONG
	| T_FLOAT
	| T_DOUBLE
	| T_SIGNED
	| T_UNSIGNED
	| T_BOOL
	| T_COMPLEX
	| T_IMAGINARY

typespec_tagged: T_STRUCT | T_UNION | T_ENUM | { $$ = CDECL_TYPE_IDENT; }

qualifier_simple: T_CONST
	| T_RESTRICT
	| T_VOLATILE

declspec_notype: qualifier | declspec_simple { ALLOC_DECLSPEC($$, $1); }
typespec_noid: typespec_simple { ALLOC_DECLSPEC($$, $1); }
qualifier: qualifier_simple { ALLOC_DECLSPEC($$, $1); }

typespec: typespec_noid | typespec_tagged T_IDENT {
	/* Compiler should be able to elide this assignment. */
	$2->u.declspec.ident = $2->u.declarator.u.ident;

	$$ = &$2->u.declspec;
	$$->type = $1;
}

declspec_noid: declspec_notype | typespec_noid

vla_ident: T_IDENT | T_ASTERISK {
	if (!($$ = cdecl__alloc_item(1)))
		YYERROR;
	*$$->s = 0;
}

array: T_LBRACKET array_length T_RBRACKET {
	ALLOC_ARRAY($$, $2);
} | T_LBRACKET vla_ident T_RBRACKET {
	$$ = &$2->u.declarator;
	$$->type = CDECL_DECL_ARRAY;
	$$->u.array.vla = $$->u.ident;
	$$->u.array.length = 0;
}

parameter: declspecs declarator {
	ALLOC_DECL($$, $1, $2);
}

varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }

parameter_type_list: parameter {
	ALLOC_FUNCTION_($$, $1);
} | parameter_type_list T_COMMA parameter {
	$$ = $1;
	$3->next = $$->u.function.parameters;
	$$->u.function.parameters = $3;
}

parens: T_LPAREN parameter_type_list varargs T_RPAREN {
	$2->u.function.parameters = reverse_decls($2->u.function.parameters);
	$2->u.function.variadic = $3;
	$$ = $2;
} | T_LPAREN declarator_ish T_RPAREN {
	struct cdecl *fake_params;

	ALLOC_DECL(fake_params, NULL, $2);
	ALLOC_FUNCTION_($$, fake_params);
}

pointer: T_ASTERISK qualifiers direct_declarator {
	ALLOC_POINTER($$, $2, $3);
} | T_ASTERISK qualifiers pointer {
	ALLOC_POINTER($$, $2, $3);
}

declarator: direct_declarator | pointer
declarator_ish: direct_declarator_ish | pointer
postfix: array | parens

direct_declarator_ish: {
	$$ = NULLDECL;
} | direct_declarator_ish postfix {
	$$ = $2;
	$$->child = $1;
}

direct_declarator: {
	$$ = NULLDECL;
} | T_IDENT {
	$$ = &$1->u.declarator;
} | direct_declarator postfix {
	$$ = $2;
	$$->child = $1;
}

english: T_DECLARE T_IDENT T_AS english_declaration {
	$$ = insert_identifier($4, $2);
} | T_TYPE english_declaration {
	$$ = $2;
}

/*
 * We use a precedence declaration to prefer shifting an identifier
 * over reducing this empty rule; see below.
 */
storage_func_specs: %prec T_TYPE { $$ = NULL; }
storage_func_specs: storage_func_specs declspec_simple {
	ALLOC_DECLSPEC($$, $2);
	$$->next = $1;
}

type_qual_spec: typespec_noid | qualifier

type_qual_specs: { $$ = NULL; } | type_qual_specs type_qual_spec {
	$$ = $2;
	$$->next = $1;
}

/*
 * The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
 * conflicts with pointer declarators.  So we end up needing to stitch
 * together three different specifiers lists.
 */
post_specs: qualifiers typespec type_qual_specs {
	$$ = join_specs3($1, $2, $3);
}

english_declaration: storage_func_specs english_declarator post_specs {
	join_specs($3, $1);
	ALLOC_DECL($$, $3, $2);
}

english_declarator: {
	$$ = NULLDECL;
} | english_declarator qualifiers T_POINTER T_TO {
	ALLOC_POINTER($$, $2, $1);
} | english_declarator english_array {
	$$ = $2;
	$$->child = $1;
} | english_declarator english_function {
	$$ = $2;
	$$->child = $1;
}

english_function: T_FUNCTION T_RETURNING {
	ALLOC_FUNCTION($$, NULL, false);
} | T_FUNCTION T_LPAREN english_parameter_list varargs T_RPAREN T_RETURNING {
	$3->u.function.parameters = reverse_decls($3->u.function.parameters);
	$3->u.function.variadic = $4;
	$$ = $3;
}

english_parameter_list: english_parameter {
	ALLOC_FUNCTION_($$, $1);
} | english_parameter_list T_COMMA english_parameter {
	$$ = $1;
	$3->next = $$->u.function.parameters;
	$$->u.function.parameters = $3;
}

typedef_name_qual: T_IDENT qualifiers {
	/* Compiler should be able to elide this assignment. */
	$1->u.declspec.ident = $1->u.declarator.u.ident;

	$$ = &$1->u.declspec;
	$$->type = CDECL_TYPE_IDENT;
	$$->next = $2;
}

null_decl: {
	$$ = NULLDECL;
}

/*
 * There is a shift/reduce conflict here when an identifier appears as the
 * first token.  The conflict is between shifting T_IDENT, or reducing the
 * empty production for storage_func_specs (cf. english_declaration).
 *
 *   - In either case, if we reduce, we won't match T_IDENT T_AS since the
 *     stack now has the extra storage_func_specs nonterminal symbol.
 *   - And if we shift, we won't match english_declaration since it is
 *     too late to add storage_func_specs to the stack.
 *
 * The only valid input affected by the conflict is a simple type names,
 * possibly followed by qualifiers.  So the conflict is adequately resolved
 * by shifting, so long as we have a special-case reduction to handle this.
 */
english_parameter: english_declaration | typedef_name_qual null_decl {
	ALLOC_DECL($$, $1, $2);
} | T_IDENT T_AS english_declaration {
	$$ = insert_identifier($3, $1);
}

english_array: T_VLA T_ARRAY english_vla T_OF {
	$$ = &$3->u.declarator;
	$$->type = CDECL_DECL_ARRAY;
	$$->u.array.vla = $$->u.ident;
	$$->u.array.length = 0;
} | T_ARRAY array_length T_OF {
	ALLOC_ARRAY($$, $2);
}

array_length: { $$ = 0; }
array_length: T_UINT {
	if (!($$ = $1)) {
		cdecl__errmsg(CDECL__EZEROARRAY);
		YYERROR;
	}
}

english_vla: T_IDENT | {
	if (!($$ = cdecl__alloc_item(1)))
		YYERROR;
	*$$->s = 0;
}

%%

/*
 * Expose the token string table to the rest of the library, in order to
 * produce strings that match parser keywords.
 *
 * In order for this to work properly, the Bison output must be postprocessed
 * by fix-yytname.awk to remove pointless quotation marks from the keyword
 * strings.
 */
const char *cdecl__token_name(unsigned token)
{
	return yytname[YYTRANSLATE(token)];
}

/*
 * Current versions of GCC (up to 13) want to inline this function into the
 * parser even when optimizing for size and the results are not great, so
 * try to prevent such inlining.
 */
CDECL__NOINLINE static void
yyerror(YYLTYPE *loc, yyscan_t scanner, struct cdecl **out, const char *err)
{
	if (strstr(err, yytname[YYTRANSLATE(T_LEX_ERROR)]))
		return;

	cdecl__err("%s", err);
}