%code top {
/*
* Parser for C declarations.
* Copyright © 2011-2012, 2021 Nick Bowler
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see .
*/
}
%name-prefix "cdecl__yy"
%parse-param {void *scanner}
%parse-param {struct cdecl **out}
%lex-param {yyscan_t scanner}
%define api.pure
%error-verbose
%locations
%{
#include
#include
#include
#include "scan.h"
#include "cdecl.h"
#include "cdecl-internal.h"
#define FAIL(msg) do { \
yyerror(&yylloc, NULL, NULL, msg); \
YYERROR; \
} while (0)
#define ALLOC(ptr, size) do { \
(ptr) = malloc(size); \
if (!(ptr)) { \
cdecl__err(CDECL_ENOMEM); \
YYERROR; \
} \
} while (0)
#define ALLOC_STRUCT(ptr, type, ...) do { \
ALLOC(ptr, sizeof (type)); \
*(ptr) = (type) { __VA_ARGS__ }; \
} while (0)
%}
%code requires {
#include
}
%code provides {
void cdecl__free(struct cdecl *);
int cdecl__yyparse(void *scanner, struct cdecl **out);
}
%union {
uintmax_t uintval;
unsigned spectype;
_Bool boolval;
char *strval;
struct cdecl_declspec *declspec;
struct cdecl_declarator *declarator;
struct cdecl *decl;
}
%{
static void free_decl(struct cdecl *);
static void free_declspec(struct cdecl_declspec *x)
{
struct cdecl_declspec *p;
while (x) {
p = x->next;
free(x->ident);
free(x);
x = p;
}
}
static void free_declarator(struct cdecl_declarator *x)
{
struct cdecl_declarator *p;
while (x) {
p = x->child;
switch (x->type) {
case CDECL_DECL_NULL:
break;
case CDECL_DECL_IDENT:
free(x->u.ident);
break;
case CDECL_DECL_POINTER:
free_declspec(x->u.pointer.qualifiers);
break;
case CDECL_DECL_ARRAY:
free(x->u.array.vla);
break;
case CDECL_DECL_FUNCTION:
free_decl(x->u.function.parameters);
break;
default:
assert(0);
}
free(x);
x = p;
}
}
static void free_decl(struct cdecl *x)
{
struct cdecl *p;
while (x) {
p = x->next;
/* The specifiers may be shared by an entire chain. */
if (!p || p->specifiers != x->specifiers)
free_declspec(x->specifiers);
free_declarator(x->declarators);
free(x);
x = p;
}
}
void cdecl__free(struct cdecl *decl)
{
free_decl(decl);
}
static void
yyerror(YYLTYPE *loc, yyscan_t scanner, struct cdecl **out, const char *err)
{
if (strstr(err, "T_LEX_ERROR"))
return;
cdecl__err(CDECL_ENOPARSE, "%s", err);
}
%}
%destructor { free($$); }
%destructor { free_declspec($$); }
%destructor { free_declarator($$); }
%destructor { free_decl($$); }
/* Magic tokens */
%token T_LEX_ERROR
%token T_ENGLISH
%token T_IDENT "identifier"
%token T_UINT "integer constant"
%token T_SEMICOLON ";"
%token T_ASTERISK "*"
%token T_LPAREN "("
%token T_RPAREN ")"
%token T_LBRACKET "["
%token T_RBRACKET "]"
%token T_COMMA ","
%token T_ELLIPSIS "..."
%token T_TYPEDEF "typedef"
%token T_EXTERN "extern"
%token T_STATIC "static"
%token T_AUTO "auto"
%token T_REGISTER "register"
%token T_INLINE "inline"
%token T_RESTRICT "restrict"
%token T_VOLATILE "volatile"
%token T_CONST "const"
%token T_VOID "void"
%token T_CHAR "char"
%token T_SHORT "short"
%token T_INT "int"
%token T_LONG "long"
%token T_FLOAT "float"
%token T_DOUBLE "double"
%token T_SIGNED "signed"
%token T_UNSIGNED "unsigned"
%token T_BOOL "_Bool"
%token T_COMPLEX "_Complex"
%token T_IMAGINARY "_Imaginary"
%token T_STRUCT "struct"
%token T_UNION "union"
%token T_ENUM "enum"
/*
* English keywords.
*/
%token T_TYPE "type"
%token T_DECLARE "declare"
%token T_POINTER "pointer"
%token T_FUNCTION "function"
%token T_RETURNING "returning"
%token T_ARRAY "array"
%token T_TO "to"
%token T_OF "of"
%token T_AS "as"
%token T_VLA "variable-length"
%type vla_ident
%type varargs
%type declspec_simple typespec_simple qualifier_simple
%type declspec_notype declspec_noid typespec_noid typespec
%type qualifier qualifiers
%type declspecs declspecs_noid
%type direct_declarator declarator pointer array parens postfix
%type direct_declarator_ish declarator_ish parameter_type_list
%type declaration declarators declarator_wrap
%type parameter parameters
%type english_vla
%type storage_func_specs post_specs
%type type_qual_spec type_qual_specs typedef_name_qual
%type english_declarator english_array english_function
%type english_parameter_list null_decl
%type english_parameter english_parameters
%type english english_declaration
/*
* Harmless shift/reduce conflicts in english_parameter. See comments below
* for more details.
*/
%expect 2
%%
input: T_ENGLISH english {
*out = $2;
} | declaration {
*out = $1;
};
semi: | T_SEMICOLON
declaration: declspecs declarators semi {
$$ = $2;
for (struct cdecl *i = $$; i; i = i->next)
i->specifiers = $1;
};
declspecs: declspec_notype declspecs {
$$ = $1;
$$->next = $2;
} | typespec declspecs_noid {
$$ = $1;
$$->next = $2;
}
declspecs_noid: { $$ = NULL; } | declspec_noid declspecs_noid {
$$ = $1;
$$->next = $2;
}
qualifiers: { $$ = NULL; } | qualifiers qualifier {
$$ = $2;
$$->next = $1;
}
declarators: declarator_wrap | declarator_wrap T_COMMA declarators {
$$ = $1;
$$->next = $3;
}
declarator_wrap: declarator {
ALLOC_STRUCT($$, struct cdecl, .declarators = $1);
}
declspec_simple: T_AUTO { $$ = CDECL_STOR_AUTO; }
| T_TYPEDEF { $$ = CDECL_STOR_TYPEDEF; }
| T_EXTERN { $$ = CDECL_STOR_EXTERN; }
| T_STATIC { $$ = CDECL_STOR_STATIC; }
| T_REGISTER { $$ = CDECL_STOR_REGISTER; }
| T_INLINE { $$ = CDECL_FUNC_INLINE; }
typespec_simple: T_VOID { $$ = CDECL_TYPE_VOID; }
| T_CHAR { $$ = CDECL_TYPE_CHAR; }
| T_SHORT { $$ = CDECL_TYPE_SHORT; }
| T_INT { $$ = CDECL_TYPE_INT; }
| T_LONG { $$ = CDECL_TYPE_LONG; }
| T_FLOAT { $$ = CDECL_TYPE_FLOAT; }
| T_DOUBLE { $$ = CDECL_TYPE_DOUBLE; }
| T_SIGNED { $$ = CDECL_TYPE_SIGNED; }
| T_UNSIGNED { $$ = CDECL_TYPE_UNSIGNED; }
| T_BOOL { $$ = CDECL_TYPE_BOOL; }
| T_COMPLEX { $$ = CDECL_TYPE_COMPLEX; }
| T_IMAGINARY { $$ = CDECL_TYPE_IMAGINARY; }
qualifier_simple: T_CONST { $$ = CDECL_QUAL_CONST; }
| T_RESTRICT { $$ = CDECL_QUAL_RESTRICT; }
| T_VOLATILE { $$ = CDECL_QUAL_VOLATILE; }
declspec_notype: qualifier | declspec_simple {
ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}
typespec_noid: typespec_simple {
ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}
qualifier: qualifier_simple {
ALLOC_STRUCT($$, struct cdecl_declspec, .type = $1);
}
typespec: typespec_noid | T_STRUCT T_IDENT {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = CDECL_TYPE_STRUCT,
.ident = $2);
} | T_UNION T_IDENT {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = CDECL_TYPE_UNION,
.ident = $2);
} | T_ENUM T_IDENT {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = CDECL_TYPE_ENUM,
.ident = $2);
} | T_IDENT {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = CDECL_TYPE_IDENT,
.ident = $1);
}
declspec_noid: declspec_notype | typespec_noid
vla_ident: T_IDENT | T_ASTERISK {
ALLOC($$, sizeof "");
strcpy($$, "");
}
array: T_LBRACKET T_UINT T_RBRACKET {
if ($2 == 0)
FAIL(_("array length must be positive"));
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY,
.u.array.length = $2);
} | T_LBRACKET vla_ident T_RBRACKET {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY,
.u.array.vla = $2);
} | T_LBRACKET T_RBRACKET {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY);
}
parameter: declspecs declarator {
ALLOC_STRUCT($$, struct cdecl,
.specifiers = $1,
.declarators = $2);
}
parameters: parameter | parameters T_COMMA parameter {
$$ = $3;
$$->next = $1;
}
varargs: { $$ = false; } | T_COMMA T_ELLIPSIS { $$ = true; }
parameter_type_list: parameters varargs {
struct cdecl *p, *c, *n;
/* Parameters were accumulated in reverse order. */
for (p = NULL, c = $1; c; p = c, c = n) {
n = c->next;
c->next = p;
}
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_FUNCTION,
.u.function.parameters = p,
.u.function.variadic = $2);
}
parens: T_LPAREN parameter_type_list T_RPAREN {
$$ = $2;
} | T_LPAREN declarator_ish T_RPAREN {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_FUNCTION);
ALLOC_STRUCT($$->u.function.parameters, struct cdecl,
.declarators = $2);
}
pointer: T_ASTERISK qualifiers direct_declarator {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_POINTER,
.u.pointer.qualifiers = $2,
.child = $3);
} | T_ASTERISK qualifiers pointer {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_POINTER,
.u.pointer.qualifiers = $2,
.child = $3);
}
declarator: direct_declarator | pointer
declarator_ish: direct_declarator_ish | pointer
postfix: array | parens
direct_declarator_ish: {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_NULL);
} | direct_declarator_ish postfix {
$$ = $2;
$$->child = $1;
}
direct_declarator: {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_NULL);
} | T_IDENT {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_IDENT,
.u.ident = $1);
} | direct_declarator postfix {
$$ = $2;
$$->child = $1;
}
english: T_DECLARE T_IDENT T_AS english_declaration {
$$ = $4;
for (struct cdecl_declarator *d = $$->declarators; d; d = d->child) {
if (d->type == CDECL_DECL_NULL) {
d->type = CDECL_DECL_IDENT;
d->u.ident = $2;
}
}
} | T_TYPE english_declaration {
$$ = $2;
}
storage_func_specs: { $$ = NULL; } | declspec_simple storage_func_specs {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = $1,
.next = $2);
}
type_qual_spec: typespec_noid | qualifier
type_qual_specs: { $$ = NULL; } | type_qual_spec type_qual_specs {
$$ = $1;
$$->next = $2;
}
/*
* The "qualifiers" nonterminal needs to be used here to avoid shift/reduce
* conflicts with pointer declarators. So we end up needing to stitch
* together three different specifiers lists.
*/
post_specs: qualifiers typespec type_qual_specs {
$$ = $2;
$$->next = $1;
for (struct cdecl_declspec *s = $$; s; s = s->next) {
if (!s->next) {
s->next = $3;
break;
}
}
}
english_declaration: storage_func_specs english_declarator post_specs {
ALLOC_STRUCT($$, struct cdecl,
.specifiers = $3,
.declarators = $2);
for (struct cdecl_declspec *s = $$->specifiers; s; s = s->next) {
if (!s->next) {
s->next = $1;
break;
}
}
}
english_declarator: {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_NULL);
} | english_declarator qualifiers T_POINTER T_TO {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_POINTER,
.child = $1,
.u.pointer.qualifiers = $2);
} | english_declarator english_array {
$$ = $2;
$$->child = $1;
} | english_declarator english_function {
$$ = $2;
$$->child = $1;
}
english_function: T_FUNCTION T_RETURNING {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_FUNCTION,
.u.function.parameters = NULL);
} | T_FUNCTION T_LPAREN english_parameter_list T_RPAREN T_RETURNING {
$$ = $3;
}
english_parameter_list: english_parameters varargs {
struct cdecl *p, *c, *n;
/* Parameters were accumulated in reverse order. */
for (p = NULL, c = $1; c; p = c, c = n) {
n = c->next;
c->next = p;
}
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_FUNCTION,
.u.function.parameters = p,
.u.function.variadic = $2);
}
english_parameters: english_parameters T_COMMA english_parameter {
$$ = $3;
$$->next = $1;
} | english_parameter
typedef_name_qual: T_IDENT qualifiers {
ALLOC_STRUCT($$, struct cdecl_declspec,
.type = CDECL_TYPE_IDENT,
.ident = $1,
.next = $2);
}
null_decl: {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_NULL);
}
/*
* There is a small shift/reduce conflict here. An unadorned identifier
* as the first thing in the parameter might be a typedef name deep in the
* first english_declaration (thus empty storage_func_specs and empty
* english_declarator need to be reduced) or it might be the identifier
* before the "as" (thus the identifier should be shifted).
*
* The typedef name conflict is the only issue, so treating it as a special
* case makes the shift harmless.
*/
english_parameter: english_declaration | typedef_name_qual null_decl {
ALLOC_STRUCT($$, struct cdecl,
.specifiers = $1,
.declarators = $2);
} | T_IDENT T_AS english_declaration {
$$ = $3;
for (struct cdecl_declarator *d = $$->declarators; d; d = d->child) {
if (d->type == CDECL_DECL_NULL) {
d->type = CDECL_DECL_IDENT;
d->u.ident = $1;
}
}
}
english_array: T_VLA T_ARRAY english_vla T_OF {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY,
.u.array.vla = $3);
} | T_ARRAY T_UINT T_OF {
if ($2 == 0)
FAIL(_("array length must be positive"));
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY,
.u.array.length = $2);
} | T_ARRAY T_OF {
ALLOC_STRUCT($$, struct cdecl_declarator,
.type = CDECL_DECL_ARRAY,
.u.array.length = 0);
}
english_vla: T_IDENT | {
ALLOC($$, sizeof "");
strcpy($$, "");
}