AT_COPYRIGHT([Copyright © 2022 Nick Bowler])
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

AT_INIT
AT_COLOR_TESTS

m4_divert_push([PREPARE_TESTS])dnl
test_run_tap () {
  "$builddir/t/$1" > "$1.tap"
  status=$?
  cat "$1.tap"
  :; { echo 'print <<EOF'; cat "$1.tap"; echo 'EOF'; } >"$1.pl"
  prove "$1.pl" 2>&1
  return $status
}
m4_divert_pop([PREPARE_TESTS])

m4_define([TEST_TAP], [AT_CHECK([test_run_tap "$1"], [0], [ignore])])
m4_define([TEST_TAP_SIMPLE], [dnl
AT_SETUP([$1])
AT_KEYWORDS([$4])dnl
m4_n([$3])dnl
TEST_TAP([$2])
AT_CLEANUP])

m4_include([tests/game.at])
m4_include([tests/gui.at])