#!/bin/sed -f

# Nick's mpdbetter `configuration file'.  Input a list of track titles, and
# substitute each with the title of the best version of that song.

# Handle special cases first
/ -extra hot mix-/{s///;b}
/ -Raven fly edit-/{s///;b}
/ -2006 memorial mix-/{s///;b}
/ -Practice Track-/{s///;b}
/ On Air Ver\./{s///;b}
/-\[instrumental\]/{s///;b}
/ちいさなヘミソフィア/{s//ヘミソフィア/;b}
/愛のメロディー/{s/\((.*)\)\?$/(soundtrack ver.)/;b}
/COLORS -.*/{s//COLORS/;b}
/ without NATSUMI/{s///;b}

# Some literal replacements
/松澤由美 - SNOW/c\
島みやえい子 - SNOW -Album Mix-
/詩月カオリ - Senecio/c\
詩月カオリ - Senecio -Album Mix-
/AKI - Pure Heart〜世界で一番アナタが好き〜/c\
詩月カオリ - Pure Heart 〜世界で一番アナタが好き〜 -Remix-
/open〜オルゴールバージョン〜/c\
詩月カオリ - open
/euphoric field/c\
ELISA - euphoric field (Japanese)
/La Clef 〜迷宮の鍵〜/c\
KOTOKO - La Clef 〜迷宮の鍵〜

# Sanitization
s/「\(The Sore Feet Song\)」/\1/

# General rules get most tracks
/\s*[~〜<〈[(ー–−-]\s\?inst.*/I          {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?tv.*/I            {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?without.*/I       {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?w\/o.*/I          {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?off.*/I           {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?back.*/I          {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?short.*/I         {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?karaoke.*/I       {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?game.*/I          {s///;b}
/\s*[~〜<〈[(ー–−-]\s\?[^ ]*カラオケ.*/I {s///;b}

# When we lack brackets we match more specific strings
/ instrumental.*/I {s///;b}
/ off vocal.*/I    {s///;b}
/ short.*/I        {s///;b}
/ tv-\w\+/I        {s///;b}
/ anime ver\./I    {s///;b}