+AM_CONDITIONAL([HAVE_MOTIF],
+ [test x"$with_x" != x"no" && test x"$dx_cv_have_motif" = x"yes"])
+AM_COND_IF([HAVE_MOTIF],
+ [MOTIF_CFLAGS=$dx_cv_motif_cflags MOTIF_LIBS=$dx_cv_motif_libs],
+ [AC_DEFINE([X_DISPLAY_MISSING])])
+AH_TEMPLATE([X11_RENDER_DEBUG],
+ [Define to 1 to enable visual aids for debugging X11 rendering.])
+
+# Check for XmPIXMAP_AND_STRING.
+#
+# Just checking for the existence of this identifier is sufficient, to ensure
+# that the C compiler accepts the name. If it turns out to not actually be
+# supported by the library used at runtime, Motif itself will catch this
+# and set to the default (i.e., XmSTRING).
+AM_COND_IF([HAVE_MOTIF],
+[AC_CACHE_CHECK([whether Motif supports XmPIXMAP_AND_STRING],
+[dx_cv_motif_have_pixmap_and_string],
+[save_CFLAGS=$CFLAGS save_LIBS=$LIBS
+CFLAGS="$MOTIF_CFLAGS $CFLAGS" LIBS="$MOTIF_LIBS $LIBS"
+AC_COMPUTE_INT([dx_tmp],
+ [XmPIXMAP != XmPIXMAP_AND_STRING && XmSTRING != XmPIXMAP_AND_STRING],
+ [#include <Xm/Label.h>], [dx_tmp=0])
+AS_IF([test x"$dx_tmp" = x"1"],
+ [dx_cv_motif_have_pixmap_and_string=yes],
+ [dx_cv_motif_have_pixmap_and_string=no])
+CFLAGS=$save_CFLAGS LIBS=$save_LIBS])
+AS_IF([test x"$dx_cv_motif_have_pixmap_and_string" = x"yes"],
+ [AC_DEFINE([HAVE_MOTIF_PIXMAP_AND_STRING], [1],
+ [Define to 1 if Motif supports XmPIXMAP_AND_STRING])])
+])
+
+AC_CONFIG_TESTDIR([.], [t:.])
+DX_PROG_AUTOTEST
+AM_CONDITIONAL([HAVE_AUTOTEST], [test x"$dx_cv_autotest_works" = x"yes"])
+
+AC_CHECK_PROGS([XPMTOPPM], [xpmtoppm])
+AC_CHECK_PROGS([PNMTOPNG], [pnmtopng])
+AC_CHECK_PROGS([CONVERT], [convert])
+AC_CHECK_PROGS([GM], [gm])
+AC_CACHE_CHECK([how to convert XPM to PNG], [dx_cv_xpm_to_png],
+[cat >conftest.xpm <<'EOF'
+/* XPM */
+static char *x[] = {
+"1 1 1 1",
+"x c #123456",
+"x"
+};
+EOF
+check_conftest_png () {
+ od conftest.png | $AWK 'BEGIN { success=0; }
+NR == 1 && $2 == "050211" && $3 == "043516" { success=1; }
+NR == 1 && $2 == "104520" && $3 == "047107" { success=1; }
+END { exit(!success); }'
+}
+rm -f conftest.png
+for dx_cv_xpm_to_png in netpbm 'gm convert' convert unknown; do
+AS_CASE([$dx_cv_xpm_to_png],
+
+[netpbm],
+[AS_IF([$XPMTOPPM conftest.xpm >conftest.ppm 2>&AS_MESSAGE_LOG_FD],
+ [], [continue])
+AS_IF([$PNMTOPNG conftest.ppm >conftest.png 2>&AS_MESSAGE_LOG_FD],
+ [], [continue])
+AS_IF([check_conftest_png], [break])],
+
+[*convert],
+[AS_CASE([$dx_cv_xpm_to_png],
+ [gm*], [test_convert="$GM convert"],
+ [test_convert="$CONVERT"])
+AS_IF([$test_convert conftest.xpm conftest.png >&AS_MESSAGE_LOG_FD 2>&1],
+ [], [continue])
+AS_IF([check_conftest_png], [break])])
+done
+rm -f conftest.xpm conftest.ppm conftest.png])
+
+AM_CONDITIONAL([USE_NETPBM], [test x"$dx_cv_xpm_to_png" = x"netpbm"])
+AM_CONDITIONAL([USE_CONVERT],
+ [AS_CASE([$dx_cv_xpm_to_png], [*convert], [], [false])])
+
+AS_IF([test x"$dx_cv_xpm_to_png" = x"gm convert"],
+ [CONVERT="$GM convert"])
+
+AC_CHECK_PROGS([OPTIPNG], [optipng])
+: "${OPTIPNG:=:}"