X-Git-Url: http://git.draconx.ca/gitweb/rrace.git/blobdiff_plain/2529a9651d160ab3a17118d778f5e5584d040765..683027f82849ca96cf424ffff699ab57e119f051:/configure.ac

diff --git a/configure.ac b/configure.ac
index b0c7fb0..3ef5c67 100644
--- a/configure.ac
+++ b/configure.ac
@@ -4,6 +4,9 @@ dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
 dnl This is free software: you are free to do what the fuck you want to.
 dnl There is NO WARRANTY, to the extent permitted by law.
 
+dnl remove pointless gnulib warning flag check
+AC_DEFUN([gl_CC_GNULIB_WARNINGS])
+
 AC_INIT([rrace], [0], [nbowler@draconx.ca])
 AC_CONFIG_HEADERS([config.h])
 
@@ -12,7 +15,12 @@ AM_SILENT_RULES([yes])
 DX_AUTOMAKE_COMPAT
 
 AC_PROG_CC_C99
+gl_EARLY
 LT_INIT
+gl_INIT
+
+AC_CACHE_SAVE
+m4_include([lib/gnulib.mk])
 
 AC_PATH_XTRA
 AS_IF([test x"$no_x" != x"yes"],
@@ -33,11 +41,63 @@ AS_IF([test x"$with_x" = x"yes" && test "$dx_cv_have_motif" != x"yes"],
 AC_SUBST([MOTIF_CFLAGS], [@&t@])
 AC_SUBST([MOTIF_LIBS], [@&t@])
 AS_IF([test x"$dx_cv_have_motif" = x"yes"],
-  [MOTIF_CFLAGS=$dx_cv_motif_cflags MOTIF_LIBS=$dx_cv_motif_libs])
+  [MOTIF_CFLAGS=$dx_cv_motif_cflags MOTIF_LIBS=$dx_cv_motif_libs],
+  [AC_DEFINE([X_DISPLAY_MISSING])])
+AM_CONDITIONAL([HAVE_MOTIF], [test x"$dx_cv_have_motif" = x"yes"])
 
 AC_CONFIG_TESTDIR([.], [t:.])
 DX_PROG_AUTOTEST
 AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
 
+AC_CHECK_PROGS([XPMTOPPM], [xpmtoppm])
+AC_CHECK_PROGS([PNMTOPNG], [pnmtopng])
+AC_CHECK_PROGS([CONVERT], [convert])
+AC_CHECK_PROGS([GM], [gm])
+AC_CACHE_CHECK([how to convert XPM to PNG], [dx_cv_xpm_to_png],
+[cat >conftest.xpm <<'EOF'
+/* XPM */
+static char *x[] = {
+"1 1 1 1",
+"x c #123456",
+"x"
+};
+EOF
+check_conftest_png () {
+  od conftest.png | $AWK 'BEGIN { success=0; }
+NR == 1 && $2 == "050211" && $3 == "043516" { success=1; }
+NR == 1 && $2 == "104520" && $3 == "047107" { success=1; }
+END { exit(!success); }'
+}
+rm -f conftest.png
+for dx_cv_xpm_to_png in netpbm 'gm convert' convert unknown; do
+AS_CASE([$dx_cv_xpm_to_png],
+
+[netpbm],
+[AS_IF([$XPMTOPPM conftest.xpm >conftest.ppm 2>&AS_MESSAGE_LOG_FD],
+  [], [continue])
+AS_IF([$PNMTOPNG conftest.ppm >conftest.png 2>&AS_MESSAGE_LOG_FD],
+  [], [continue])
+AS_IF([check_conftest_png], [break])],
+
+[*convert],
+[AS_CASE([$dx_cv_xpm_to_png],
+  [gm*], [test_convert="$GM convert"],
+  [test_convert="$CONVERT"])
+AS_IF([$test_convert conftest.xpm conftest.png >&AS_MESSAGE_LOG_FD 2>&1],
+  [], [continue])
+AS_IF([check_conftest_png], [break])])
+done
+rm -f conftest.xpm conftest.ppm conftest.png])
+
+AM_CONDITIONAL([USE_NETPBM], [test x"$dx_cv_xpm_to_png" = x"netpbm"])
+AM_CONDITIONAL([USE_CONVERT],
+  [AS_CASE([$dx_cv_xpm_to_png], [*convert], [], [false])])
+
+AS_IF([test x"$dx_cv_xpm_to_png" = x"gm convert"],
+  [CONVERT="$GM convert"])
+
+AC_CHECK_PROGS([OPTIPNG], [optipng])
+: "${OPTIPNG:=:}"
+
 AC_CONFIG_FILES([Makefile])
 AC_OUTPUT